Lidar et Lidar TF 03

Version imprimable

Voir 40 message(s) de cette discussion en une page

29/01/2021, 09h53
Stantedy

Lidar et Lidar TF 03

Bonjour,

concernant mon idée de radar avec le capteur ULtra son Sick...
j'ai trouvé un Radar Lidar.... étanche et pas cher...
il utilise comme protocole de com:Interface de communication : UART / RS485 / IO.
on peux faire un truc avec un arduino nano?
le modele c'est le TF 03 ( descriptif sur amazon)
29/01/2021, 11h13
Jay M

1 pièce(s) jointe(s)

Je suppose que c'est ce modèle (on le trouve moins cher en chine sur eBay (164€ au lieu de 239€) mais délais de livraisons un peu longs)
Pièce jointe 589649

Je ne connais pas ce module, mais j'ai trouvé une documentation

Si vous prenez un TF03-100 il est en mode série par défaut en TTL (et peut supporter un mode CAN par configuration)
le TF03-100 RS485/RS232 serait celui qui supporte le RS485/RS232.

==> avec votre Arduino il faut prendre le premier, un TF03-100 "tout court" et connecter les pins 1 (Vcc), 5 (Rx), 6 (Tx) et 7 (GND). Il s'alimente en 5V et nécessite 180mA donc on peut l'alimenter directement depuis la broche 5V d'un Arduino.

Par défaut il communique à 115200 bauds et envoie 100 trames par seconde - c'est assez élevé et on sera ennuyé (perte de trames) si on utilise SoftwareSerial comme avec le GPS (qui n'était qu'à 9600 bauds). Il faudra donc le connecter sur le port série matériel de l'Arduino, ce qui veut dire une petite manipulation lors de l'installation du logiciel: il faudra débrancher (ou isoler) le TF-03. Ça peut se faire en prévoyant des cavaliers qui connecteront les pins 0 et 1 au Tx/Rx du TF03-100.

Quand on charge le soft, on enlève les cavaliers, puis on les remet pour l'usage. A priori ce n'est pas super contraignant, on ne fait cela qu'une seule fois.

Ça veut dire aussi qu'on ne peut plus utiliser la console Série comme sortie de debug - sauf à bidouiller un peu, on pourrait ne pas connecter le Tx de l'Arduino au TF03-100 et le garder pour la communication avec la console série si on n'a pas besoin d'envoyer de commandes de configuration à ce module.

Sinon il faut prendre un Arduino qui aurait 2 ports séries hardware comme une MEGA (mais c'est gros) ou d'autres type MKR ou ESP32 mais ils sont en 3.3V et il faudrait rajouter une adaptation de tension sur les lignes de communication.

Sur la page de DFRobot ils ont même une bibliothèque pour gérer le protocole (communication en binaire)...

Bref, si ces bibliothèques sont robustes, ce n'est pas difficile à construire :)
29/01/2021, 14h42
Stantedy

Lidar et Lidar TF 03

Bonjour a tous,

pour ceux qui n'ont pas suivi...
créer une alarme de distance avec un Arduio Nano et un Lidar TF 03

Philippe
29/01/2021, 16h10
Vincent PETIT

Déplacement de 2 messages d'une autre discussion dans celle-ci afin de créer un nouveau sujet.
Pour la modération.
Vincent

1 pièce(s) jointe(s)

Citation:

Envoyé par Stantedy

bon on s'y colle...?
comment ca ce passe pour les beep...? au fur a mesure, les beep deviennent de plus en plus rapprochés?
sur le petit nano vous arrivez donc a faire tourner l'animal?

Salut - oui pour les beeps on peut les faire en fonction de la distance: plus la distance est courte, plus les beeps sont rapprochés et en dessous d'une certaine distance ça beep en continu et au dessus d'une certaine distance, ça ne beep pas.

Oui un Nano va gérer cela sans problème. Je n'ai pas besoin du module pour développer le code, ça n'a pas l'air compliqué, essayez cela:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 const byte buzzPin = 8; const unsigned int toneFreq = 500; const unsigned int maxDistanceBeep = 1000; // in cm. Start beeping if distance less than 10m const unsigned int minDistanceBeep = 40; // in cm. continuous beep if distance less than 40cm uint16_t distance = 2 * maxDistanceBeep; // very crude TF03-100 reading interface based on https://acroname.com/sites/default/files/assets/tf03_product_manual_v0.4_en.pdf // protocol: receive at 115200 bauds 8N1, (100Hz by default) // Byte0 Byte1 Byte2 Byte3 Byte4 Byte5 Byte6 Byte7 Byte8 // 0x59 0x59 dLSB dMSB xxxx xxxx xxxx xxxx cksum // with Low 8 bits of cksum = Byte0 + Byte2 +... + Byte7 enum : byte {START0, START1, DLOW, DHIGH, BYTE4, BYTE5, BYTE6, BYTE7, CKSUM} parserState = START0; bool acquisition() { static uint16_t d = 0; static byte checksum = 0 ; bool acquired = false; int rec = Serial.read(); if (rec != -1) { uint16_t wordReceived = rec & 0xFF; switch (parserState) { case START0: if (wordReceived == 0x59) parserState = START1; break; case START1: if (wordReceived == 0x59) { d = 0; checksum = 0x59 + 0x59; parserState = DLOW; } else parserState = START0; break; case DLOW: d = wordReceived; checksum += wordReceived; parserState = DHIGH; break; case DHIGH: d |= (wordReceived << 8); checksum += wordReceived; parserState = BYTE4; break; case BYTE4: checksum += wordReceived; parserState = BYTE5; break; case BYTE5: checksum += wordReceived; parserState = BYTE6; break; case BYTE6: checksum += wordReceived; parserState = BYTE7; break; case BYTE7: checksum += wordReceived; parserState = CKSUM; break; case CKSUM: if (wordReceived == checksum) { distance = d; acquired = true; } parserState = START0; break; } } return acquired; } void audioFeedback(uint16_t d) { static uint32_t lastTrigger; if (d > maxDistanceBeep) noTone(buzzPin); else if (d < minDistanceBeep) tone(buzzPin, toneFreq); else { if (millis() - lastTrigger >= d) { tone(buzzPin, toneFreq, 30); lastTrigger = millis(); } } } void setup() { Serial.begin(115200); pinMode(buzzPin, OUTPUT); pinMode(LED_BUILTIN, OUTPUT); } void loop() { acquisition(); audioFeedback(distance); }
il n'y a pas besoin de librairies tierces, le protocole est simple donc je le lis directement.

Vous chargez le code sur la Nano sans matériel accroché

- Vous connectez un buzzer sur la pin 8, c'est défini au début du code avec

Code:

const byte buzzPin = 8;

- Vous connectez les 4 broches du Lidar: (cf documentation)
Pièce jointe 589687

(en pratique la connexion "Brown --> 1 (Tx)" n'est pas utilisée car on n'envoie jamais rien au module donc la connexion n'est pas obligatoire)

Vous alimentez le tout. ATTENTION si alimentation par USB, ne pas ouvrir la console série de l'IDE Arduino.

Si je ne me suis pas trompé, vous pointez le Lidar vers un mur et:
- à plus de 10m pas de bruit
- entre 10m et 40cm des beeps de plus en plus rapprochés
- sous 40cm un beep continu

Curieux de savoir si ça fonctionne :)

(Si vous avez un Arduino Mega sous la main, je peux modifier la version pour qu'on puisse faire du debug)

29/01/2021, 18h45
Stantedy

Jay M

Salut Jay

est ce qu'on peux "corser" les choses....

allez j'explique...

Note: je base tout le systeme (Alarme, Gps et ce petit dernier) qu'il n'y a quasiment aucun câblage sur le bateau, tout au plus une alim pour ce qui est gourmand en énergie...
ET du super petit....

situation physique du matériel:

- radar a l'arriere
-on/off de mise en service du radar au poste pilote (milieu du bateau)

le on/off ce fait sans fil. (ca c'est facile et super fiable)

j'ai besoin du beep a coté du pilote

qu'est qu'on fait, une communication TXD/RXD sans fil entre de Lidar et l'arduino? ou uniquement pour le Beep? ou alors un mega beep (genre camion des éboueurs)

pourquoi: le Lidar est IP67 donc pas de soucis mais par contre l'arduino c'est autre chose....

pour les distances: on commence a beeper lent a 10 m
entre les 2 on accelere au fur et a mesure (enfin ci c'est possible!)
et Beep continu arrivé a 3 metres
29/01/2021, 19h09
Jay M
pour les distances min et max, il suffit de modifier
Code:

1 2 const unsigned int maxDistanceBeep = 1000; // in cm. Start beeping if distance less than 10m const unsigned int minDistanceBeep = 40; // in cm. continuous beep if distance less than 40cm
ce sont les valeurs en cm

Pour l'instant j'utilise la valeur de la distance (en cm) pour faire une pause entre deux beeps (en ms).

par exemple à 4m (400cm) il y a 400ms entre 2 beeps. c'est la ligne de code

Code:

if (millis() - lastTrigger >= d) {

qui dit que si le temps écoulé en ms depuis le dernier beep est plus grand que la valeur de la distance alors on re-beep.

Le "silence" entre deux beep est donc linéairement proportionel à la distance. Si on veut faire un truc plus chiadé que du bête linéaire, faut mettre une petite formule de calcul qui dit combien attendre en ms en fonction de la distance d

Pour le plus "corsé":

Citation:

le on/off ce fait sans fil. (ca c'est facile et super fiable)

Vous êtes en Infra rouge ou en radio ? (en radio je pense que vous risque de prendre toutes les perturbations électromagnétiques des moteurs, ça risque de ne pas être fiable pour une communication soutenue à 115200 bauds)

ce serait simple de modifier le code pour qu'une PIN envoie une impulsion à chaque fois qu'un BEEP doit avoir lieu. Si vous savez relayer cette impulsion sans fil vers votre central pour que le beep soit là bas, c'est envisageable. possible ?
29/01/2021, 19h18
Stantedy

Jay M

oui on est d'accord... (je savais deja qu'on allez l’être...)

je me démerde a juste transmettre le signal du beep et je chiade le coffret pour l'arduino...

OK

donc la pin du buzzer devient une pin qui indique s'il faut faire un beep.
- LOW = pas de beep
- HIGH = beep

donc pour qu'il n'y ait qu'une seule impulsion (et pas un PWM sur la pin du buzzer) vous pouvez essayez le code suivant

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
const byte buzzPin = 8;
const unsigned int toneFreq = 500;
const unsigned int maxDistanceBeep = 1000;  // in cm. Start beeping if distance less than 10m
const unsigned int minDistanceBeep =   40;  // in cm. continuous beep if distance less than 40cm
 
uint16_t distance = 2 * maxDistanceBeep;
 
// very crude TF03-100 reading interface based on https://acroname.com/sites/default/files/assets/tf03_product_manual_v0.4_en.pdf
//  protocol: receive at 115200 bauds 8N1, (100Hz by default)
//    Byte0 Byte1 Byte2 Byte3 Byte4 Byte5 Byte6 Byte7 Byte8
//    0x59  0x59  dLSB  dMSB  xxxx  xxxx  xxxx  xxxx  cksum
//  with Low 8 bits of cksum = Byte0 + Byte2 +... + Byte7
 
enum : byte {START0, START1, DLOW, DHIGH, BYTE4, BYTE5, BYTE6, BYTE7, CKSUM} parserState = START0;
 
bool acquisition() {
  static uint16_t d = 0;
  static byte checksum  = 0 ;
  bool acquired = false;
 
  int rec = Serial.read();
  if (rec != -1) {
    uint16_t wordReceived = rec & 0xFF;
    switch (parserState) {
      case START0:
        if (wordReceived == 0x59) parserState = START1;
        break;
 
      case START1:
        if (wordReceived == 0x59) {
          d = 0;
          checksum  = 0x59 + 0x59;
          parserState = DLOW;
        }
        else parserState = START0;
        break;
 
      case DLOW:
        d = wordReceived;
        checksum  += wordReceived;
        parserState = DHIGH;
        break;
 
      case DHIGH:
        d |= (wordReceived << 8);
        checksum  += wordReceived;
        parserState = BYTE4;
        break;
 
      case BYTE4:
        checksum  += wordReceived;
        parserState = BYTE5;
        break;
 
      case BYTE5:
        checksum  += wordReceived;
        parserState = BYTE6;
        break;
 
      case BYTE6:
        checksum  += wordReceived;
        parserState = BYTE7;
        break;
 
      case BYTE7:
        checksum  += wordReceived;
        parserState = CKSUM;
        break;
 
      case CKSUM:
        if (wordReceived == checksum) {
          distance = d;
          acquired = true;
        }
        parserState = START0;
        break;
    }
  }
  return acquired;
}
 
void audioFeedback(uint16_t d)
{
  static uint32_t lastTrigger;
 
  if (d > maxDistanceBeep) digitalWrite(buzzPin, LOW); // pin LOW = pas de beep
  else if (d < minDistanceBeep) digitalWrite(buzzPin, HIGH); // pin HIGH = beep continu
  else {
    if (millis() - lastTrigger >= d) { // impulsion de 30ms sur la pin de sortie quand on doit faire un beep
      digitalWrite(buzzPin, HIGH);
      delay(30);
      digitalWrite(buzzPin, LOW);
      lastTrigger = millis();
    }
  }
}
 
 
void setup() {
  Serial.begin(115200);
  pinMode(buzzPin, OUTPUT);
  pinMode(LED_BUILTIN, OUTPUT);
}
 
void loop() {
  acquisition();
  audioFeedback(distance);
}

30/01/2021, 10h01
Vincent PETIT

Bonjour,

Citation:

Envoyé par Jay M

Pour le plus "corsé":

Vous êtes en Infra rouge ou en radio ? (en radio je pense que vous risque de prendre toutes les perturbations électromagnétiques des moteurs, ça risque de ne pas être fiable pour une communication soutenue à 115200 bauds)

Excellente remarque, oui il y aura potentiellement des problèmes de compatibilité électromagnétique et il faut savoir que les bandes ISM qu'utilisent les petits modules radio (433MHz, 868MHz, 2,4GHz, ...) sont très chargés.

Les télécommandes de portails ou autres bips, la vidéo surveillance, les fours à micro ondes, les alarmes, le bluetooth, le Wifi, etc sont dans les bandes ISM. On pourrait très bien imaginer qu'un téléphone, avec le bluetooth activé, dans la poche de quelqu'un aux commandes du bateaux puisse rompre la communication 2.4GHz d'un petit module nrf24l01nrf.

Ce serait problématique car pas de bip en reculant amènerait à un choc.

Pour avoir conçu des systèmes avec de la sûreté de fonctionnement le cas du radar de recul qu'on croit fonctionner alors que non est très embêtant car il causera presque systématiquement un accident puisqu'on s'y fie (on aura tendance à moins regarder et plus écouter pour juger de la distance). En sûreté de fonctionnement on amène dans le soft la notion de diagnostic et mode dégradé, c'est à dire que le Arduino prévient la personne aux commandes que le radar est inopérant et le pilote comprend qu'il doit ouvrir les yeux à la place de ses oreilles.
30/01/2021, 10h08
Stantedy

Jay M

Bonjour Jay

pour le renvois de beep j'ai trouvé ca... (ca consomme que dalle en veille ...)

https://fr.aliexpress.com/item/32728...c00f8lbqa&mp=1
30/01/2021, 11h15
Jay M

Les RF 433 Mhz ne se valent pas tous... en superhétérodyne c'est mieux mais ça reste pour du bidouillage où la notion de risque est limitée. (aucune garantie de distribution du message) Et comme le rappelle @Vincent - fréquence encombrée et perturbée.

Sa remarque sur le mode dégradé est aussi bonne, dans mon code pour le moment il n'y a aucune alerte en cas d'erreur - c'est rajoutable sans trop de difficulté (par exemple alerte si pas de communication cohérente pendant plus d'une seconde - faut juste définir à quoi ressemble l'alerte)

sinon un gros beep de camion poubelle ça peut avoir du bon :)
30/01/2021, 18h58
Stantedy

Jay M

Re...

la fenetre de detection sur le Lidar est parametrable?

je m'explique: le bateau equipé fait 5M de large

donc la detection doit ce faire dans une fenetre de 5 m de Large, sur 10metres de long et sur en gros de la surface de l'eau a 2m de haut
tout ca est parametrable dans le code?
31/01/2021, 10h56
Stantedy

Jay M

Bonjour Jay

2 questions...

j'ai vu qu'on pouvez mettre les arduino en mode sommeil...
d’après vous qu'est qui est mieux couper l'alim ou indiquer via une Pin de se mettre en "sommeil"?

concernant le Lidar et le renvoi du Beep...
si on l'arduino Nano renvois l'info Beep Lidar et éventuellement un Beep pour le mode dégrader via un module Lora en 868Mhz a un petit arduino Micro...?
car il serait bien (car je n'y avais pas pensé) de pouvoir envoyer le même beep a 2 endroit différents (certain bateau sont équipé de deux poste pilote (un principal et un en Fly Bridge a l’extérieur)...
çà deviens compliqué mon histoire ...

Ps: Bon Dimanche
31/01/2021, 13h16
Jay M

1 pièce(s) jointe(s)

Salut et Bon Dimanche

Citation:

la fenetre de detection sur le Lidar est parametrable?

Non, c'est vraiment un outil de mesure de distance. Donc le faisceau Laser passe à Travers une lentille et ça fait une lumière très cohérente à faible distribution (Field of View) -> 0.5° dit la doc donc à 10m vous visez un cercle de 9cm de diamètre.

==> le LIDAR n'est sans doute pas adapté alors au besoin si vous voulez couvrir une grande zone.

Si vous regardez sur les voitures, ils ont plusieurs capteurs répartis sur le pare-choc et ils utilisent des ultra-sons car qui ont une assez grande distribution. ce sont des petits modules qui ressemblent à cela
Pièce jointe 589782

Citation:

d’après vous qu'est qui est mieux couper l'alim ou indiquer via une Pin de se mettre en "sommeil"?

Un arduino boot vite, donc si on peut tout éteindre pour de vrai, c'est mieux. il ne suffit pas de mettre l'Arduino en veille, il faudrait aussi cesser d'alimenter ou mettre en sommeil les capteurs

Pour la gestion du sans fil, tout est envisageable mais il faudrait tester, je n'ai aucune idées des perturbations électromagnétiques qui pourraient venir mettre le bazar... Vous aurez de petites antennes et peu de puissance dans l'émission. Une porteuse modulée dans les règles (Short-range device) - sans essayer de faire passer de vraies data - pourrait suffire à envoyer un 0 ou 1 (présence du signal = beep sinon pas de beep). Comme tout ce qui est sans fil, ce n'est généralement pas simple à "tuner".
31/01/2021, 13h57
Stantedy

Jay M

Merci Jay,

on va faire des test demain quand j'ai recu les Lidar... (au pire on va tester sur un ou deux bateau ...)
pouvez vous (quand vous avez un peux de temps) a ce probleme de buzer a distance (je m'y pert un peux là...)
on a pas beaucoup de distance a couvrir, une trentaine de metres... et cela pour deux endroit sur le bateau.
31/01/2021, 14h10
Stantedy

1 pièce(s) jointe(s)

Jay M

juste pour vous situer un peu...

on a 2 entreprises, la première Technical Yachting, on fait que de la maintenance et du dépannage (meca, hydraulique, électricité électronique, etc etc ) çà ne fait que 20 ans que je fait ca..
la deuxième est dédié alarme et video que pour les bateaux .

ci joint une doc d'un bateau qu'on a a l'entretien...Pièce jointe 589785
31/01/2021, 15h22
Jay M

ah oui.. joli bateau !

et à ce niveau de finition il n'y a pas de "radar de recul" intégrés ?
31/01/2021, 15h58
Stantedy

Jay M

Eh Ben Non et Pas d'Alarme Non PLUS!!!!

pour la transmission des beep a 2 endroits on peux le faire Jay?
quand au spectre de detection du Lidar on peux peux etre trouver un autre moins selectif? celui me parait fiable et d'une bonne conception c'est con...
31/01/2021, 16h21
Jay M

incroyable...

Un truc à tester éventuellement pour voir si une solution "de base" est envisageable

vous achetez un truc comme ça ou comme ça, vous mettez le récepteur dans le poste de pilotage, vous branchez 12V d'un côté du relais et une ampoule 12V de l'autre et vous allez à l'arrière du bateau appuyer sur la télécommande. Si vous réussissez à 100% allumer la lampe, c'est que le 433Mhz passe correctement

pour 1 émetteur et plusieurs récepteur, oui c'est possible s'ils sont sur la même fréquence / codage (radio-commandes à code fixe, pas tournant)

Voir 40 message(s) de cette discussion en une page