Discussion :

[Daniel.C]

Bonjour,

Je bute sur ce problème : Dans le champ de filtre, j'ai plusieurs items sélectionnés. Je peux afficher ou cacher l'item "(Vide)"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Sheets("Feuil2").PivotTables(1).PivotFields("Noms")
    .PivotItems("(blank)").Visible = True
End With

Je ne peux pas tester cette propriété. Le test retourne une erreur 2042 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Sheets("Feuil2").PivotTables(1).PivotFields("Noms")
    Debug.Print .PivotItems("(blank)").Visible
End With

C'est d'autant plus bizarre que, dans la fenêtre des variables locales, si on examine l'objet, on voit que la propriété "Visible" est correctement renseignée.
On trouve beaucoup de problèmes apparentés sur internet, mais pas de solution, apparemment.

Merci d'avance.

[Philippe Tulliez]

Bonjour Daniel,
C'est effectivement un phénomène très curieux et quand on veut inverser l'état de la propriété Visible on obtient une erreur 13 - incompatibité de type dès que l'on arrive en fin de boucle (Item '(blank)' ).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub testTcd()
 Dim pvt As PivotTable: Set pvt = ActiveSheet.PivotTables("myTcd")
 Dim pvtFld As PivotField: Set pvtFld = pvt.PivotFields("VOITURE")
 Dim c As Byte
 For c = 1 To pvtFld.PivotItems.Count
  If pvtFld.PivotItems(c).Name = "(blank)" Then
    pvtFld.PivotItems(c).Visible = True
   Else
    pvtFld.PivotItems(c).Visible = False
  End If
 Next
 For c = 1 To pvtFld.PivotItems.Count
  pvtFld.PivotItems(c).Visible = Not pvtFld.PivotItems(c).Visible
 Next
End Sub

Pour pallier ce problème

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
  On Error Resume Next
  pvtFld.PivotItems(c).Visible = Not pvtFld.PivotItems(c).Visible
  If Err Then pvtFld.PivotItems(c).Visible = False
  On Error GoTo 0

Mais c'est fou

[Daniel.C]

Bonjour Philippe,

Je n'ai pas très bien compris ton code; quand le nom de l'item est "(blank)", la ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

pvtFld.PivotItems(c).Visible = Not pvtFld.PivotItems(c).Visible

renvoie une erreur. Donc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Err Then pvtFld.PivotItems(c).Visible = False

La propriété Visible est toujours mise à "faux". Ou j'ai mal compris ?

[Philippe Tulliez]

Bonjour Daniel,

La propriété Visible est toujours mise à "faux". Ou j'ai mal compris ?

Oui tu a parfaitement compris, dans ce code test, la première partie met la propriété Visible à True de l'Item (Blank) et tous les autres à False et la seconde partie inverse les valeurs.
Après avoir constaté comme toi l'erreur 2202 avec le Debug.Print, j'ai voulu voir ce qui se passait avec un test conditionnel.

[Daniel.C]

Ouf, j'ai fait le tour. Ca ne résoud pas mon problème qui est d'inverser la valeur (si visible, alors, masquée et réciproquement). J'admets que c'est assez tordu comme question.

[Philippe Tulliez]

Bonjour Daniel,

Ouf, j'ai fait le tour. Ca ne résoud pas mon problème qui est d'inverser la valeur (si visible, alors, masquée et réciproquement). J'admets que c'est assez tordu comme question.

Au contraire ta question est des plus pertinentes. Je trouve plutôt tordue la manière dont le code réagit.

[NVCfrm]

Bonsoir Daniel,

c'est embêtant les modes d'accès à certaines propriétés en vba.
On s'y perd. ce qui m'a inspiré c'est qu'avec les Shapes il y a des fois où il vaut mieux ne pas indexer mais indiquer le nom.

ce bloc ne fait pas d'erreur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With ActiveSheet.PivotTables("TableauCroiséDynamique2").PivotFields("Produit")
        .PivotItems("(blank)").Visible = True
End With

[78chris]

Bonjour

Il semblerait que cela vienne d'un problème de localisation : blank et vide.

J'ai tenté un contournement qui semble résoudre
Nom du champ à adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
    With ActiveSheet.PivotTables("Tableau croisé dynamique1").PivotFields("Mois")
 
        For i = 1 To .PivotItems.Count
            If .PivotItems(i) = "(blank)" Then
                .PivotItems(i).Value = "vide"
                x = .PivotItems(i).Visible
                If x = True Then
                    .PivotItems(i).Visible = False
                Else
                    .PivotItems(i).Visible = True
                End If
                .PivotItems(i).Value = "(vide)"
            End If
        Next i
    End With

[Daniel.C]

Merci 78Chris, c'est le bon contournement. Bizarre quand même, puisqu'en utilisant l'index, on n'utilise pas le nom et qu'on a accès aux autres propriétés. Je pense en se moment au pauvre gars qui a posé un problème similaire (sur internet, sans réponse) avec, en plus, des utilisateurs francophones et néerlandophones...

[ESVBA]

Daniel.C tu poses la question à laquelle personne ne veut me répondre depuis quelques jours. Merci.

Mon but est d'afficher les filtres cochés dans un TCD. Eh oui, ils n'apparaissent pas : on le droit à "(plusieurs éléments)" ou a "(tous)" (moins génant).

J'essaye la méthode de 78chris.

ESVBA

[Daniel.C]

Bonjour à tous.

Le problème semble bien lié aux paramètres locaux de Windows. Il y a un problème analogue avec les dates. Les valeurs renvoient également une erreur 2042 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    With ActiveSheet.PivotTables(1).PivotFields("Dates")
        For Each Pi In .PivotItems
            Debug.Print Pi.Name
            Debug.Print Pi.Visible
        Next Pi
    End With

En adaptant la méthode "78Chris", le problème disparaît :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
    With ActiveSheet.PivotTables(1).PivotFields("Dates")
        For Each Pi In .PivotItems
            Pi.Name = Format(Pi.Name, "m/d/yyyy")
            Debug.Print Pi.Name
            Debug.Print Pi.Visible
        Next Pi
    End With

[78chris]

Bonjour

La localisation laisse de plus en plus à désirer...

Merci Daniel de cette info pour les dates.

[78chris]

Bonjour

En synthétisant les deux exemples on pourrait faire une fonction testant l'état d'un item valable pour tous les cas (s'il n'y a pas d'autre loup )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Function EtatChamp(TCDOnglet As String, TCDNom As String, TCDChamp As String, Position As Long) As Boolean
 
    With Worksheets(TCDOnglet).PivotTables(TCDNom).PivotFields(TCDChamp)
 
        If .PivotItems(Position) = "(blank)" Then
            .PivotItems(Position).Value = "vide"
            EtatChamp = .PivotItems(Position).Visible
            .PivotItems(Position).Value = "(vide)"
        ElseIf IsDate(.PivotItems(Position)) Then
            Dim Valini As Date
            Valini = .PivotItems(Position).Name
            .PivotItems(Position).Name = Format(.PivotItems(Position).Name, "m/d/yyyy")
            EtatChamp = .PivotItems(Position).Visible
            .PivotItems(Position).Name = Valini
        Else
            EtatChamp = .PivotItems(Position).Visible
        End If
 
    End With
 
End Function

Fonction appelable depuis une procédure mais non depuis une cellule.

[Daniel.C]

De plus en plus étonnant; il suffit de mettre dans la valeur initiale (s'il n'y a pas un loup ) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Function EtatChamp2(TCDOnglet As String, TCDNom As String, TCDChamp As String, Position As Long) As Boolean
 
    With Worksheets(TCDOnglet).PivotTables(TCDNom).PivotFields(TCDChamp)
        .PivotItems(Position).Value = .PivotItems(Position).Value
        EtatChamp2 = .PivotItems(Position).Visible
    End With
 
End Function

[78chris]

Bonjour

Sur 2010 cela marche pour le vide mais pas pour les dates : quid de ton côté ?

[Daniel.C]

Effectivement, ça ne fonctionne pas avec Excel 2010 (j'avais testé avec 2013); mais :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.PivotItems(Position).Name = .PivotItems(Position).Name

fonctionne ! Au fou !

[78chris]

Bonjour

Suite du feuilleton : d'après mes tests sur 2010 ni l'un, ni l'autre ne marche pour les dates et Name sur (vide) laisse (blank).

A l'occasion je regarde sur 2013 avec mon exemple...

J'en reste à 2 cas : date ou pas date. Value marchant pour (vide) et toute valeur non date semble-t-il.

[Daniel.C]

Je viens de vérifier pour plus de sûreté. Je confirme.

Name sur (vide) laisse (blank)

Oui mais le test fonctionne. Il est possible, comme j'ai les 2 versions sur le même ordi, que l'installation de 2013 ait modifié quelque chose dans Excel 2010.