Discussion :

[enicnath]

Bonjour,
Le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
%macro ESSAI;
   %let MOT=;
   %do i=1 %to 19;
      %if &i < 10 %then %let j=&i; %else %let j=%substr(&i,2,1);
      %let MOT=&MOT.&j;
      %if &MOT ne %then %put &MOT;
   %end;
%mend ESSAI;
%essai;

Donne comme résultat :

1
12
123
1234
12345
123456
1234567
12345678
123456789
1234567890
12345678901
123456789012
1234567890123
12345678901234
123456789012345
1234567890123456
12345678901234567
123456789012345678
1234567890123456789

Si on incrémente i au-delà de 19, on obtient une erreur :

ERREUR: Dépassement ; évaluation stoppée.
ERREUR: L'exécution de la macro ESSAI va s'arrêter

C'est au moment de l'exécution du test sur la variable MOT que le problème se pose.

Quelqu'un saurait-il comment procéder pour dépasser cette limite ?

[sasadm]

Essaie cette écriture :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
 %IF ^%sysevalf(%superq(MOT)=,boolean) ne %then %put &MOT;

J'utilise cette macro pour tester si un paramètre macro est vide :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
%macro Blanc(param);
   %sysevalf(%superq(param)=,boolean)
%mend;

C'est le moyen le plus sûr car param peut contenir des parenthèses ou d'autres caractères interprétés normalement comme du code SAS ou macro.

source: Paper 022-2009
IS THIS MACRO PARAMETER BLANK?
Chang Y. Chung, Princeton University, Princeton, NJ
John King, Ouachita Clinical Data Services, Mount Ida, AR

[olivier.decourt]

Comme le souligne SASADM, le souci ne vient que de la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

%IF &MOT ne %then ...

Il faut savoir que %IF est une instruction assez "spéciale". Quand on lui envoie une condition, elle cherche à lui trouver une valeur logique en s'aidant des fonctions d'évaluation comme %EVAL et %SYSEVALF, celles qui transforment les chaînes de caractères qu'on trouve dans les macro-variables en nombres. Quand le compilateur macro voit arriver ta condition

12345678901234567890 NE

(c'est la valeur de &mot quand ça plante), il prend peur car il croit qu'on veut lui demander si cette valeur est supérieure ou inférieure à une autre. Or cette valeur est un NOMBRE que SAS ne peut pas manipuler car il est trop gros.
En revanche, la chaîne de caractères, elle, ne pose aucun souci, et il faut donc rédiger le %IF autrement.
La proposition de SASADM est bonne, mais elle risque d'effrayer le commun des codeurs. Je te propose une alternative toute bête qui fonctionne dans de nombreux cas (pas tous) et ici aussi : si la longueur de &mot est supérieure à 1 (il y a au moins 1 caractère non vide dans &mot).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
%macro ESSAI (max) ;
   %let MOT=;
   %do i=1 %TO &max;
      %IF &i < 10 %then %let j=&i; %else %let j=%substr(&i,2,1);
      %let MOT=&MOT.&j;
      %IF %LENGTH(&MOT)>0 %then %put &MOT;
   %end;
%mend ESSAI;
%essai (50) ;

Bon courage.
Olivier

[enicnath]

Merci SASADM et Olivier, ça résoud tout à fait mon problème !
par contre Olivier, tu dis que ta solution ne fonctionne pas dans tous les cas. Pourrais-tu me préciser, sauf le cas où MOT est vide, dans quels autres cas elle ne fonctionne pas et pourquoi ?

[sasadm]

Dans ton cas ça fonctionnera toujours car tu manipules des chiffres et donc des caractères qui ne seront pas confondus par le compilateur SAS avec des éléments du langage macro.

La technique du length atteint ses limites quand il s'agit de tester la valeur d'un paramètres dont tu ne maitrises pas la forme. Dans le traitement de formulaire WEB par exemple où la saisie des champs est laissée libre à l'utilisateur. Là, la valeur du paramètre peut "casser" le code macro comme dans l'exemple ci-dessous :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
%macro ESSAI ( ) ;
   %let MOT=);
	%IF %LENGTH(&MOT)>0 %then %put &MOT;
%mend ESSAI;
 
%essai ( ) ;
 
 
%macro ESSAI2 ( ) ;
    %let MOT=);
	%IF ^%sysevalf(%superq(MOT)=,BOOLEAN) ne %then %put &MOT;
%mend ESSAI2;
 
%essai2 ( ) ;

[enicnath]

Merci !