Discussion :

[crissud]

Bonjour

J'ai des données dans plusieurs lignes et plusieurs colonnes.
J'ai pu écrire dans une macro un total à chaque colonne.

Je voudrais à présent avoir un total pour chacune des lignes de mon tableau.
Je ne connais pas le nombre de ligne, car il évolue au grès des données.

Or avec l'enregistreur de macro je n'arrive pas au résultat espéré

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub TotalLigne()
'
' o
'
Dim DerColonne
'
    DerColonne = Range("IV1").End(xlToLeft).Column + 1
 
        Range("A2").Select
    Selection.End(xlToRight).Select
    Range("E2").Select
    ActiveCell.FormulaR1C1 = "=SUM(RC[-3]:RC[-1])"
    Range("E2").Select
    Selection.AutoFill Destination:=Range("E2:E402"), Type:=xlFillDefault
    Range("E2:E402").Select
    Selection.NumberFormat = "#,##0.00"
    Range("I15").Select
End Sub

merci de votre aide

[mercatog]

Bonjour
Essaies ceci (sans les Select)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub TotalLignes()
Dim LastLig As Long
Dim LastCol As Integer
 
Application.ScreenUpdating = False
With Sheets("Feuil1")                                                'A adapter
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row                 'Ligne de la dernière cellule remplie de la colonne A
    LastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column + 1     'Colonne de la première cellule vide de la ligne 1
    .Cells(1, LastCol).Value = "TOTAL"
    .Range(.Cells(2, LastCol), .Cells(LastLig, LastCol)).Formula = "=Sum(B2:" & .Cells(2, LastCol - 1).Address(0, 0) & ")"
    .Range(.Cells(2, LastCol), .Cells(LastLig, LastCol)).NumberFormat = "#,##0.00"
End With
End Sub

[crissud]

Super
parfait

Merci
bon fin de week end
@+