Discussion :

[AstridG]

Bonjour,

J'ai un fichier contenant des mesures de température au pas quotidien. Hors certaines mesures sont manquantes et je souhaiterai les remplacer par la moyenne des valeurs encadrantes, c'est à dire faire la moyenne des mesures du jour d'avant et du jour d'aprés dans la case manquante. Lorsque deux (ou plus) jours manquent de façon consécutive, je voudrai mettre dans toutes les cases la même valeur qui serait la moyenne des températures encadrantes.

Ca me parait bien compliqué à réaliser. Il faut vraisemblablement partir sur une boucle de type:
"if temperature="" then do..."
mais je sèche sur la syntaxe de la moyenne des valeurs encadrantes, d'autant plus que dans certains cas on a plusieurs valeurs manquantes consécutives.
Ou alors une proc means, mais je ne vois absolument pas non plus la syntaxe qui me permettrait de faire ça.

Merci!

Astrid

[RemiBousquet]

Voici une table qui correspond je pense à ton problème :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
data table ;
input jour temp ;
format jour ddmmyy10. ;
cards ;
18263 1
18264 2
18265 .
18266 4
18267 .
18268 .
18269 .
18270 8
18271 .
;
run ;

La difficulté de ton problème vient de ce que l'on fasse appel à des lignes avant et des lignes après la ligne sur laquelle tu fais ton calcul, ce que SAS ne peut pas gérer. (lag() permet d'utiliser les lignes d'avant, mais pas celles d'après). Il faut donc procéder en plusieurs étapes.

Et voici une solution à ton problème, basée sur deux tris successifs, l'utilisation d'un retain, de la fonction missing() et de la fonction mean()

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
proc sort data = table ; by descending jour ; run ;
data table ;
    set table ;
    retain temp_sup ;
    if not missing(temp)
        then temp_sup = temp ;
run ;
proc sort data = table ; by jour ; run ;
data table ;
    set table ;
    retain temp_inf ;
    if not missing(temp)
        then temp_inf = temp ;
run ;
data table ;
    set table ;
    if missing(temp)
        then temp_retraite = mean(temp_inf, temp_sup)  ;
        else temp_retraite = temp ;
    drop temp_inf temp_sup ;
run ;

La fonction mean permet de gérer simplement le cas où la première et/ou la dernière température est manquante. C'est plus propre que :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

temp_retraite = (temp_inf + temp_sup) /2 ;

[datametric]

ca à l'air bien mais tu peux regarder la proc Expand pour voir si elle ne te simplifierai pas ce travail ?

[AstridG]

Cette solution marche bien, merci beaucoup de vous être penchés sur la question!

Astrid