Discussion :

[jlm57]

Bonjour,

Je crée des radiobuttons par code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim RadioButton As New System.Windows.Forms.RadioButton
For i = 0 To NombreLigne
       RadioButton.Name = "RadioButton" & i.ToString
       RadioButton.Location = New Point(120, 150 + (i * 50))
       Controls.Add(RadioButton)
       RadioButton = New System.Windows.Forms.RadioButton
Next i

Seulement ces radiobutton n'exitent pas physiquement.

Lors de l'execution de mon appli, je clique sur les boutons et ils changent d'état.

Jusque là tout va bien.

Maintenant, j'aimerai capter le click sur les boutons et savoir sur lequel j'ai cliqué.

Comment dois-je commencer?
D'après ce que j'ai trouvé sur le net, il semble que je doive créer un évènement_click de toute pièce.

J'ai essayé. Je n'y arrive pas.

Merci pour votre aide, pour la solution la plus simple s'il y en a une que créer un évènement.

[Sehnsucht]

Bonsoir,

Il te fait en effet écrire une méthode qui servira à réceptionner l'évènement, sur le même schéma qu'une méthode "classique", en respectant la signature attendue par l'évènement:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub MyRadioButtons_Click(ByVal sender As Object, ByVal e As EventArgs)
    ' ici ton code
End Sub
 
' autre exemple avec MouseClick pour montrer la différence au niveau de la signature
Private Sub MyRadioButtons_MouseClick(ByVal sender As Object, ByVal e As MouseEventArgs)

Ensuite il faut abonner cette méthode aux évènements de tes RadioButton lors de leur création:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
For i As Integer = 0 To NombreLigne
    Dim rb As New RadioButton() With { _
        .Name = "RadioButton" & i.ToString(), _
        .Location = New Point(120, 150 + 50 * i) _
    } ' j'utilise une autre syntaxe mais le résultat est identique
 
    AddHandler rb.Click, AddressOf MyRadioButtons_Click
    Controls.Add(rb)
Next

Enfin, pour obtenir le RadioButton qui a déclenché l'évènement, il faut utiliser le paramètre sender, qui contient justement le contrôle/l'objet qui a déclenché l'évènement.
Attention, sender est de type Object, il faut donc penser à le caster pour accéder à ses propriétés (en partant du principe d'utiliser l'option Strict)
Penser également à vérifier si sender ne vaut pas Nothing et le type réel de sender avant de caster (par exemple si on abonne les évènements de plusieurs types de contrôle à la même méthode):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Private Sub MyRadioButtons_Click(ByVal sender As Object, ByVal e As EventArgs)
    If sender Is Nothing Then Throw New ArgumentNullException("sender")
    If TypeOf sender Is RadioButton Then
         Dim rb As RadioButton = DirectCast(sender, RadioButton)
         ' le reste du code utilisant rb...
    End If
End Sub

Cordialement !

[jlm57]

Merci infiniment, Sehnsucht

Pour ces explications extrèmement claires et simples.

Sur le net, c'est toujours tellement plus compliqué.

Mais en plus, c'est personnalisé.

Non seulement, j'ai tout compris et en plus çà a marché du 1er coup. Contrairement au net où il y a toujours des erreurs.

Cordialement