Discussion :

[Manoutz]

facile, isn't it? le code de zelinho n'était pas bon

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
data test;
input test $50.;
cards;
Hard Rock
Histoire / Actualités
Humour-Théatre
Jazz
Jeunesse
Jeux Mac
Jeux Nintendo WII-DS
run;
 
DATA  test ;
	SET test;
 
		nom=translate(test,' ','-');
		nom=translate(nom,' ','/');
		nom5=strip(compbl(nom));
RUN;

[zellinho]

bah ... non ... c'est pas ça...

Tu me donnes ça :

Hard Rock
Histoire Actualités
Humour Théatre
Jazz
Jeunesse
Jeux Mac
Jeux Nintendo WII DS

et je veux ça :

Hard_Rock
Histoire_Actualités
Humour_Théatre
Jazz
Jeunesse
Jeux_Mac
Jeux_Nintendo_WII_DS

on s'approche quand même

[zellinho]

par contre ça :

DATA VAR_ARBO2 ;
SET VAR_ARBO;
nom2=translate(nom,' ',"'");
nom3=translate(nom2,' ','-');
nom4=translate(nom3,' ','/');
nom5=translate(strip(compbl(nom4)),'_',' ');
RUN;

ça marche !

youhou !!!

MERCI A TOUS POUR VOTRE PRECIEUSE AIDE !!!

[Manoutz]

ok je pensais tu voulais finir sur des espaces. Autant pour moi..

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
data test;
input test $50.;
cards;
Hard Rock
Histoire / Actualités
Humour-Théatre
Jazz
Jeunesse
Jeux Mac
Jeux Nintendo WII-DS
run;
 
DATA  test ;
	SET test;
 
		nom=translate(test,' ','-');
		nom=translate(nom,' ','/');
		nom5=strip(compbl(nom)); 
		nom6=translate(strip(compbl(nom5)),'_',' ');
RUN;

[suistrop]

Hello,

Avec une expression réguliere :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
DATA test;
input test $50.;
cards;
Hard Rock
Histoire / Actualités
Humour-Théatre
Jazz
Jeunesse
Jeux Mac
Jeux Nintendo WII-DS
run;
data test_1;
	set test;
test1 = prxchange("s/[\/ -]{1,}/_/",-1,strip(test));
run;

Suistrop

[Manoutz]

salut suistro,

sais tu ou trouver (toi ou qqn d'autre) de la bonne doc sur le prx?

[suistrop]

Hello,

Je ne connais de site en particulier, j'ai entendu parler des expression reguliere quand j'ai débuter en php.

Le mieux est de taper REGEXP dans google.

Pour sas je connais que 2 facons de les utiliser :

C = PRXMATCH ("/REGEXP/",T1) ;
Ou T va prendre la premiere valeur du caractere rencontré dans l'expression réguliere et 0 sinon.

T1 = PRXCHANGE ("s/REGEXP1/REGEXP2/", -1, T0) ;
Ici on remplace la premiere expression réguliere par la seconde. dans la variable T0. le -1 indique qu'on le fait autant de fois que necessaire.

Apres il faut s'entrainer et poser des questions !

Suistrop.

[s_a_m]

Bonjour;

ici

A noter que ces expressions sont extrêmement puissantes ;

Moi je n’utilise presque pas de LIKE mais de PRXMATCH.
A noter que ces fonctions sont beaucoup utilisées dans le langage perl ( en tout les cas moi je les utilise beaucoup)

[Géraldine_Cade_SAS]

Bonjour,

Dans ce cas il faut traiter le séparateur " / " à part de "/". Les fonctions TRANWRD ou TRANSLATE peuvent être utilisées pour remplacer un caractère ou une chaîne de caractères. TRIM et LEFT vont servir à supprimer les blancs ajouter par tranwrd.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
data a ;
input valeur $ 1-30 ;
cards ;
Hard Rock
Histoire / Actualités
Humour-Théatre
Jazz
Jeunesse
Jeux Mac
Jeux Nintendo WII-DS
;
run ;
data b ;
	set a ;
	put valeur = ;
	valeur=tranwrd ( valeur , ' / ', '_') ;
	valeur=tranwrd ( valeur , '/', '_') ;
	valeur=tranwrd ( valeur , ' - ', '_') ;
	valeur=tranwrd ( valeur , '-', '_') ;
	valeur=tranwrd ( trim(left(valeur)) , ' ', '_') ;
	put valeur = ;
run ;

Je pense que ça donne bien le résultat voulu.

Géraldine CADE-DESCHAMPS
Support Clients SAS