Discussion :

[TURBODIESEL]

Bonjour,
Je suis confronté au problème suivant :
- Une base de données d'adresses (par exemple 500 lignes)
- Une liste d'une dizaine de nom de rue

Comment appliquer un fond de couleur à toutes les adresses contenant l'un des noms de rue de la liste.

Voir exemple dans le classeur joint.

Merci pour votre aide
Thierry

[Zekraoui_Jakani]

Avez-vous essayé le format conditionnel (voir ruban) ?

[TURBODIESEL]

Oui, mais cette mise en forme conditionnelle nécessite à mon avis de passer par une formule (peut-être matricielle) mais je ne trouve pas l'astuce.

[Menhir]

Avec une mise en forme conditionnelle utilisant formule qui combine les fonction SIERREUR() et CHERCHE().

[excfl]

Bonjour le forum,

Présenter la liste des rues comme suit :


MFC :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=OU(NB.SI($E1;$A$2)=1;NB.SI($E1;$A$3)=1;NB.SI($E1;$A$4)=1;NB.SI($E1;$A$5)=1;NB.SI($E1;$A$6)=1;NB.SI($E1;$A$8)=1)

S'applique à : =$E:$E

[papouclo]

Bonjour,
Autre proposition :
Redéfinir le nom LST_VAL par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(Feuil1!$A$2;;;NBVAL(Feuil1!$A:$A)-1;1)

Sélectionner la plage E2:E77 en gardant E2 comme cellule active et demander une nouvelle règle de MFC.
Choisir : >> Utiliser une formule pour déterminer pour quelles cellules le format sera appliqué
et écrire la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(--ESTNUM(CHERCHE(LST_VAL;E2)))

Choisir le format désiré.
Cordialement
Claude

[TURBODIESEL]

Alors là Monsieur Claude Respect et Chapeau bas !!!
Cela fonctionne à merveille.

Ok pour le nom de zone variable.
Mais je coince un peu sur la matricielle. Quelle est l'utilité du -- en début de sommeprod ?

Merci également à tous les autres contributeurs

Thierry

[papouclo]

Bonjour,
Si la formule proposée est gênante pour la compréhension, on peut la remplacer par la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(1 * ESTNUM(CHERCHE(LST_VAL;E2)))

à valider par Ctrl + Maj + Entrée
cellule désignant une cellule de la plage E2:E8, dans la formule { = SOMMEPROD(--ESTNUM(CHERCHE(LST_VAL;cellule))) } , ESTNUM(CHERCHE(LST_VAL;cellule)) renvoie une matrice de 6 valeurs logiques VRAI ou FAUX .
En fait, si l'on est en E2 , ESTNUM(CHERCHE(LST_VAL;E2)) renvoie la matrice { FAUX ; FAUX ; FAUX ; FAUX ; FAUX ; FAUX }
Si l'on est en E3, ESTNUM(CHERCHE(LST_VAL;E3)) renvoie la matrice { FAUX ; VRAI ; FAUX ; FAUX ; FAUX ; FAUX }
Excel de lui même remplace ces valeurs logiques VRAI - FAUX par les valeurs numériques associées 1 - 0 pour effectuer les calculs demandés dans la formule, à une condition : qu'il y ait d'autres nombres qui interviennent dans la formule.
C'est le cas pour le premier exemple de l'image ci-dessous.

Mais dans le deuxième exemple où l'on demande la somme de cellules ne contenant que des VRAI - FAUX , Excel renvoie une somme égale à 0 qui ne donne pas le nombre de VRAI .
Deux manières d'éviter ce problème :
- Rajouter un nombre en multipliant la matrice par 1 (ligne 3 de l'image)
- Ecrire en début de formule le symbole " -- " (ligne 4 de l'image) qui donne en quelque sorte à Excel l'ordre de convertir toutes les valeurs logiques en valeurs numériques.
Cordialement
Claude

[TURBODIESEL]

Merci Claude pour cette explication très claire.
J'avais expérimenté depuis pour découvrir l'intérêt du --
Habile façon de traduire les valeurs booléennes en numériques pris en compte par les sommes.

Bien vu ! Merci beaucoup pour cet éclairage.
Thierry