Visionneuse sous W98 Erreur d'exécution :8007000e

**Barbu1595** · 15/09/2008, 19h10

Bonjour,
Dans un application VB6 , j'ai une simple visionneuse composée d'une Filelistbox et d'une Textbox dont le code est le suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub File1_Click()
file = "c:\transfert\" + File1.FileName
crlf = Chr$(13) + Chr$(10)
Open file For Input As #1
Line Input #1, texte
lire = texte
Do While Not EOF(1)
  Line Input #1, texte
  lire = lire + crlf + texte
Loop
Me.Text1.Text = lire
Close #1
Label2.Caption = " VISUALISATION DU FICHIER  :  " + File1
Exit Sub
ExitbutOuvrir:
End Sub

Sous XP pas de problème .
Sous W98 :
Lors de la première selection dans la liste de fichiers pas de problème le contenu s'affiche dans dans la Textbox.
Par contre si je sélectionne un deuxième fichier j'ai un blocage du programme avant l'affichage du contenu et le méssage d'erreur d'exécution (mémoire insuffisante) s'affiche.
J'ai fait l'essai en remplaçant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Do While Not EOF(1)
  Line Input #1, texte
  lire = lire + crlf + texte
Loop

Par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
compteur = 0
Do While Compteur < 80
  Line Input #1, texte
  lire = lire + crlf + texte
  compteur = compteur + 1
Loop

Dans ces conditions (nbre de lignes affichées limitées à 80) je n'ai plus d'erreur.
Mes possibilités d'analyses sont limitées sur les PC en W98 car ils n'ont pas VB6 d'installé
Merci de votre aide

**ProgElecT** · 15/09/2008, 22h19

Bienvenue sur DVP
Plusieurs petites choses, dans l'ordre qui me semble le plus important.
Donner arbitrairement un numero pour ouvrire un fichier est toujours aléatoire, il est largement préférable que cela soit Window qui te le donne avec la fonction FreeFile.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
DIm NumFich As Integer
NumFich = FreeFile
Open file For Input As #NumFich
 Line Input #NumFich, texte
'.......

Il est preferable de remplacer tes + par des & quand on additonne

, des mots

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

lire = lire & crlf & texte

tu peux remplacer ton crlf par une constante que te fournis VB, vbCrLf = chr$(13)+Chr$(10), ou bien vbNewLine = Constante pour NewLine (nouvelle ligne); spécifique de la plate-forme.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Label2.Caption = " VISUALISATION DU FICHIER  :  " + File1

File1.Filname je supose

Essais comme cela pour voire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub File1_Click()
Dim NumFich
If File1.ListIndex = -1 Then Exit Sub
file = "c:\transfert\" & File1.List(File1.ListIndex)
NumFich = FreeFile
Open file For Input As #NumFich
Line Input #NumFich, texte
lire = texte
Do While Not EOF(NumFich)
  Line Input #NumFich, texte
  lire = lire & vbNewLine & texte
 'ou 
 'lire = lire & vbCrLf & texte
Loop
Me.Text1.Text = lire
Close #NumFich
Label2.Caption = " VISUALISATION DU FICHIER  :  " & File1.List(File1.ListIndex)
'si il n'y a pas de gestion d'erreur, ces 2 lignes sont inutiles
'Exit Sub
'ExitbutOuvrir:
End Sub

**Barbu1595** · 16/09/2008, 19h30

Merci ProgElecT de ton aide .
J'ai testé ton code .
Maheureusement j'ai toujours le problème.
Je ne vois pas Endif dans ton code c'est mormal ?

**ProgElecT** · 16/09/2008, 20h48

Je ne vois pas Endif dans ton code c'est mormal ?

Le End If n'est pas obligatoire quand il se trouve sur la même ligne,
If ...... Then ....... ELse ........ suffit

Je n'ai plus d'ordinateur avec Win 98 et n'ai jamais eu le type d'erreur que tu signales pour une lecture de fichier, essais cette variante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub File1_Click()
Dim NumFich As Integer
Dim File As String, Texte As String, Lire As String
 
If File1.ListIndex = -1 Then Exit Sub
 
File = File1.Path & "\" & File1.List(File1.ListIndex)
NumFich = FreeFile
Open File For Input As #NumFich
Line Input #NumFich, Texte
Lire = Texte
Do
  Line Input #NumFich, Texte
  Lire = Lire & vbNewLine & Texte
  If EOF(NumFich) Then Exit Do
  DoEvents
Loop
Close #NumFich
Me.Text1.Text = Lire
Label2.Caption = " VISUALISATION DU FICHIER  :  " & File1.List(File1.ListIndex)
End Sub

En relisant l'ensemble des infos que tu nous a données, un essai à faire pour eliminer un doute, ouvre plusieur fois de suite un fichier que tu sais ne pas contenir plus de 80 lignes, avec soit l'avant dernier code proposé ou le dernier.
Tu parles d'un probléme de nombre de ligne, le poids du fichier a ouvrir me semblerai plus juste.

**ucfoutu** · 16/09/2008, 20h54

Envoyé par ProgElecT

Tu parles d'un probléme de nombre de ligne, le poids du fichier a ouvrir me semblerai plus juste.

Bonjour, et un salut à Progelect,

J'y ajouterais bien volontiers : et la structure éventuelle du fichier ...
Car s'il s'agit d'un fichier structuré et dont les "champs" sont de surcroît tous de type String, ===>> bonjour les dégâts possibles avec Line Input

**Barbu1595** · 19/09/2008, 18h07

Bonjour,

J'ai testé le dernier code de ProgElecT toujours la même erreur .

C'est bien un problème de taille de fichier.
Avec des fichiers de :
54 Ko ou inférieur : pas de problème
62 Ko ou supérieur : problème

Remarque:
fichier 54 Ko ouverture possible avec Bloc-note
fichier 62 Ko ouverture possible seulement avec WordPad

La structure des fichiers est succession de lignes du type suivant:

Y.P. Unitesters Ltd. YP-30H A.T.E
Mfr name - xxxxxxxx
Date:09/08/05 Time:15:51:05
Functional List:Mot_AL-Global_V1.rep
Purchase / Job No. :
Part No. :
Serial No. :4007
_________________________________________

Test results:
PASS: Line: 0001 Temp Mon - Resistance test From: 211 To: 212
Required: 110.0 Ohm, Tolerance: 5%,Measured: 112.4 Ohm

PASS: Line: 0015 Cos + (Mon) / Cos - (Mon) - Capacitance test From: 227 To: 226
Required:750.0 µF, Tolerance: 10%,Measured: 777.8 µF
From To Required Measured
-------------------- --------------------- ----------- -----------
007-01--PMP_3 (I) 007-02--PMP_4 (I) <5.000 Ohm 292.8 mOhm
007-01--PMP_3 (I) 007-03--PMP_5 (I) <5.000 Ohm 305.8 mOhm
Chain Required Measured
-------------------- --------------------- -----------
007-01--PMP_3 (I) >100.0 MOhm @ 1000V 1.592 GOhm
007-07--CORPS PMP >100.0 MOhm @ 1000V 1.601 GOhm

Comment contourner cette limite pour les PC fonctionnants sous W98?

**ucfoutu** · 19/09/2008, 18h21

Re,

Ce n'est pas une structure, que tu nous montres là, mais le résultat de l'exploitation !
A l'examen de ce résultat, il se pourrait bien qu'il s'agisse en effet là d'un fichier texte structuré en base de données...
Si tel est vraiment le cas, il faut en connaître la structure (celle qui a par ailleurs servi à l'écrire) !
D'où vient ce fichier ?

**OhMonBato** · 19/09/2008, 18h40

Le controle TextBox étant limité à 64Ko, tu ferais mieux de le remplacer par un controle RichTextBox qui a une capacité bien supérieure et tu pourrais remplacer ton code par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Do
  Line Input #NumFich, Texte
  RichText1.Text = RichText1.Text & vbCrLf & & Texte
  If EOF(NumFich) Then Exit Do
  DoEvents
Loop
Close #NumFich

**ProgElecT** · 19/09/2008, 19h41

Envoyé par Barbu1595 (1° post)

Sous XP pas de problème, Sous W98 ..........

8007000e => Erreur des ressources système dépassé et pas assez de stockage disponible pour terminer cette opération.
Cela expliquerait les dificultés que tu rencontres sous W98, supposant que ces ordinateurs n'ont pas beaucoup de mémoire instalée et que W98 gére encor plus mal la mémoire que ses suivant.
Malheureusement, TextBox ou RichTextBox, j'ai bien peur que cela ne change rien, de plus l'erreur ne survient-elle pas dans le Open du fichier plutôt que l'hors du transfert de ta variable lire

**ucfoutu** · 19/09/2008, 21h51

Bonjour,

Salut à OhmonBato et à Progelect,

J'ai également bien peur qu'il ne s'agisse de tout autre chose...

Si l'on ne devait considérer que la limitation d'une Textbox (par exemple 64 KOi pour XP), je connais au moins deux méthodes (une lente et une très rapide) pour y remédier (on en fait le pari ? Qui veut parier ?... ne pariez pas car VB6 réserve toujours des surprises...

).

Je peux me tromper, mais je pense comme Progelect que le problème se situe peut-être avant même l'insertion dans la Textbox (pas assez de mémoire pour stocker dans la variable...) et est peut-être dû à un Line Input qui pointe vers du "trop grand" (du fait d'un séparateur de fichier structuré ===>> débordement) ou encore parce que la mémoire résiduelle disponible est insuffisante.

Dans le cas d'un fichier structuré : il faudrait le lire autrement que par Line Input, à l'aide de sa structure (Type).
Dans le cas d'une mémoire résiduelle insuffisante, il suffirait d'écrire ligne par ligne directement dans la TextBox pour ne pas rencontrer ce problème de stockage dans une variable (méthode lente) ou encore se lancer dans une astuce (méthode rapide) , mais toujours ligne par ligne et directement dans la textbox.
Une dernière méthode (mais à condition qu'il ne s'agisse que d'un fichier texte "plat" et non structuré en base de données) serait tout bêtement d'ouvrir, à l'intérieur même de la forme (avec SetParent), le bloc-notes et le fichier lu.
Voilà ...
J'attends les éclaircissements nécessaires... la solution exacte suivra alors ...

**ucfoutu** · 19/09/2008, 22h22

Re...

Je décide ici de faire un message à part et non un édit de mon message précédent car le présent message DOIT être parfaitement distinct.
Il illustre ce que je disais dans mon précédent message...
Si on veut le détruire, qu'on le fasse donc ! j'aurais au moins tenté d'exposer une astuce VB6 (on la gardera ou non ===>> ce ne sera pas mon affaire).

Essayez ce petit projet et vous comprendrez (3 boutons de commande).
Attention : la méthode Command1 est TRES TRES LENTE

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Option Explicit
 
Private Sub Command1_Click()
  'méthode lente ... compter plusieurs minutes, hein ...
  Dim i As Long
  Text1.Text = vbNullString  'on part à vide
  For i = 1 To 100000
    Text1.SelText = Format$(i, "00000000") & vbCrLf
  Next
  MsgBox "alors ? on a combien de caractères ? ===>>> " & Len(Text1.Text)
End Sub
 
Private Sub Command2_Click()
  'méthode rapide
  Dim i As Long, coco As Long, base As String
  Text1.Text = vbNullString 'on part à vide
  base = Space$(1000000)  ' pour un million de caractères
  coco = 1
  For i = 1 To 100000
    Mid$(base, coco) = Format$(i, "00000000")
    Mid$(base, coco + 8) = vbCrLf
    coco = coco + 10 ' + 10 car vbcrlf = 2 caractères
  Next
  Text1.SelText = base  'et voilà ! 1000000 de caractères stockes --- vbcrlf = 2 caractères, hein ...)
  MsgBox "alors ? on a combien de caractères ? ===>>> " & Len(Text1.Text)
End Sub
 
Private Sub Command3_Click()
  'méthode qui échouera
  'le début est comme pour command2
  ' mais on commet la maladresse d'attribuer base directement à Text1.Text
  Dim i As Long, coco As Long, base As String
  Text1.Text = vbNullString 'on part à vide
  base = Space$(1000000)  ' pour un million de caractères
  coco = 1
  For i = 1 To 100000
    Mid$(base, coco) = Format$(i, "00000000")
    Mid$(base, coco + 8) = vbCrLf
    coco = coco + 10 ' + 10 car vbcrlf = 2 caractères
  Next
  Text1.Text = base    'Ouille ! ===>>> kaput au caractère N° 65535  (le 5ème de la ligne N° 6553)
  MsgBox "alors ? on a combien de caractères ? ===>>> " & Len(Text1.Text)
End Sub

Observez bien que la méthode Command3 subit (contrairement aux deux autres) la limitation VB6 pour une TextBox...

Que l'on fasse ce que l'on veut de ce truc.

**Barbu1595** · 22/09/2008, 19h28

Bonjour ProgElecT, ucfoutu, ohMonBato ,....

1 - J'ai doublè la RAM (512 Mo au lieu 256Mo) sans succès.

2 - Pour voir la partie du code qui bloque sous W98, fait des changements de label à différents niveaux :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub File1_Click()
Dim NumFich As Integer
Dim File As String, Texte As String, Lire As String
  If File1.ListIndex = -1 Then Exit Sub
File = File1.Path & "\" & File1.List(File1.ListIndex)
NumFich = FreeFile
Open File For Input As #NumFich
Line Input #NumFich, Texte
Lire = Texte
Label2.Caption = " VISUALISATION DU FICHIER P1  :  " & File1.List(File1.ListIndex)
Do
  Line Input #NumFich, Texte
  Lire = Lire & vbNewLine & Texte
    If EOF(NumFich) Then Exit Do
  DoEvents
Loop
Close #NumFich
Label2.Caption = " VISUALISATION DU FICHIER P2  :  " & File1.List(File1.ListIndex)
Me.Text1.Text = Lire
Label2.Caption = " VISUALISATION DU FICHIER P3  :  " & File1.List(File1.ListIndex)
End Sub

A l'écran j'ai

VISUALISATION DU FICHIER P1 : ES***.TXT

Donc le blocage se situe dans la boucle Do Loop.

3 - J'ai remplacé la Textbox par une RichTextBox et utilser le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
[Private Sub File1_Click()
Dim NumFich As Integer
Dim File As String, Texte As String, Lire As String
  If File1.ListIndex = -1 Then Exit Sub
File = File1.Path & "\" & File1.List(File1.ListIndex)
NumFich = FreeFile
Open File For Input As #NumFich
Line Input #NumFich, Texte
Lire = Texte
Do
  Line Input #NumFich, Texte
  Lire = Lire & vbNewLine & Texte
    If EOF(NumFich) Then Exit Do
  DoEvents
Loop
Close #NumFich
Me.RichTextBox1.Text = Lire
Label2.Caption = " VISUALISATION DU FICHIER  :  " & File1.List(File1.ListIndex)
End Sub

Pas d'erreur mémoire mais un temps d'attente très long pour les fichiers de taille importante : 100 Ko :11" ; 307 Ko : 128 "

Les temps de traitements sont les mêmes avec 256 Mo et 512 Mo de RAM

Etrange cette différence de comportement d'une TextBox en fonction de l'OS
(XP pas de limite de taille du fichier et W98 limité à < 62 Ko)

Par contre une attente de 128" pour un traitement de 307 Ko ,ne convient pas pour l'application.

Ce sont des fichiers texte générés par un exécutable (dont je n'ai pas les sources); pour moi ils ne sont pas structurés.

**OhMonBato** · 22/09/2008, 19h40

Et si tu remplaces par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
Do
  Line Input #NumFich, Texte
  Lire = Lire & vbNewLine & Texte
Loop until  EOF(NumFich)

Ca donne la même chose question temps ?

**ucfoutu** · 22/09/2008, 19h42

Bonsoir,

Essaye ceci, pour voir :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Command1_Click()
   Dim fichier As String, Texte As String, Lire As String
  If File1.ListIndex = -1 Then Exit Sub
  fichier = File1.Path & "\" & File1.List(File1.ListIndex)
   Dim FF As Integer: FF = FreeFile
   Open fichier For Input As #FF
        strText = Input(LOF(FF), #FF)
   Close #FF
   Me.RichTextBox1.Text = strText 
 End Sub

et dis-nous (temps, etc...)

**ProgElecT** · 22/09/2008, 20h06

Pourquoi passer par un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Open fichier For Input As

La commande LoadFile pour un RichTextBox est la pour sa

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

RichTextBox1.LoadFile File, rtfText

**OhMonBato** · 22/09/2008, 20h46

Pourquoi ?
Ben, parce que j'y ai même pas pensé !

**Barbu1595** · 23/09/2008, 19h25

Bonjour ProgElecT, ucfoutu, ohMonBato ,....

1 - J'ai testé la solution de ohMonBato:
Sous W98, toujours la même lenteur pour lire les fichiers > 62Ko :
100 Ko = 11" ; 307 Ko = 128 "
Mettre le test de fin de fichier sur le Loop ne change rien

2 - J'ai testé la solution de ucfoutu:
Miracle sous W98 comme sous XP l'affichage est très très rapide :
100 Ko < 1" ; 1270 Ko < 2 "

ucfoutu
Mettre la taille du fichier dans un Input c'est du nouveau pour moi

3 - J'ai voulu tester la solution de ucfoutu dans une textbox:avec le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub File1_Click()
  Dim fichier As String, Texte As String, Lire As String
  If File1.ListIndex = -1 Then Exit Sub
  fichier = File1.Path & "\" & File1.List(File1.ListIndex)
   Dim FF As Integer: FF = FreeFile
   Open fichier For Input As #FF
        strText = Input(LOF(FF), #FF)
   Close #FF
   Me.Text1.Text = strText
End Sub

J'ai eu le message d'erreur

Conclusion:
Il faut utiliser une RichTextBox avec Input(LOF(FF), #FF) pour solutionner mon problème.

Merci à vous tous de votre aide judicieuse.

Visionneuse sous W98 Erreur d'exécution :8007000e

VB 6 et antérieur

Discussions similaires

Partager

Partager