Discussion :

[Esak59]

Bonjour à toutes et à tous.

Voila j'ai un gros souci que je n'arrive pas à résoudre encore une fois.

J'ai une interface qui fonctionne très bien (filtrage, userform, etc....)

Mais voila j'aimerais que mes combobox ignorent les cellules vides dans chaque colonnes sélectionnées.

Je vous joins un exemple qui vous permettra de bien situé ma demande ainsi que le code de mon userform.

Merci beaucoup

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Option Base 1
 
Private Sub UserForm_Initialize()
Dim LastLig As Long
Dim j As Long
Dim i As Byte
Dim n As Long
Dim ColCrit
Dim hWnd As Long
 
ColCrit = Array(1, 2, 3, 4, 5, 6)
 
With Sheets("exemple")
     .AutoFilterMode = False
        For i = 1 To UBound(ColCrit)  
            LastLig = .Cells(.Rows.Count, ColCrit(i)).End(xlUp).Row
        For j = 3 To LastLig
            Me.Controls("ComboBox" & i).Value = .Cells(j, ColCrit(i)).Value
        If Me.Controls("ComboBox" & i).ListIndex = -1 Then Me.Controls("ComboBox" & i).AddItem .Cells(j, ColCrit(i)).Value 
            Me.Controls("ComboBox" & i).ListIndex = -1
        Next j
With Me.Controls("ComboBox" & i)
                                       For x = 0 To .ListCount - 1 
                                                       For y = 0 To .ListCount - 1
 
        If .List(x) < .List(y) Then
            strTemp = .List(x)
                        .List(x) = .List(y) 
                            .List(y) = strTemp
 
End If
    Next y
        Next x
            End With
                Next i
                    End With

[Theze]

BOnjour Esak59,

Je n'ai pas pris la peine de télécharger ton fichier mais j'ai modifié ton code. Je pense que pour une meilleure lisibilité de ce dernier tu devrais adopter la façon de coder qu'ont les personnes ici à savoir incrémenter ton code, l'aérer et surtout, le commenter car ça facilite sa maintenance. J'ai supprimé ton tableau "ColCrit" car il ne sert à rien puisque les valeur se suivent de 1 à 6 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
 
Private Sub UserForm_Initialize()
 
    Dim LastLig As Long
    Dim J As Long
    Dim I As Byte
    Dim n As Long
    Dim hWnd As Long
 
    With Sheets("exemple")
        .AutoFilterMode = False
 
        'parcour les colonnes de A à F
        For I = 1 To 6
            'en recherche le n° de ligne de la dernière cellule non vide
            LastLig = .Cells(.Rows.Count, I).End(xlUp).Row
 
            'parcour les cellules de chaque colonnes
            For J = 3 To LastLig
 
                'évite les cellules vides
                If .Cells(J, I) <> "" Then
 
                    'affecte la valeur au combo concerné
                    Me.Controls("ComboBox" & I).Value = .Cells(J, I).Value
 
                    'si elle n'existe pas la rajoute
                    If Me.Controls("ComboBox" & I).ListIndex = -1 Then
                        Me.Controls("ComboBox" & I).AddItem .Cells(J, I).Value
                    End If
 
                    Me.Controls("ComboBox" & I).ListIndex = -1
 
                End If
 
            Next J
 
            'effectue un tri croissant dans le combo
            With Me.Controls("ComboBox" & I)
 
                For x = 0 To .ListCount - 1
 
                    For y = 0 To .ListCount - 1
 
                        If .List(x) < .List(y) Then
                            strTemp = .List(x)
                            .List(x) = .List(y)
                            .List(y) = strTemp
 
                        End If
 
                    Next y
 
                Next x
 
            End With
 
        Next I
 
    End With
 
End Sub

Hervé.

[Esak59]

Bonjour à toutes et à tous

Désolé pour cette réponse tardive.

J'ai adapter ton code, à mon projet car le fichier que le code que j'ai posté était à titre d'exemple.

Donc après quelques retouches par ici et par là, j'ai réussi à l'adapter comme il se doit.

Merci à toi encore Theze, pour toutes ces explications.