Discussion :

[minnesota]

Voici un exemple de script, à placer dans ton dossier "lives" et à lancer depuis ce même dossier. Il est en mesure de faire ce que tu as demandé. Une gestion sommaire des erreurs a été intégrée, certes, elle ralentit le script, mais elle t'évite des problèmes. Toutefois, il convient de tester au préalable le script sur une copie partielle du dossier "lives" pour t'assurer de son efficacité.

Tu peux modifier la partie :

set image_ext=.jpg .bmp .gif .jpeg .png

si tu souhaites ajouter ou retirer des extensions de fichiers à prendre en charge. Veuille à ne pas mettre d'étoile genre *.jpg mais bien .jpg

Enfin, voilà le script en question,
En espérant que ça te libérera plus de temps pour faire encore plus de belles photos


ren_image.cmd

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
@echo off
title Nommage de fichiers
::---------------------------------------------------------------------------------------------------------------
set image_ext=.jpg .bmp .gif .jpeg .png
::---------------------------------------------------------------------------------------------------------------
set log_file=errorlog.txt
set folder_name=
set nb_files=0
set tt_files=0
set tt_error=0
echo.
echo Dossier en cours :
for /f "tokens=*" %%i in ('dir /ad /b 2^>NUL') do call :renin "%%i"
if not "%folder_name%"=="" (set/p z=[%nb_files%])<NUL
echo.

goto fin

:renin
if not "%folder_name%"=="" (set/p z=[%nb_files%])<NUL
echo.
set /a nb_files=0
set folder_name=%~1
(set/p z=-^> %folder_name% )<NUL
title Dossier: %folder_name:~,15%...
for /f "tokens=*" %%i in ('dir /a-d /b %folder_name%\* 2^>NUL ^| findstr /i /v "%folder_name%" ^| findstr /i "%image_ext%"') do call :fileren "%%i"
goto :eof

:fileren
ren "%folder_name%\%~1" "%folder_name%-%~1" 2>NUL
if not errorlevel 1 goto pass
set /a tt_error+=1
echo erreur pour "%~1" de "%folder_name%" >> %log_file%
:pass
set /a nb_files+=1
set /a tt_files+=1
title Dossier: %folder_name:~,15%...  en_cours:[%nb_files%]  cumul:[%tt_files%]  erreurs:[%tt_error%]
goto :eof


:fin
echo.
echo Fin des op‚rations, pressez une touche pour quitter.
pause>NUL

[djillijd]

Yesssss ! Oh bah ça marche du tonnerre ton script !
bon maintenant je vais essayer de le comprendre voir de regarder ses limites !
Merci à tous encore une fois !

Ma prochaine série de photos vous sera dédiée

Bye, Djil