Discussion :

[ouskel'n'or]

La question étant récurrente, je propose deux méthodes
1 - Copier toutes les feuilles de classeur1 dans classeur2 à l'exception de certaines feuilles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub CopieDeCertainesFeuilles()
Dim CL1 As Workbook
Dim CL2 As Workbook
Dim LaFeuille as worksheet
Dim i As Byte, ListeANePasCopier '(as variant)
Dim ko As Boolean
    Set CL1 = Workbooks("Classeur1.xls")
    Set CL2 = Workbooks("Classeur2.xls")
    ListeANePasCopier = Array("Feuil1", "Feuil6", "Feuil9")
    For Each LaFeuille In CL1.Worksheets
        For i = 0 To UBound(ListeANePasCopier)
            ko = ko Or LaFeuille.Name = ListeANePasCopier(i)
        Next
        If Not ko Then LaFeuille.Copy After:=CL2.Worksheets(CL2.Worksheets.Count)
        ko = False
    Next
    Set CL1 = Nothing
    Set CL2 = Nothing
End Sub

2 - Ne copier que certaines feuilles de classeur1 dans classeur2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub CopieDeFeuillesChoisies()
Dim CL1 As Workbook
Dim CL2 As Workbook
Dim LaFeuille As Worksheet
Dim i As Byte, ListeACopier '(as variant)
Dim Ok As Boolean
    Set CL1 = Workbooks("Classeur1.xls")
    Set CL2 = Workbooks("Classeur2.xls")
    ListeACopier = Array("Feuil1", "Feuil3", "Feuil7")
    For Each LaFeuille In CL1.Worksheets
        For i = 0 To UBound(ListeACopier)
            Ok = Ok Or LaFeuille.Name = ListeACopier(i)
        Next
        If Ok Then LaFeuille.Copy After:=CL2.Worksheets(CL2.Worksheets.Count)
        Ok = False
    Next
    Set CL1 = Nothing
    Set CL2 = Nothing
End Sub

Si une méthode plus simple fait la même chose... merci de la proposer.

[tirex28]

bonjour,

http://www.developpez.net/forums/sho...d.php?t=362927

Permet d'integrer un critere de sélection des feuilles plutot que de les coder en "dur".

Le move peut-etre remplacé par copy, mais aussi par printout ou delete par exemple.

Cordialement,

Tirex28/

[ouskel'n'or]

J'ai regardé le code que tu indiques.
Il s'agit en effet d'un autre cas de figure avec lecture d'un critère lu dans une feuille de calculs.
On peut également avoir les noms des feuilles à copier/ne pas copier dans une colonne ou demander à l'utilisateur de les sélectionner dans une liste...
On pourrait aussi, plutôt que de "coder les noms en dur" coder les N° de feuilles... "en dur" et utiliser Sheets(i)...
Mais on peut de même passer les noms en revue et poser la question à l'utilisateur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    For Each LaFeuille In CL1.Worksheets
       if Msgbox("Copier la feuille " & LaFeuille.Name, vbYesNo) = vbyes then _
            LaFeuille.Copy After:=CL2.Worksheets(CL2.Worksheets.Count)
    Next

[ouskel'n'or]

On pourrait également simplifier le code et éviter une boucle.
Quelque soit la méthode pour créer le tableau des feuilles, on peut utiliser Join et instr

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    ListeANePasCopier = Array("Rien","Feuil1", "Feuil6", "Feuil9","Rien")
    LaListe = Join(ListeANePasCopier, ";")
    For Each LaFeuille In CL1.Worksheets
         if instr(lcase(LaListe), ";" & lcase(LaFeuille.Name) & ";")= 0 then _
             LaFeuille.Copy After:=CL2.Worksheets(CL2.Worksheets.Count)
    Next

où "Rien" permet d'avoir tous les noms encadrés de ";" afin d'éviter les confusions dans les noms de feuilles. Ex : Feuil1, Feuil10, Feuil11...