Discussion :

[safouunette]

Bonjour,
je veux créer une macro qui me copie une feuille d'un fichier du jour dont la case A1 de la premiere feuille contient la valeur de la forme (jj/mm/aaaa).
La macro cherchant un fichier .xls ayant le nom "aaaa" qui est l'année dans un dossier s'il le trouve on rentre à la boucle et s'il n'existe pas on le crée. une fois dans le fichier on cherche dans les onglets excel qui sont dedans et chercher: s'il ya un onglet ayant un nom du mois - termine par "mm"- on rentre dans la boucle sinon on crée un.
j'ai commencé à coder mais je me trouve dans des boucles!! et je ne vois pas la structure du truc!
Merci de me donner des avis s'il y en a.
Saf

[jojo86]

Salut,
Je ne comprends pas du tout ce que tu veux faire...
Je pense que tu vas devoir traiter le problème en plusieurs étapes sans vouloir tout faire d'un coup.
Par exemple, tu peux commencer à élaborer une macro qui copiera ton onglet suivant les conditions que tu souhaites.
Ensuite tu fais une autre macro qui ira rechercher le fichier aaaa etc...

Mais pour le moment il faut que tu explique plus clairement ton souhait.
Je te propose de commencer par expliquer Comment copier et Ou copier et en fonction de quoi?

Cordialement.

[mercatog]

Un exemple complet pour ouvrir (ou créer) un fichier année et copier des données vers la feuille mois de ce fichier (la créer si elle n'existe pas)
La macro est à mettre dans le fichier journalier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub Archivage()
Dim wbk As Workbook
Dim aSh As Worksheet, Sh As Worksheet
Dim Dossier As String, Fichier As String, Feuille As String
 
Dossier = "C:\Documents and Settings\Administrateur\Bureau\DossierTest\"    'Dossier de recherche
Application.ScreenUpdating = False
Set aSh = ThisWorkbook.Worksheets(1)                                            'aSh feuille 1 du classeur actuel
If IsDate(aSh.Range("A1").Value) Then
    Fichier = Dossier & Year(aSh.Range("A1").Value) & ".xls"                    'Nom du fichier à ouvrir ou créer
    'Feuille = CStr(Month(aSh.Range("A1").Value))                                'Nom de la feuille correspondant au mois 1,2...
    'ou bien
    'Feuille ="Texte"& format(Month(aSh.Range("A1").Value),"mm")                ''Nom de la feuille correspondant au mois Texte01, Texte02...
    'ou bien
    Feuille = MonthName(Month(aSh.Range("A1").Value))                            'Nom de la feuille correspondant au mois janvier, fevrier...
    On Error Resume Next
    Set wbk = Workbooks.Open(Fichier)                                           'On ouvre le fichier (s'il n'existe pas wbk reste vide
    On Error GoTo 0
    If wbk Is Nothing Then                                                      'Si wbk est vide càd fichier inexistant
        Set wbk = Workbooks.Add(1)                                              'On crée un nouveau fichier avec une seule feuille
        Set Sh = wbk.Worksheets(1)                                              'Sh feuille unique de ce nouveau classeur
        Sh.Name = Feuille                                                       'on nomme cette feuille
    Else                                                                        'Si wbk est non vide, le fichier à ouvrir est ouvert
        On Error Resume Next
        Set Sh = Worksheets(Feuille)                                            'on cherche la feuille du mois (si elle n'existe pas Sh reste vide)
        On Error GoTo 0
        If Sh Is Nothing Then                                                   'si Sh est vide càd feuille n'existe pas
            Set Sh = wbk.Worksheets.Add(after:=wbk.Sheets(wbk.Sheets.Count))    'on ajoute une feuille à la fin du fichier ouvert wbk
            Sh.Name = Feuille                                                   'on la nomme
        End If
    End If
    '----------------------------------------------------A ce stade on a le fichier ouvert avec le feuille du mois
    aSh.Range("A1:D20").Copy Sh.Range("A1")                                     'par exemple on copie A1:D20 du fichier du jour vers la feuille
    'ICI ON MET NOTRE CODE avec les variables feuilles aSh (feuille de départ) et Sh (feuille du mois dans le classeur de l'année
    '----------------------------------------------------
    ChDir Dossier                                                               'on change le repertoire
    Application.DisplayAlerts = False
    wbk.SaveAs Year(aSh.Range("A1").Value) & ".xls"                             'on sauveagrade le fichier
    Application.DisplayAlerts = True
    wbk.Close                                                                   'on le ferme
    Set wbk = Nothing
    Set Sh = Nothing
End If
Set aSh = Nothing
End Sub

[safouunette]

bonjour à tous,
mercatog c'est exactement ce que je cherchais!
Merci mille fois
cordialement