Gros souci de marging pour un form d'impression

**Attila54** · 21/02/2012, 11h52

Bonjour,
J'ai un souci de marging dans mon appli avec laquelle je genere, en fin de calcul, un formulaire d'impression contenant divers paramètres

Pour information voici l'image d'un print type :

vous voyez le souci ..... je voudrais pouvoir imprimer sur la totalité de la page A4 avec un marging normal mais impossible de trouver le réglage adequat.
Du coup, les caracteres sont petits et je ne peux pas entrer tous les parametres désirés.

Je peux toujours changer la dimension du fom, cela ne change rien et ne m'imprime pas ce qui a ete agrandi.

J'ai beau chercher dans le designer, dans le printform lui même, je ne vois aucune possibilité de changer cela.

Voici le code de mon bouton print

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private Sub Imprimer_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Imprimer.Click
        Imprimer.Visible = False
        Image.Visible = False
        Quitter.Visible = False
        Avant.Visible = False
        Arriere.Visible = False
        If printerlist() = String.Empty Then
            If langue = "en" Then
                messageaff = "No printer available on this station"
                infoaff = "Error"
            Else
                messageaff = "Aucune imprimante disponible sur ce poste"
                infoaff = "Erreur"
            End If
            MessageBox.Show(messageaff, infoaff, MessageBoxButtons.OK, MessageBoxIcon.Error)
        Else
            Using p As New ClassImpression()
                Try
                    p.SetDocument(Me)
                    p.Imprimeforme()
 
                Catch ex As Exception
                    If langue = "en" Then
                        messageaff = "Printer Error : end of the impression"
                        infoaff = "Error"
                    Else
                        messageaff = "Erreur imprimante : fin de l'impression"
                        infoaff = "Erreur"
                    End If
                    MessageBox.Show(messageaff, infoaff, MessageBoxButtons.OK, MessageBoxIcon.Error)
                End Try
            End Using
        End If
        If flagnavigate = True Then
            Afficheboutons()
        End If
        Imprimer.Visible = True
        Image.Visible = True
        Quitter.Visible = True
    End Sub

Auriez vous une idée ??

Merci bien

**asmduty** · 21/02/2012, 12h00

Comment fais-tu pour imprimer ?
Peut-on voir le code ?

**Attila54** · 21/02/2012, 12h03

grillé de une minute

aurais je omi de repondre a une question ou manque t"il des éléments ?

Merci

**asmduty** · 22/02/2012, 08h37

Bonjour,

je n'avais pas vu le code ...
Peut-on voir comment se présente la classe "ClassImpression" ?

Merci

**Attila54** · 22/02/2012, 11h14

bonjour asmduty
voici la classimpression()

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
Imports System.Drawing.Printing
Imports System.Runtime.InteropServices
 
Public Class ClassImpression
 
    Inherits PrintDocument
 
    Public Sub SetDocument(ByVal feuille As Control)
 
        Const SRCCOPY As Integer = &HCC0020 ' pour copier la source
        Dim controlGraphics As Graphics = feuille.CreateGraphics   ' graphique de la feuille à imprimer
        Dim controlSize As Size = feuille.ClientSize ' taille de la forme à copier
        Buffer = New Bitmap(controlSize.Width + 204, controlSize.Height + 312) ' buffer contenant la feuille à copier 
        Dim bufferGraphics As Graphics = Graphics.FromImage(Buffer)
 
        Dim bufferHdc As IntPtr = bufferGraphics.GetHdc   'hdc de la form destinée à l'impression
        Dim controlHdc As IntPtr = controlGraphics.GetHdc
        '*** DESSINE LE FORMULAIRE DANS LA PICTURE EN LE CENTRANT
        NativeMethods.StretchBlt(bufferHdc, 102, 156, controlSize.Width, controlSize.Height, controlHdc, 0, 0, controlSize.Width, controlSize.Height, SRCCOPY)
        bufferGraphics.ReleaseHdc(bufferHdc)
        controlGraphics.ReleaseHdc(controlHdc)
 
    End Sub
 
    Public Sub Imprimeforme()
        Using printDialogue As New PrintDialog()
            printDialogue.Document = Me
            If printDialogue.ShowDialog = DialogResult.OK Then
                printDialogue.PrinterSettings.DefaultPageSettings.PaperSize = printDialogue.PrinterSettings.PaperSizes.Item(6)    'dimensions pour A4
                Me.Print()
            End If
        End Using
    End Sub
 
    Protected Overrides Sub OnPrintPage(ByVal e As System.Drawing.Printing.PrintPageEventArgs)
 
        e.Graphics.DrawImage(buffer, 0, 0) ' impression proprement dite
        e.HasMorePages = False ' document une seule page
 
    End Sub
 
End Class

merci

**asmduty** · 22/02/2012, 11h40

Voilà un exemple de code que j'utilise dans la methode monPrintDocument.PrintPage :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
  'On récupère l'image à imprimer
        Using MyGr As Graphics = e.Graphics
 
            'On calcule le ratio pour la largeur de l'image
            Dim LargImage As Decimal = memoryImage.Width / memoryImage.HorizontalResolution * 100
            Dim RapX As Decimal = e.MarginBounds.Width / LargImage
            'On calcule le ratio pour la hauteur de l'image
            Dim HautImage As Decimal = memoryImage.Height / memoryImage.VerticalResolution * 100
            Dim RapY As Decimal = e.MarginBounds.Height / HautImage
            'On garde le ratio le plus petit pour redimensionner l'image afin que l'image imprimée ne sois pas coupée
            RapX = IIf(RapX < RapY, RapX, RapY)
            Dim RectSortie As New Rectangle(0, 0, Decimal.Parse(LargImage * RapX), CInt(HautImage * RapX))
            'On définit l'emplacement d'impression de l'image sur la page
            RectSortie.X = e.MarginBounds.X + Decimal.Parse((e.MarginBounds.Width - RectSortie.Width) / 2)
            RectSortie.Y = e.MarginBounds.Y + Decimal.Parse((e.MarginBounds.Height - RectSortie.Height) / 2)
            'Et on dessine l'image finale qui sera imprimée
            MyGr.DrawImage(memoryImage, RectSortie)
 
        End Using

C'est du code trouvé sur ce forum que j'avais adapté, tu dois aussi pouvoir l'adapter/le retrouver sur le forum

**Attila54** · 22/02/2012, 12h48

merci bien, je regarde comment ca se presente mais j'avoue avoir du mal a m'y retrouver dans mon propre classimpression.

J'etais pourtant persuadé avoir deja reussi a le modifier pour imprimer une page avec des marges de 1cm de chaque cote.

J'ai plusieurs champs a ajouter et je prefererais etendre ma zone d'impression plutot que de mettre hasmorepage a true et imprimer sur 2 pages ...

**MABROUKI** · 23/02/2012, 01h15

bonjour Attila

je te suggere d'utiliser ce code gdi+ .nettement plus simple pour imprimer un control meme avec scrollbar....

exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
 
 
 
'- ajoute pour tester l'exemple:
'- un Panel  sur le WinForm 
'- PrintDocument
'- PrintPreviewDialog
'- un bouton ApercuImp
Imports System.Drawing.Printing
Public Class Form2
 
    Public Sub New()
 
        ' Cet appel est requis par le Concepteur Windows Form.
        InitializeComponent()
 
        ' Ajoutez une initialisation quelconque après l'appel InitializeComponent().
        ' Un simple control panel que j'ai rempli avec d'autres controls
        ' Dock du panel1 & position à 0,0
        Me.Panel1.Dock = DockStyle.Fill
        Me.Location = New Point(0, 0)
        'Ajuste la taille du form
        Me.WindowState = FormWindowState.Maximized
    End Sub
 
    Private Sub PrintDocument1_PrintPage(ByVal sender As Object, ByVal e As System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
        Dim MyGr As Graphics = e.Graphics
        'Met PageUnit à Display (apercu conforme à sortie printer)
        MyGr.PageUnit = GraphicsUnit.Display
        MyGr.SmoothingMode = Drawing2D.SmoothingMode.AntiAlias
        MyGr.SmoothingMode = Drawing2D.SmoothingMode.HighQuality
 
        'Envoie panel dans un bitmap avec Control.DrawToBitmap
        Dim memoryImagePanel = New Bitmap(Me.Panel1.Bounds.Width, Me.Panel1.Bounds.Height)
        Me.Panel1.DrawToBitmap(memoryImagePanel, Me.Panel1.Bounds)
 
        'code .net managed qui recopie l'image en gardant les proportions 
        'rect source =>memoryImagePanel ou ton form
        Dim RectSource As RectangleF = New Rectangle(0, 0, memoryImagePanel.Width, memoryImagePanel.Height)
        'definit les "marges" diaboliques
        Dim myMargin As Margins = New Margins(40, 40, 40, 40)
        'les assignes à  PrintDocument1
        PrintDocument1.DefaultPageSettings.Margins = myMargin
        'rect destination c'est notre page A4 ou  se trouve le rectangle d'impression e.MarginBounds que nous avons personnalise cette fois.
        Dim RectDest As RectangleF = e.MarginBounds
 
        'surcharge de DrawImage qui recopie l'image en gardant les proportions 
        MyGr.DrawImage(memoryImagePanel, RectDest, RectSource, GraphicsUnit.Pixel)
 
 
    End Sub
    Private Sub btnApercuImp_Click_1(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnApercuImp.Click
        PrintPreviewDialog1.Document = PrintDocument1
        PrintPreviewDialog1.ShowDialog()
    End Sub
 
End Class

bonne soiree.............

**Attila54** · 23/02/2012, 09h15

bonjour asmduty et MABROUKI
Merci beaucoup, j'ai pu resoudre ce probleme grace a vos conseils

par contre comment se fait il que mon formprint soit bloqué en hauteur a 788 ce qui n'est pas le cas de mes autres forms ?
Serait ce du initialement a l'api windows du classimpression ?

**asmduty** · 23/02/2012, 09h52

Bonjour,

merci MABROUKI pour ce complément qui pourrait aussi me servir.
Pour ton formprint bloqué à 768 en hauteur, vérifies que tu n'as pas définit un "maximumwidth"

**Attila54** · 23/02/2012, 10h10

ben dans mes proprietes du form, j'ai maximumsize à 0;0 et en detail with à 0 et height à 0
je pensais a reduire les valeurs dans :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

New Bitmap(controlSize.Width + 204, controlSize.Height + 312)

mais cela ne change rien.

**asmduty** · 23/02/2012, 10h58

Si maximumSize n'est pas définit je ne vois pas d'où pourrait venir ce problème.
Quand tu dis que c'est bloqué à 768, tu veux dire quoi ?
Tu ne peux pas mettre en mode conception 1024 en hauteur ?

**Attila54** · 23/02/2012, 11h08

c'est exactement cela mais c'est 788 que cela bloque
en mode conception:
size initiale du form : 746;768
je veux la mettre a : 850; 850
j'obtiens au final 850;788

**Attila54** · 23/02/2012, 14h20

Alors la ........ j'ai fait un test pour voir

- je fais un nouveau projet avec un form appelé form1 vierge de tout
- je veux redimensionner le form1 qui est a 300*300 par defaut

ma hauteur est automatiquement bloquée a 788 et ma largeur a 1386 quoi que je fasse soit pil poil 20 * 20 au dessus de ma resolution d'ecran 1366*768) msdn dit que la propriete formsize est automatiquement limitée a la resolution max de l'ecran + 12 .... la ca m'embete fortement. Je ne vais quand même pas changer d'ecran juste pour cela alors que l'appli est utilisée sur un moniteur a resolution bien plus elevée ...

**asmduty** · 23/02/2012, 15h28

A mon avis c'est pourtant ta résolution qui pose problème !
Essai de redéfinir la taille de la fenêtre dans le code au form_load.

**Attila54** · 23/02/2012, 15h29

bon, probleme regle en changeant de moniteur ...... la je me sens un peu comment dire ..... dans un grand moment de solitude ......

Merci a tous pour l'aide

**Attila54** · 23/02/2012, 15h32

j'ai essaye asmduty, mais même en mettant une new size dans le form load, il me garde par defaut la valeur max de ma resolution d'ecran + 20 pixels.

Je n'avais jamais eu jusqu'alors un formprint dont la heiteur depassait 768 d'ou mon inatention

**asmduty** · 23/02/2012, 15h47

Cela dit ce problème est interessant, selon l'utilisation de ton application, peut-être que des utilisateurs pourraient être dans le même cas !
Il faudrait peut être prévoir une solution donc, l'idéal étant de gérer la conception et le palcement des contrôle avec des pourcentages. (Table Layout Panel)

**Attila54** · 23/02/2012, 16h13

je me suis dit aussi que cela pouvait poser probleme dans le cas de certains utilisateurs. Je ne savais pas comment aborder la chose .... tu viens de me le dire ....
Merci bien

**ahmed_kh** · 29/04/2012, 15h33

salut tout le monde.
j'ai copié le code de MABROUK,mais j'ai un problème que l'apperçue est vide .voila le capture écran.merciiiiii

Gros souci de marging pour un form d'impression [Débutant]

VB.NET

Discussions similaires

Partager

Partager