Discussion :

[dlight]

Bonjour.

Je m'inspire actuellement de la discussion suivante:

http://www.developpez.net/forums/d97...xcel-vers-pdf/

Ma question:

Est-il possible de faire en sorte que la fenêtre de PDF creator ne soit pas affichée et que le nom et le répertoire soient déjà déterminé lors de la sauvegarde.

Bref, le PDF s'enregistre directement à l'endroit de mon choix sans l'intervention de l'utilisateur...

Merci à l'avance

[kiki29]

Salut,Lancer PDFCreator.exe
Menu Imprimante/Options
Enregistrement Automatique

Tu as également l'aide en ligne

[dlight]

Merci à vous KiKi29 de prendre le temps de me répondre.

Je suis encore novice en Vba, je me demande donc comment lancer PDFCreator.
J'ai cherché et j'ai trouvé ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Shell "C:\Program Files\PDFCreator.exe",vbNormalFocus

mais à chaque fois j'ai l'erreur 53.

Aussi, j'ai oublié de dire que le nom du fichier PDF prendra la forme suivante:

123456789 Prénom Nom

Les trois informations se trouvent dans le fichier excel

Je n'ai pas de problème dans la création de code avec des variables. Par contre, je ne sais pas comment le résultat de la variable peut ce placer dans le nom du fichier PDF.

Merci à l'avance pour l'aide

Dlight

[kiki29]

Re,quand je disais lancer c'était double cliquer sur PDFCreator.exe et ensuite de procéder via son menu Imprimante etc ,enfin bref

Sinon http://www.google.fr/#hl=fr&rlz=1R2A...89ae64ad3b47fb

et un code qui devrait s'apparenter à qqch comme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Option Explicit
 
Sub TstPdfCreator()
Dim JobPDF As Object
Dim sNomPDF As String
Dim sCheminPDF As String
 
    sNomPDF = "commande_" & Range("B13") & ".pdf"
    sCheminPDF = ThisWorkbook.Path & "\"
 
    If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub
 
    Set JobPDF = CreateObject("PDFCreator.clsPDFCreator")
 
    With JobPDF
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Initialisation de PDFCreator impossible", vbCritical + vbOKOnly, "PDFCreator"
            Exit Sub
        End If
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
        .cOption("AutosaveDirectory") = sCheminPDF
        .cOption("AutosaveFilename") = sNomPDF
 
        '   0=PDF, 1=Png, 2=jpg, 3=bmp, 4=pcx, 5=tif, 6=ps, 7=eps, 8=txt
        .cOption("AutosaveFormat") = 0
        .cClearCache
    End With
 
    ActiveWorkbook.PrintOut copies:=1, ActivePrinter:="PDFCreator"
 
    'Fichier dans la file d'attente
    Do Until JobPDF.cCountOfPrintjobs = 1
        DoEvents
    Loop
    JobPDF.cPrinterStop = False
 
    'Attendre que la file d'attente soit vide
    Do Until JobPDF.cCountOfPrintjobs = 0
        DoEvents
    Loop
    JobPDF.cClose
    Set JobPDF = Nothing
End Sub

Naturellement à adapter à ton contexte

[dlight]

Merci à vous KiKi29. C'est tout simplement parfait.

Sans votre aide, je n'aurais jamais réussi.


Dlight