Discussion :

[Bluchy]

Bonjour à tous


J'ai une question pourtant qui me parait être assez simple: Copier une valeur d'un fichier excel et la copier dans un autre fichier excel.

Cette macro se situe dans mon fichier de sortie qui va ouvrir d'autre fichiers excels et rappatrier certaines cellules.

J'ai fait ce code en essayant de décomposer le plus en fonction/procédure car j'ai beaucoup de cellules à copier dans mon fichier de sortie "sortie.xls".Malheureusement j'ai des problèmes d'activation de feuilles et d'ouverture de fichiers...

Si vous pouviez m'aider se serait super

Ps: Si vous avez une solution encore plus simple, je suis preneur!

Merci d'avance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
 
Function Ouvre(CheminClasseur As String) As Workbook
 
   Dim ClasseurSource As Workbook, ClasseurCible As Workbook
 
    Ouvre = Null
   If VerifOuvertureClasseur(CheminClasseur) Then
       MsgBox "Classeur " & CheminClasseur & " déja ouvert." 'Que faire si déjà ouvert?
   Else
       Set ClasseurSource = Application.Workbooks.Open(CheminClasseur)
       Application.DisplayAlerts = False
       Ouvre = ClasseurCible
 
 
   End If
End Function
 
Function VerifOuvertureClasseur(Fichier As String) As Boolean
   Dim x As Integer
 
   On Error Resume Next
   x = FreeFile()
 
   Open Fichier For Input Lock Write As #x 'préciser les options d'accès au fichier, ici verouillé en écriture...
   Close x
 
   If Err.Number = 0 Then VerifOuvertureClasseur = False
   If Err.Number = 70 Then VerifOuvertureClasseur = True
 
   On Error GoTo 0
End Function
 
 
 
Sub CopierCellule(FichierSource As String, NbLigneSource As Integer, NbColonneSource As Integer, NbLigneDest As Integer, NbColonneDest As Integer)
 
Dim valeur As Integer
Dim classeur As Workbook
 
 
classeur = Ouvre(FichierSource)
classeur.Worksheets(1).Activate 'j active la page   ICI EST LE PB 
valeur = Workbooks(FichierSource).Sheets("XXX").Cells(NbLigneSource, NbColonneSource).Value ' je cherche dans longlet XXX la valeur de la cellule
Workbooks("sortie.xls").Worksheets("XXX").Cells(NbLigneDest, NbColonneDest).Value = valeur
Workbooks("sortie.xls").close
 
 
 
 
 
End Sub
 
 
' Recherche des éléments nécessaires dans le fichier Excel d'analyses
 
Sub OnCopie()
 
' ici on essaie de copier différents fichier1 dans sortie.xls mon fichier courant qui contient la macro
 
Call CopierCellule("fichier1.xls", 5, 5, 2, 5)
Call CopierCellule("fichier2.xls", 5, 5, 3, 8)
 
 
End Sub

[mercatog]

N'oublie pas le Set pour les objets WorkBook
Sans tester, essaies ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Function Ouvre(CheminClasseur As String) As Workbook
 
If VerifOuvertureClasseur(CheminClasseur) Then
    MsgBox "Classeur " & CheminClasseur & " déja ouvert."    'Que faire si déjà ouvert?
Else
    Set Ouvre = Workbooks.Open(CheminClasseur)
End If
End Function
 
Sub CopierCellule(FichierSource As String, NbLigneSource As Integer, NbColonneSource As Integer, NbLigneDest As Integer, NbColonneDest As Integer)
Dim valeur As Double
Dim Classeur As Workbook
 
 
Set Classeur = Ouvre(FichierSource)
If Not Classeur Is Nothing Then
    valeur = Classeur.Worksheets("XXX").Cells(NbLigneSource, NbColonneSource).Value    ' je cherche dans longlet XXX la valeur de la cellule
    ThisWorkbook.Worksheets("Synthèse RBU3").Cells(NbLigneDest, NbColonneDest).Value = valeur
    Set Classeur = Nothing
    MsgBox "Import réussi"
Else
    MsgBox "Import failed"
End If
End Sub

[Touffe54]

Salut,

J'ai écrit un petit code, qui fonctionne aussi, et que me parait plus simple.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Public Type Tampon
    Tmp1 As String
    Tmp2 As String
    Tmp3 As Integer
    Tmp4 As Integer
End Type
 
 
 
Public Sub Transfert()
 
    Dim fichier As String
    Dim T As Tampon
 
    fichier = ThisWorkbook.Path & "\FeuilleTransfert.xls"
 
    T.Tmp1 = Range("A1")
    T.Tmp2 = Range("A2")
    T.Tmp3 = Range("A3")
    T.Tmp4 = Range("A4")
 
    Workbooks.Open Filename:=fichier
 
    Workbooks("FeuilleTransfert.xls").Activate
 
    Range("A1") = T.Tmp1
    Range("A2") = T.Tmp2
    Range("A3") = T.Tmp3
    Range("A4") = T.Tmp4
 
 
End Sub

Tu crées une variable public "type" dans un module. Dans ta macro, tu entres les données de ta feuille d'origine, t'ouvre ton autre classeur et tu bennes tout ce qu'il y a dans ta variable "type" dans ton nouveau classeur. Tu peux faire çà aussi avec un module de classe, si tu veux élaborer un peu plus ton programme. Chez moi çà marche très bien ce système. J'espère t'avoir aidé.

[Bluchy]

Merci pour vos réponses

Ca marche nickel