Discussion :

[bosk1000]

Bonsoir a tous

je ne sais pas si je poste au bonne endroit

voila j'ai un dossier avec 29 fichiers excel. Ces fichiers portent tous à la fin "09"
(exemple caisse09, banque09, etc... pour l'année 2009)

et plutot que de renommer à la main c'est 29 fichiers en 10 à la place de 09, je voudrais savoir s'il est possible par un code de les renomer en une fois

merci pour votre aide

[androginius]

Bonsoir!

Je viens juste de poster un code pour un cas similaire. Va voir là et adapte le code au nom de fichier que tu veux donner.

http://www.developpez.net/forums/d85...mmer-fichiers/

Bonne soirée

[bosk1000]

merci de m'aider

mais je n'arrive pas a l'adapter ne comprenant pas le processus
voila ce que je fait, mais je suis complètement out

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Private Sub renommer()
 
    Dim nom As String, lettre As String
    Dim fs, dossier, fichiers, f
    Dim j As Integer
 
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set dossier = fs.getfolder(Range("A1"))
    Set fichiers = dossier.Files
 
    For Each f In fichiers
        nom = "10"
        For j = 1 To Len(f.Name)
            lettre = Mid(f.Name, j, 1)
            If lettre <> "09" Then
                nom = lettre & nom
            End If
        Next j
        f.Name = nom
    Next f
 
End Sub

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub renommer()
 
    Dim nom As String
    Dim fs, dossier, fichiers, f
 
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set dossier = fs.getfolder("C:\Docs")
    Set fichiers = dossier.Files
 
    For Each f In fichiers
       nom=left(f.name,instrrv(f.name,".")-2) &"10" &mid(f.name,instrrv(f.name,".")
        f.Name = nom
    Next f  
End Sub

[aalex_38]

Bonjour à tous,

une autre façon de faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
Sub Renommer_annee_Forum()
Dim Dossier As String, NewFic As String, Fich As String
Dossier = "x:\xxx\yyy\zzz\" 'on renseigne le chemin
If Right(Dossier, 1) <> "\" Then Dossier = Dossier & "\" ' on ajoute si besoin le slash en fin de chemin
ChDrive Dossier: ChDir Dossier ' on précise le chemin sur lequel on va appliquer la commande dir
 
Fich = Dir("*09*") ' on liste les fichiers qui contiennent 9
While Fich <> "" ' Tant qu'on trouve un fichier qui correspond on boucle
    NewFic = Replace(Fich, "09", "10") ' on remplace dans la variable les 09 contenus dans les nos du fichier par 10
    Name Dossier & Fich As Dossier & NewFic ' cette commande name permet de renommer le fichier
    Fich = Dir() ' on continue de lister les fichiers (prend toujours le critère du premier dir
Wend ' fin de la boucle
 
End Sub

Edit : En passant par une fonction :
- L'appel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Sub Test_rename()
MsgBox " J'ai renommé " & Renommer("D:\xxx", "10", "9") & " Fichier(s) en remplacant 09 par 10 !", vbInformation + vbOKOnly + vbMsgBoxRight, "Renommer des fichiers"
End Sub

- La fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Function Renommer(ByVal Dossier As String, ByVal oldS As String, newS As String) As Long
Dim NewFic As String, Fich As String
If Right(Dossier, 1) <> "\" Then Dossier = Dossier & "\"
ChDrive Dossier: ChDir Dossier
 
Fich = Dir("*" & oldS & "*")
While Fich <> ""
    NewFic = Replace(Fich, oldS, newS)
    Name Dossier & Fich As Dossier & NewFic
    Renommer = Renommer + 1
    Fich = Dir()
Wend
End Function

[bosk1000]

merci
j'attaque les test

mercatog,
l'instruction instrrv pose un souci

erreur de compilation
sub ou fonction mal définie


aalex_38

j'ai adapter ton code, ça fonctionne du tonnere


par contre, je n'ai pas l'habitude de ce type de commande, et je suis vraiment perdus sur la comprehension

merci beaucoup

[mercatog]

oups!
il fallait lire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

nom = Left(f.Name, InStrRev(f.Name, ".") - 2) & "10" & Mid(f.Name, InStrRev(f.Name, "."))

[aalex_38]

par contre, je n'ai pas l'habitude de ce type de commande, et je suis vraiment perdus sur la comprehension

Dis mois le code qui te pose problème en attendant je vais essayer de commenter le code.

[bosk1000]

très bonne explication merci

[androginius]

Bonojur le Forum, bonjour tout le monde!

Bosk1000:
Désolé de ne pas t'avoir donné plus d'explications, je ne pensais pas que tu aurais de gros problèmes à adapter le code.

Aalex:
Merci pour la deuxième méthode proposée. Il me vient une question:
L'utilisation de Dir à la place des objects filsesystemobjet et autres a-t-elle un avantage? As-tu rencontré des situations pour lequelles il vaut mieux utiliser une méthode ou l'autre?

merci et bonne journée à toutes et tous.

[aalex_38]

L'utilisation de Dir à la place des objects filsesystemobjet et autres a-t-elle un avantage? As-tu rencontré des situations pour lequelles il vaut mieux utiliser une méthode ou l'autre?

Je n'utilise pas pour l'instant "Scripting.FileSystemObject" alors j'aurai du mal a comparer, toutes les méthodes se valent.

L'avantage de Dir est que l'on peut selectionner directement ce que l'on veut par exemple *.jpg si on veut toutes les images.

Dans le code que j'ai fourni la fonction replace est egalement interessante car elle remplace toutes les occurences cherchées dans le nom.