Discussion :

[RATIER]

Bonjour,

dans un datagridview , je souhaite que la touche 'enter' fonctionne comme la fleche de doite ou la touche 'tab', c'est a dire qu'elle passe à la celulle suivante et non pas à la ligne suivante.

Pour cela j'ai creer dans mon projet la classe suivante herite de datagrid view :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
Public Class CustomDataGridView
 
    Inherits DataGridView
 
    <System.Security.Permissions.UIPermission(System.Security.Permissions.SecurityAction.LinkDemand, _
    Window:=System.Security.Permissions.UIPermissionWindow.AllWindows)> _
    Protected Overrides Function ProcessDialogKey( _
          ByVal keyData As Keys) As Boolean
 
        ' Extract the key code from the key value. 
        Dim key As Keys = keyData And Keys.KeyCode
 
        ' Handle the ENTER key as if it were a RIGHT ARROW key. 
        If key = Keys.Enter Then
            Return Me.ProcessRightKey(keyData)
        End If
 
        Return MyBase.ProcessDialogKey(keyData)
 
    End Function
 
    <System.Security.Permissions.SecurityPermission(System.Security.Permissions.SecurityAction.LinkDemand, _
    Flags:=System.Security.Permissions.SecurityPermissionFlag.UnmanagedCode)> _
    Protected Overrides Function ProcessDataGridViewKey( _
        ByVal e As System.Windows.Forms.KeyEventArgs) As Boolean
 
        ' Handle the ENTER key as if it were a RIGHT ARROW key. 
        If e.KeyCode = Keys.Enter Then
            Return Me.ProcessRightKey(e.KeyData)
        End If
 
        Return MyBase.ProcessDataGridViewKey(e)
 
    End Function
 
 
End Class

Pourtant la touche 'enter' passe toujours à la ligne suivante. J'ai l'impression que cette classe n'est pas gérée.
Merci d'avance pour votre aide

[sinople]

Tu as essayer de catcher l'enter sur l'evement KeyDown?

De plus je n'essayerai pas de simuler la touche droite (en effet lorsque tu es en mode édition la touche droite ne fait pas passer à la cellule suivante...).

J'utiliserai plutot le Tab, voir même directement donner le focus la ou ça doit aller.

[RATIER]

C'est ce que je compte faire mais je voulais quand meme savoir pourquoi il ne tient pas compte de cette classe herité de datagridview qui normalement fonctionne.

[chrismonoye]

Bonjour,
Il faudrait des messagebox pour voir ce que ton code retourne.
Pour tester ta solution j'ai trouvé ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Protected Overrides Function ProcessCmdKey(ByRef msg As Message, keyData As Keys) As Boolean
	If keyData = Keys.Enter Then
		' Lorsque l'on valide le contenu d'une cellule,
		' on va passer à la cellule suivante, ou la ligne suivante si c'est la dernière cellule,
		' voire créer une nouvelle ligne si nous nous trouvons sur la dernière ligne
		Dim row As Integer = Me.CurrentCell.RowIndex, column As Integer = Me.CurrentCell.ColumnIndex
 
		column += 1
		If column = Me.ColumnCount Then
			row += 1
			column = 0
		End If
		If row = Me.Rows.Count Then
			Me.Rows.Add()
		End If
 
		Me.CurrentCell = Me.Rows(row).Cells(column)
 
		' Si on n'édite pas la cellule, on indique que l'on a déjà géré la touche en retournant true
		' sinon on se retrouve une ligne trop bas car la gestion par defaut de la touche enter fait descendre d'une ligne
		If Not Me.IsCurrentCellInEditMode Then
			Return True
		End If
	End If
 
	Return MyBase.ProcessCmdKey(msg, keyData)
End Function

C'est issu de la discution suivante :
http://www.developpez.net/forums/d25...-lappui-enter/
Mais le DataGridview est tellement "blindé" que je suis presque sûr que ça va clocher ailleurs.
Je me range donc du coté de sinople, autant se servir du clavier (tab fait le même effet).

[sinople]

T'as regardé en pas à pas s'il rentre dans ton code?

Si j'ai dit d'utiliser l'évenement Keydown, c'est qu'un pression sur la touche "ENTER" (parmi d'autre...) n'est pas attrapable avec tous les évenements clavier. Du coup pour vérifier c'est pas le top!

Après fait un test avec un Console.Writeline("Toto") ou un msgBox("Toto") au début pour vérifier qu'il rentre bien dans la fonction à chaque touche.

Je n'ai pas regardé l'aspect héritage, juste l'aspect clavier ENTER.

[RATIER]

C'est difficile la gestion des touches dans la datagrid.

j'ai une solution temporaire c'est a dire qu'elle fonctionne si on tape sur enter et que la cellule n'est pas en mode edition.

j'enregistre la colonne et la ligne de la cellulle courante dans la sub 'PreviewKeyDown' si on tape sur enter.
Ensuite dans la sub 'KeyPress', je positionne le focus sur la cellule suivante en gérant bien sur la derniere colonne et les colonnes invisibles.
Ca fonctionne bien seulement dans lon logiciel je veux taper une chaine dans une colonne puis taper sur 'enter' et là ca fonctionne pas car la celulle est en mode edition.

[chrismonoye]

Bonjour,
j'ai testé votre code de départ avec un form neuf.
Il ne pose aucun problème chez moi avec une création d'une nouvelle instance de "CustomDataGridView" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
 
        Dim dgvCostum As New CustomDataGridView
        dgvCostum.Location = New Point(30, 30)
        dgvCostum.AutoSize = True
        Me.Controls.Add(dgvCostum)
        '*** Ci dessous sont mes données pour remplir le DGV pour tester. A remplacer par les votres.
        ConstructionTable()
        VueDansDGV(dgvCostum)
 
    End Sub

[RATIER]

C'est ce que je craignais, il faut creer le datagrid manuellement.
Je vais essayer cela.
en tout cas merci beaucoup pour votre aide.