Discussion :

[gerarddurand]

Bonjour,

(Je n'ai rien trouvé de plus percutant pour mon intitulé.)

Pour faire une copie de ma base j'ai le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim fs As Object
Set fs = CreateObject("Scripting.FileSystemObject")
fs.copyfile "c:\users\le dauphin bleu\documents\hotel1.accdb", Clef & ":\"

Pendant la copie je voulais faire clignoter une étiquette qui indique "Patientez ". Tout fonctionne bien jusqu'au départ de la copie. Là mon étiquette arrête de clignoter. Elle recommence quand la copie est terminée.

Quelqu'un pourrait me dire pourquoi et surtout m'expliquer comment faire.

Une autre question , si vous voulez bien.

A la place de l'étiquette, j'aimerais faire une barre de progression. J'ai trouvé un tuto mais je ne l'ai pas compris.

A votre bon coeur.

Merci

[RobiPMS]

Bonjour.

Concernant ta question sur la barre de progression, peut-être trouveras-tu une piste dans cette discussion : http://www.developpez.net/forums/d11...sateur-boucle/

Cordialement.
RL

[pc75]

Bonjour,

Je ne pense pas que tu puisses prendre la main sur le programme pendant la copie.

Pourquoi tu n'affiches pas un gif animé ? L'effet serait le même non ?

[gerarddurand]

Bonsoir,

de RobiPMS:

Concernant ta question sur la barre de progression, peut-être trouveras-tu une piste dans cette discussion : http://www.developpez.net/forums/d11...sateur-boucle/

En effet j'ai pu faire une barre de progression mais cela n'arrange pas mon problème car le cycle stoppe quand la sauvegarde s'effectue. Je m'en passerai.

En tout cas j'ai appris quelque chose.

Merci à toi et à PC75

Cordialemant

[LedZeppII]

Bonsoir,

J'ai essayé quelque chose et ça à l'air de fonctionner.
J'ai un formulaire sur lequel je mets un bouton et une barre de progression (contrôle activeX Microsoft ProgressBar Control, version 6.0)
Le bouton s'appelle cmdCopier.
La barre de progression s'appelle axProgressBarCopie.

Voici le code de l'événement "Sur clic" du bouton :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Private Sub cmdCopier_Click()
Dim sSource As String, sDest As String
Dim flSce As Integer, flDest As Integer
Const C_BUFFSIZE = 4000&
Dim bytBuffer() As Byte
Dim lFilePos As Long, lFilePosMax As Long
Dim oPgBar As MSComctlLib.ProgressBar
 
' Fichier Source
sSource = CurrentProject.FullName
' Fichier Destination
sDest = Environ("TEMP") & "\" & CurrentProject.Name
 
' Ouverture du fichier source
flSce = FreeFile()
Open sSource For Binary Access Read Shared As flSce
' Taille du fichier source
lFilePosMax = LOF(flSce)
' Initialiser la taille du tableau d'octets
ReDim bytBuffer(1 To C_BUFFSIZE)
' Initialisation barre de progression (MSComctlLib.ProgressBar)
Set oPgBar = Me.axProgressBarCopie.Object
oPgBar.Max = lFilePosMax
oPgBar.Min = 0
oPgBar.Value = 0
 
' Ouverture fichier destination. Au préalable, on le supprime s'il existe.
If Len(Dir(sDest, vbNormal)) > 0 Then Kill sDest
flDest = FreeFile()
Open sDest For Binary Access Write As flDest
 
' Boucle pour copier le fichier par blocs de C_BUFFSIZE octets
Do
   ' Lire dans fichier source
   Get #flSce, , bytBuffer
   ' Position dans le fichier
   lFilePos = Loc(flSce)
   ' Si elle dépasse la Position max (au dela de la fin de fichier)
   ' on ajuste la taille du tableau d'octets
   If lFilePos > lFilePosMax Then
      ReDim Preserve bytBuffer(1 To C_BUFFSIZE + lFilePosMax - lFilePos)
   End If
   ' Ecrire dans fichier destination
   Put #flDest, , bytBuffer
   ' Mettre à jour barre de progression
   If lFilePos <= lFilePosMax Then oPgBar.Value = lFilePos
   '
   DoEvents
Loop Until (lFilePos >= lFilePosMax)
 
' Fermer les fichiers
Close flDest
Close flSce
 
End Sub

Le code copie la bdd en cours dans le dossier des fichiers temporaires.
Le principe est d'effectuer une copie du fichier en VBA par bloc de 4000 octets.
Après la copie de chaque bloc, on met à jour la barre de progression.

A+

[marot_r]

Peut-être en utilisant le OnTimer et mettant la fonction qui fait clignoter dans cet événement.

Avec une féquence de 1s, si ça marche, tu aurais une sorte de multitasking du pauvre et sans passer par une copie binaire du fichier comme l'a suggéré LedZeppII .

A+