Discussion :

[andrea0]

* Bonjour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

LastLine = Range("D65536").End(xlUp).Row

Avec ca j'arrive à faire calculer la dernière ligne en colonne D.

Mais moi ce que je veux c lui faire calculer un LastLinePositif,la dernière ligne pour laquelle j'ai un chiffre positif en colonne D qui est trier(de la ligne 20 à cette LastLinePositif j'ai des chiffres positif et après des negatifs).

J'ai plusieurs onglets et donc j'en ai besoin pour la suite de ma macro.

Merci pour votre aide

[zazaraignée]

Fais une boucle Do... Loop avec un While ou un Until qui teste ta condition et un offset vers le haut pour passer à la cellule suivante.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Do While Range("D" & CStr(LastLine)).Value < 0
    LastLine = LastLine - 1
Loop

(pas testé)

[MarcelG]

Bonjour,

Dans le même esprit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Public Sub essai()
Dim c As Range
Set c = Range("A1")
Do While c.Value > 0
        Set c = c.Offset(1, 0)
        ligne = c.Row - 1
Loop
Debug.Print ligne
End Sub

Testé

[andrea0]

Merci zazaraignée de m'avoir lu (il ya un bug sur la première ligne je ne vois pas où est l'erreur)

Merci MarcelG ta macro marche bien
si je peux me permettre une dernière petite chose

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("AP(ligne+1):APLastLine").Select

ici j'ai ligne(la ligne que tu m'as aidé à calculer) et LastLine qui sont des variables dans ma boucle.

Mais la syntaxe n'est pas bonne ça bug

aurais-tu une idée ?

Merci encore pour votre aide

Par exemple si dans un onglet ligne=135 et Lastline=358 on a

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("AP136:AP358").Select

J'aimerai juste intégrer ces variables la dedans

[MarcelG]

Bonsoir Andréas,

Tu fais une erreur de concaténation.

L'une des syntaxes pour désigner un objet Range
est par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("AP10:AP20")

Il te faut donc rétablir ta chaîne de yexte, en respectant bien les doubles-cotes (")

Donc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("AP" & (ligne + 1) & ":AP" & LastLine).Select

exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Public Sub ESSAI()
ligne = 10
LastLine = 20
Range("AP" & (ligne + 1) & ":AP" & LastLine).Select
End Sub

Bien entendu, ligne et lastline sont à adapter à ton cas

[zazaraignée]

En supposant que la cellule active est dans la colonne qui nous intéresse :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Function DerniereLignePositive(colonne As Integer) As Long
    Dim ligne As Long
    ligne = Feuil1.Rows.Count
    ligne = Range(Chr(colonne + 64) & CStr(ligne)).End(xlUp).Row
    Do While Range(Chr(colonne + 64) & CStr(ligne)).Value < 0
        ligne = ligne - 1
    Loop
    DerniereLignePositive = ligne
End Function
 
Sub SelectionnerDernierePositive()
    Dim ligne As Long
    ligne = DerniereLignePositive(ActiveCell.Column)
    Range(Chr(ActiveCell.Column + 64) & CStr(ligne)).Select
End Sub

Si tu souhaites sélectionner toute la ligne, Il faut ajouter un EntireRow avant le Select :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Range(Chr(ActiveCell.Column + 64) & CStr(ligne)).EntireRow.Select

Code testé, cette fois-ci.

[Qwazerty]

Salut
Oula Zaza, y'a Cells

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function DerniereLignePositive(Colonne As Integer) As Long
    Dim ligne As Long
    With Feuil1
        ligne = .Cells(.Rows.Count, Colonne).End(xlUp).Row
        Do While .Cells(ligne, Colonne).Value < 0
            ligne = ligne - 1
        Loop
    End With
    DerniereLignePositive = ligne
End Function
 
Sub SelectionnerDernierePositive()
    Dim ligne As Long
    ligne = DerniereLignePositive(ActiveCell.Column)
    Cells(ligne, ActiveCell.Column).Select
End Sub

Pourquoi ne pas faire une boucle For each, ce serait plus élégant non ?
[Edit]
Ou encore, comme ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Function DerRangePositiv(Colonne As Range) As Range
 
With Colonne
    If .Worksheet.AutoFilterMode Then .Worksheet.AutoFilterMode = False
    .AutoFilter 1, ">0"
    Set DerRangePositiv = .Cells(.Rows.Count, 1).End(xlUp)
    .Worksheet.AutoFilterMode = False
End With
 
End Function
 
Sub essaiLP()
DerRangePositiv(Feuil1.Columns("A")).Select
End Sub

[/Edit]
++
Qwaz

[zazaraignée]

@ Qwazerty
Ouaip!
Comme on dit chez nous : « T'as pas tort, mon pétard » (en québécois vulgaire, le ort de tort et le ard de pétard se prononcent pareil, identique, semblable commac, quoi! Ça se dit toujours, commac (ou k, sais plus) ? )

[andrea0]

encore dsl pour le retard
j'ai pu tester ca que maintenant et ca marche très bien c exactementr ce que je voulais
Merci à vous tous.