Discussion :

[youpitralala]

Bonjour,

Je dois faire un traitement super simple... J'ai un fichier .CSV (séparateur ; - pas de caractères " au bout des chaines et il peut y avoir plusieurs ; consécutifs) dans lequel je veux insérer 4 colonnes vide entre E:E et F:F !

Et je coince bêtement parce que c'est un fichier .CSV

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim sNOM As String
Dim objWKB As Excel.Workbooks
Dim objSHT As Excel.Worksheet
 
sNOM = "C:\1738.csv"
 
Set objWKB = Application.Workbooks.OpenText(sNOM, SemiColumn:=True)

Et rien que là, ça marque quand je compile Fonction ou Variable attendue...

Si tout se passait bien (je voudrais rajouter ça au bout du code) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
    Set objSHT = objWKB.Sheets(1)
    objSHT.Activate
    Columns("F:F").Select
    Selection.Insert Shift:=xlToRight
    Selection.Insert Shift:=xlToRight
    Selection.Insert Shift:=xlToRight
    Selection.Insert Shift:=xlToRight
    Application.DisplayAlerts = False
    objWKB.Save
    objWKB.Close

Avez-vous une petite idée ?

Merci d'avance

Vincent

[Vadorblanc]

Bonjour youpitralala
Je viens de proposer un code à azsdcv discussion "Compilation de données Excel", je pense que tu peux essayer aussi, tu as la meme demande, par contre je ne comprends pas ta demande "J'ai un fichier .CSV (séparateur ; - pas de caractères", un fichier CSV est toujoiurs séparés par des points virgules non ?
Cordialement

[kiki29]

Salut, déjà

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Semicolon:=True

ensuite voir aide en ligne sur OpenText : [F1], sans oublier le post de Joel sur http://www.developpez.net/forums/d67...xt-separateur/

[youpitralala]

Bonjour à tous,

Mon problème ne vient pas tout à fait de l'ouverture du fichier .CSV mais de l'affectation du résultat dans un objet EXCEL.Workbooks

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
    Dim sNOMS As String, sNOMD As String
    Dim objWKB As Excel.Workbooks
    Dim objSHT As Excel.Worksheet
 
    sNOMS = "C:\1738.csv"
    sNOMD = "C:\1738.txt"
 
    ' J'ai essayé de passer par un .TXT intermédiaire
    Name sNOMS As sNOMD
 
    Set objWKB = Workbooks.OpenText(Filename:=sNOMD, Origin:=xlWindows, StartRow:=1, DataType:=xlDelimited, Semicolon:=True)

--> Génère Fonction ou variable attendue et s'arrête sur le OpenText

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
    Set objWKB = Application.Workbooks.OpenText(Filename:=sNOMD, Origin:=xlWindows, StartRow:=1, DataType:=xlDelimited, Semicolon:=True)

--> idem : fonction ou variable attendue

Si je mets juste la ligne ci dessous ça marche sauf que je veux faire un traitement 'invisible' donc je ne souhaite pas que des fenêtres s'ouvrent.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Workbooks.OpenText Filename:=sNOMD, Origin:=xlWindows, StartRow:=1, DataType:=xlDelimited, Semicolon:=True

La doc me dit pourtant s'applique à Workbooks (Collection)

La même ligne suivante fonctionne bien :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Set objWKB = Application.Workbooks.Open(Filename:=sNOMD)

Je tourne un peu en rond.......

Si quelqu'un a une idée du problème ou peut me donner un code qui fait le traitement suivant :

ouverture du fichier sNOM (format CSV)
Insertion de 4 colonnes en F:F
Sauvegarde + fermeture

Merci d'avance,

Vincent

[rvtoulon]

Bonjour,
il faut effectivement convertir ton fichier en .txt.
Je n'ai pas de probleme en faisant comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub inser_ligne_csv()
Dim chemin As String, fichier As String, sNOM As String
Dim objWKB As Workbook, objSHT As Worksheet
 
Application.ScreenUpdating = False
Application.DisplayAlerts = False
 
chemin = "C:\"
fichier = "1738.csv"
sNOM = "1738.txt"
 
Name chemin & fichier As chemin & sNOM
 
Workbooks.OpenText Filename:=chemin & sNOM, SemiColon:=True
 
Set objWKB = Workbooks(sNOM)
 
Set objSHT = objWKB.Sheets(1)
    With objSHT.Columns("F:F")
     For i = 1 To 4
      .Insert Shift:=xlToRight
     Next i
    End With
 
 
    objWKB.SaveAs Filename:=chemin & fichier, FileFormat:=xlCSV, local:=True
 
    objWKB.Close
Application.DisplayAlerts = True
Application.ScreenUpdating = True
End Sub

[setepenre]

Pour l'importation de ton csv :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Workbooks.OpenText Filename:="Chemin & nom du fichier", Origin:=xlWindows, StartRow:=1 _
     , DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
     ConsecutiveDelimiter:=False, Tab:=False, Semicolon:=True, Comma:=False _
     , Space:=False, Other:=False, FieldInfo:=Array(Array(1, 2), Array(2, 9), _
     Array(3, 9), Array(4, 9), Array(5, 9), Array(6, 9), Array(7, 1), Array(8, 9), Array(9, 9), TrailingMinusNumbers:=True

Il y aura autant d'Array qu'il y aura de colonnes.

Ensuite tu insères tes colonnes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    Columns("E:H").Select
    Selection.Insert Shift:=xlToRight

Ensuite tu sauvegardes en format csv

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    ActiveWorkbook.SaveAs Filename:= _
        "répertoire & nom fichier", FileFormat:=xlCSV, _
        CreateBackup:=False
    ActiveWorkbook.Close

[youpitralala]

Bonjour,

Effectivement l'affectation du Set objWKB en 2 fois marche parfaitement !

Merci, ça m'a tout résolu mon problème.

Vncent

[rvtoulon]

juste une remarque, dans le code que j'ai mis, l'instruction "name ... as ..." transforme ton fichier ici en Txt.
Mais comme à la fin de la macro tu enregistres ton fichier en ".csv" tu te retrouves avec deux fichiers a savoir un .txt et un .csv.
Il faut donc supprimer le .txt.
Dans le code que j'ai mis , on peux rajouter pour supprimer le .txt :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
objWKB.Close
Kill chemin & sNOM 'supprime le fichier snom = test.txt
Application.DisplayAlerts = True
Application.ScreenUpdating = True