Discussion :

[hepav]

Bonjour
J'ai un problème pour mon impresion

Suite a remplissage de mon formulaire access2010 disponible sur tout les pc du réseau.
Je souhaite executer l'impression d'un fichier PDF sur une imprimante definit ("prt025") sans pour autant changer l'imprimante par defaut du pc definitivement.

J'ai donc ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Commande146_Click()
 
Dim stDocName As String
DoEvents
 
 
stDocName = Me.Texte8
Set wsh = CreateObject("WScript.Network")
wsh.SetDefaultPrinter "prt025"
 
ShellExecute Me.hwnd, "print", "S:\DEMLONE\Déclaration Incorporation\" & stDocName & ".PDF", "", "", 1
End Sub

mais je ne sais pas comment revenir a l'ancienne imprimante par défaut.

pouvez vous m'aider????

[Arkham46]

Bjr,

Il y a les fonctions SetDefaultPrinter et GetDefaultPrinter (à partir de win 2000/XP donc utilisables si Office 2010 installé) :

Dans un module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Option Compare Database
Option Explicit
 
Private Declare Function APISetDefaultPrinter Lib "winspool.drv" Alias "SetDefaultPrinterA" (ByVal pszPrinter As String) As Long
Private Declare Function APIGetDefaultPrinter Lib "winspool.drv" Alias "GetDefaultPrinterA" (ByVal pszBuffer As String, pcchBuffer As Long) As Long
 
Public Function GetDefaultPrinter() As String
Dim lPrinterName As String
Dim lSize As Long
APIGetDefaultPrinter vbNullString, lSize
lPrinterName = Space(lSize)
APIGetDefaultPrinter lPrinterName, lSize
GetDefaultPrinter = Left(lPrinterName, Len(lPrinterName) - 1)
End Function
 
Public Function SetDefaultPrinter(pPrinterName As String) As Boolean
' Renvoit True si succès
SetDefaultPrinter = (APISetDefaultPrinter(pPrinterName & vbNullChar) <> 0)
End Function

Pour l'utilisation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Dim lOldPrinter As String
lOldPrinter = GetDefaultPrinter
If SetDefaultPrinter("prt025") Then
    ShellExecute Me.Hwnd, "print", "S:\DEMLONE\Déclaration Incorporation\" & stDocName & ".PDF", "", "", 1
    SetDefaultPrinter lOldPrinter
Else
    MsgBox "Erreur : Impossible de définir l'imprimante pdf par défaut!"
End If

[hepav]

merci je viens d'ajouter ça et c'est nickel

encore merci

[Arkham46]

merci je viens d'ajouter ça et c'est nickel

encore merci

bien, alors il ne te reste plus qu'à cliquer sur le bouton que tu trouves en bas de la discussion pour la clore