Discussion :

[morobaboumar]

Bonsoir membres du forum,
Heureux de vous retrouver!
Comment puis je enregistrer avec du code dans une table des mots à accent aigu ?
Exemple de noms: N'Diaye, N'Fa, N'Kono.

Voici la capture du message d'erreur après clique sur la commende enregistrer:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
Private Sub BtnEnregisterElevesComposants_Click()
Dim stMsg As String
Dim Itm As Variant
Dim oDb As Database
Dim oRS As Recordset
Dim critere As String
Dim Eleve As String
Dim ajouter As Boolean
 
On Error GoTo OUMAR
 
With Me.ListeELEVES_ANNEE_CLASSE
    '' contrôle saisie élèves
    If .ItemsSelected.count = 0 Then Exit Sub
    'contrôle saisie Classe
    If IsNull(Me.lstClasse_Evaluation) Then
        MsgBox "Sélectionnez une classe.", vbCritical
        Me.lstClasse_Evaluation.SetFocus
        'Me.lstClasse_Evaluation.Dropdown  **** Pour dérouler le combobox à l'aide de la méthode DROPDOWN
        SendKeys "{F4}"      '*** Pour dérouler le combobox à l'aide de l'envoi de touche clavier (F4)
        Exit Sub
    End If
 
    Set oDb = CurrentDb
    Set oRS = oDb.OpenRecordset("Tbl_EVALUATION_NIVEAU_SCOLAIRE", dbOpenDynaset)
 
    For Each Itm In .ItemsSelected
        Eleve = .Column(4, Itm)
        oRS.FindFirst "[Nom_Prenoms_EleveComposant] LIKE '*" & Eleve & "*'"
        ajouter = False
 
        If oRS.NoMatch Then
            ajouter = True  'Add the record to the table and
            stMsg = "L'élève " & Eleve & " a été rajouté à la liste, avec succès !"
        Else
            Dim fld As Field
            stMsg = "L'élève " & Eleve & " existe déjà dans la table !" & vbLf    '**********************
            stMsg = stMsg & "avec les données suivantes :" & vbCrLf
            For Each fld In oRS.Fields
                stMsg = stMsg & fld.name & " : " & fld.Value & vbCrLf
            Next fld
            stMsg = "Année scolaire en cours : " & Me.lstAnnee_Evaluation & vbCrLf & vbCrLf & stMsg & vbCrLf & "Voulez-vous le rajouter ?"
            If MsgBox(stMsg, vbQuestion + vbYesNo, "Ajouter un Elève") = vbNo Then
                ajouter = False
            Else
                ajouter = True  'Add the record to the table
            End If
        End If        'stMsg = stMsg & .Column(4, Itm) & vbCrLf
 
        If ajouter = True Then
            With oRS
                .AddNew
                ![NumEnregistreComposant] = f_NumAutoEnregistrementElevesComposants() + 1
                ![Nom_Prenoms_EleveComposant] = Me.ListeELEVES_ANNEE_CLASSE.Column(4, Itm)
                ![COMPOSITION] = Me.ListeComposition_Evaluation
                ![NiveauCompositionFrancais] = Me.ListeNiveauEVALUATION
                ![IdEcole] = Me.ID_ETABL_FREQ
                ![AnneeScol] = Me.ANNEE_SCOL
                ![NumInsCreleve] = Me.ListeELEVES_ANNEE_CLASSE.Column(2, Itm)
                ![Mleeleve] = Me.ListeELEVES_ANNEE_CLASSE.Column(3, Itm)
                .Update
            End With
            MsgBox "Année scolaire en cours : " & Me.lstAnnee_Evaluation & vbCrLf & stMsg, vbInformation + vbOKOnly, "Elève ajouté"
        End If
    Next Itm
 
' enlever la sélection
    .RowSource = .RowSource
 
' affichage des éléments saisis
    Me.Refresh
    Me.ListeELEVES_ANNEE_CLASSE.Requery
    Forms("Frm_EvaluationScolaireElevesECIND").Tbl_EVALUATION_NIVEAU_SCOLAIRE_SFrm.Requery
    ListeELEVES_ANNEE_CLASSE.RowSource = ListeELEVES_ANNEE_CLASSE.RowSource
    End With
Forms!Frm_EvaluationScolaireElevesECIND!CtlTabEVALUATION_COMPOSITION.Pages(1).SetFocus
DoCmd.GoToRecord , , acLast
OUMAR_Exit:
    Exit Sub
 
OUMAR:
    MsgBox err.Description, vbExclamation + vbOKOnly, err.Number
    Resume OUMAR_Exit
End Sub

Cordialement.

[tee_grandbois]

bonsoir,

Comment puis je enregistrer avec du code dans une table des mots à accent aigu ?

ce n'est pas l'accent aigu qui pose problème mais l'apostrophe.
Il faudrait la remplacer par des double guillemets ici (ligne 29):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
'oRS.FindFirst "[Nom_Prenoms_EleveComposant] LIKE '*" & Eleve & "*'"
oRS.FindFirst "[Nom_Prenoms_EleveComposant] LIKE ""*" & Eleve & "*"""

et à tout autre endroit où l'apostrophe est utilisé dans un comparaison du nom

[morobaboumar]

Bonsoir tee_grandbois,
La ligne de code marche.
Merci infiniment.
Cordialement.