Discussion :

[Cece06]

Bonjour !

Voici mon problème :

J'ai un dossier contenant plein de fichiers Excel qui contiennent tous plusieurs feuilles.

Il faut que je rajoute une colonne dans chacune des feuilles des fichiers (la colonne A). Puis que dans cette colonne, je rajoute sur chaque ligne le titre du fichier.

Voila ce que j'ai commencé à faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub rajouter_colonne()
 
Dim num_opti As Variant
Dim sh As Variant
 
num_opti = Dir("C:\Users\cboureau\Desktop\Test\" & "*.xlsx")
 
Do While Len(num_opti) > 0
 
    For Each sh In num_opti
 
        Do Until Cells(i + 1, 2).Value = ""
                 Cells(i + 1, 1).Value = num_opti
        Loop
 
    Next sh
 
num_opti = Dir
Loop
 
End Sub

Il me manque juste l'insertion de la colonne et je ne suis absolument pas sur pour le For Each...

Je vous remercie.

[ZebreLoup]

Quand tu dis sur chaque ligne, tu veux peut-être t'arrêter à une zone où il y aurait des données non ?
(Et ton code ne fait pas du tout ce que tu veux, en plus du fait que tu mélanges un peu For Each... et For i = 1 To...)
Et n'oublie pas d'utiliser la balise # pour que l'on identifie ton code comme tel dans ton message.

[Cece06]

Quand je dis sur chaque lignes c'est qu'il faut que ça s'arrete lorsque les cases sont vides dans la feuille. C'est pour ça que j'ai fait le # Do Until....#

Mais je sais, j'ai un peu de mal avec les For Each...

[ZebreLoup]

Essaie de comprendre ce code et adapte le :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Option Explicit
 
Public Sub RajouterColonne()
 
    Dim nomFichier As String
    Dim wb As Workbook
    Dim ws As Worksheet
    Dim i As Integer
 
    'On recherche le premier fichier xlsx
    nomFichier = Dir("C:\Users\cboureau\Desktop\Test\*.xlsx")
 
    Do While nomFichier <> "" 'Pour tous les fichiers
 
        Set wb = Workbooks.Open(nomFichier) 'On ouvre le classeur
 
        For Each ws In wb.Worksheets 'Pour chacune des feuilles
 
            ws.Columns("A:A").Insert Shift:=xlToRight
 
            i = 1
            Do While ws.Cells(i, "B").Value <> "" 'Tant que la colonne B n'est pas vide
                ws.Cells(i, "A").Value = wb.Name 'Ou nomFichier si tu veux le chemin complet
                i = i + 1 'Ligne suivante
            Loop
 
        Next ws
 
        wb.Save 'On sauve le classeur
        wb.Close 'On le ferme
 
        nomFichier = Dir 'Fichier xlsx suivant
 
    Loop
 
End Sub

[Cece06]

J'ai un problème sur le :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set wb =  workbooks.open(nomFichier)

J'ai rajouté un Application. mais ça ne fonctionne pas quand même, j'ai une erreur 1004. Tu penses savoir d'où ça vient ?

[Edit]
C'est bon, il faut concatener nomFichier avec le chemin du fichier

[ZebreLoup]

Oui, pardon, j'étais parti du principe qu'il te donnait le chemin complet, erreur de ma part. J'utilise rarement DIR, d'habitude je travaille plutôt avec les fonctions du FileSystemObject.
Du coup utilise nomFichier plutôt que wb.Name

[nchal]

Salut,

juste pour info, soit tu mets les balises [CODE] et [./CODE] (sans le point) autour de ton code, soit tu clique sur #, un bouton pour mettre automatiquement les balises