Discussion :

[Ranei]

Bonjour !


Alors voilà, pour un cours j'essaye de calculer une somme mensuelle, à partir d'un tableau excel où dans la colonne C il y a les dates à partir du rang 10 et les choses à sommer quotidiens dans la colonne i.

Voilà ce que j'ai programmé. Mais au niveau de annee2, j'ai l'erreur 1004 avec Range de l'objet Global a échoué... ne connaissant pas grand chose aux macros Excel, je ne sais pas quoi faire !

J'espère que vous pourrez m'aider !
Merci d'avance !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Dim mois As Double, annee As Double, somme As Double, annee2 As Double, mois2 As Double, i As Double

annee = InputBox("Entrez l'année dont vous souhaitez faire le calcul. (sous forme 2010 par ex)", "Somme mensuelle :Choix de l'année")
mois = InputBox("Entrez le mois dont vous souhaitez faire le calcul. (sous forme 09 par ex pour septembre)", "Somme mensuelle :Choix du mois")

somme = 0

For i = 10 To 65536

Workbooks("macroexcel.xls").Sheets("Feuil1").Activate
    annee2 = Right(Range("C" & Str(i)).Value, 4)    
    MsgBox (annee2)
    
        If annee2 = annee Then
                mois2 = Mid(Range("C" & Str(i)).Value, 4, 2)
                
                    If mois2 = mois Then
                        somme = somme + Range("I" & Str(i)).Value
                    End If
        End If
        
Next i

MsgBox (Str(somme))

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Dim Annee As Integer
Dim Somme As Double
Dim Mois As Byte
Dim Dte As Date
Dim i As Long
 
Annee = InputBox("Entrez l'année dont vous souhaitez faire le calcul. (sous forme 2010 par ex)", "Somme mensuelle :Choix de l'année")
Mois = InputBox("Entrez le mois dont vous souhaitez faire le calcul. (sous forme 09 par ex pour septembre)", "Somme mensuelle :Choix du mois")
 
'il faut tester sur les valeurs entrées par l'utilisateur
With Workbooks("macroexcel.xls").Sheets("Feuil1")
   For i = 10 To .Cells(.Rows.Count, "C").End(xlUp).Row
      If IsDate(.Range("C" & i).Value) Then
         Dte = .Range("C" & i).Value
         If Year(Dte) = Annee Then
            If Month(Dte) = Mois Then
               Somme = Somme + .Range("I" & i).Value
            End If
         End If
      End If
   Next i
End With
MsgBox Somme

[Ranei]

Merci beaucoup !