Discussion :

[elbrujo2323]

Bonjour à tous,

Je voudrais savoir s'il était possible de récuperer le résultat d'une procédure oracle appelée via mon mdb access sans utiliser ADODB, c'est à dire en utilisant DAO. En gros faire pareil que dans le tuto http://access.developpez.com/faq/?pa...l#OraProcStock mais sans utiliser ADODB.

Merci

[Tofalu]

DAO a été pensé pour travailler avec le moteur Jet. Je te recommande vivement d'utiliser ADODB

[=JBO=]

Bonjour elbrujo2323,

Poourquoi ne pas utiliser ADODB : Il semblerait que ce soit l'avenir... et aussi le présent .

Mais bon, pour les amateurs du "passé" (dont je suis) ce bon vieux DAO reste dans la course.

Via le moteur JET, DAO "classique" permet d'accéder à des sources de données ODBC au moyen de tables liées et de procédures SQL directes (que Access liste dans la fenêtre base de données), voire de base de données ODBC (à manipuler uniquement par programme VB/VBA/autres...).

Depuis DAO 3.5, il est aussi possible de créer une connexion directe vers un serveur ODBC au moyen de la technologie ODBCDirect (donc sans passer par le moteur JET) .
En autre apport à DAO, ODBCDirect permet d'exécuter des procédures stockées sur un SGBD en contrôlant "finement" les paramètres.

Je te donne ci-dessous une "conversion DAO" partielle du code que tu as référencé. Tu constateras qu'il n'y a pas de grandes différences.

Au passage, on remarque qu'il faut créer un workspace d'un type spécifique:
un workspace ODBCDirect, par opposition à workspace Jet.

DAO ODBCDirect est utilisable seulement par programmation (VB/VBA).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Public Sub ODBCDirect_RunStoredProc()
 
    Dim wrk As DAO.Workspace
    Dim cnn As DAO.Connection, strConnect As String
    Dim qdf As DAO.QueryDef
 
    ' Créer un workspace ODBCDirect nommé "ODBCDirect"
    ' * changer ce nom si besoin
    ' * le nom d'utilisateur et le mot de passe ODBC peuvent être spécifiés ici
    '   (ils n'ont pas de rapport avec le fichier de sécurité (MDW) par défaut)
    Set wrk = CreateWorkspace("ODBCDirect", "Admin", "", dbUseODBC)
 
    ' Modifier la chaîne de connexion pour l'adapter au cas particulier
    ' UID et PWD ne sont pas nécessaires si déjà spécifiés ds CreateWorkspace
    strConnect = "ODBC;DSN=W805;UID=LeLogin;PWD=LeMotDePasse;DATABASE=LaBase"
 
    ' Ouvrir une connexion
    Set cnn = wrk.OpenConnection("LaConnexion", dbDriverNoPrompt, False, strConnect)
 
    ' Créer un QueryDef pour l'exécution de la procédure stockée
    Set qdf = cnn.CreateQueryDef("RunStoredProc")
    With qdf
        ' Spécifier le SQL
        .SQL = "{call odbpack.proc(?,?,?)}"
        ' Spécifier les paramètres (sens et valeurs)
        .Parameters(0).Value = 1
        .Parameters(1).Direction = dbParamInputOutput
        .Parameters(1).Value = 2
        .Parameters(2).Direction = dbParamOutput
 
        ' Exécuter la requête
        .Execute
 
        MsgBox "Return Values from Proc are : " & _
                 .Parameters(1).Value & _
                 " and " & _
                 .Parameters(2).Value
    End With
 
    ' Fermer la requête et la connexion
    qdf.Close
    cnn.Close
End Sub