Discussion :

[Pier3d]

Bonjour,

J'ai écrit une macro qui permet de formater des données brutes qui alimentent, sur une autre feuille, 4 tableaux croisés dynamiques. Ceci se répète trois fois dans le classeur : une feuille de données suivie d'une feuille de tabeaux, ect.

À la fin de la macro, avant de redonner le contrôle à l'utilisateur, je désire ramener la sélection à A2 dans chacune des 6 feuilles question d'uniformiser la vue. J'ai donc écrit ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
' Remise de la sélection à "A1" pour toutes les feuilles
On Error Resume Next
 
For Feuille = 1 To Worksheets.Count    
    Sheets(Feuille).Select
    Range("A2").Select
Next Feuille

Puis, je me suis posé la question : Select ou Activate ?

J'ai essayé les deux et je n'ai pas vu de différence évidente. J'ai donc refilé la question à notre ami Google et je suis arrivé ici sur une discussion daté de 2005.

En gros, on disait que la question n'a plus vraiment d'importance vu que ces deux commandes (méthodes ?) sont de moins en moins employées presque, si j'ai bien compris, passées en désuétude. Et, on me suggère plutôt ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim f As Worksheet
 
  For Each f In ThisWorkbook.Worksheets
    f.Activate
    f.Range("A1").Activate
  Next

Je comprends qu'utiliser un boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each

est plus « moderne » que la bonne vieille boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Next

mais c'est la double présence de la méthode Activate qui m'étonne. Après qu'on m'ait dit qu'elle était en voie de dispartition. Voici la phrase exacte :

Envoyé par alsimbad
sans oublier bien sur que ces deux outils sont quasiment inutiles a une ou deux exceptions près.

Je suis probablement un exemple parfait d'une de ces deux exceptions...

Pour revenir à la bouche For Each, je l'emploi souvent. Chaque fois que je pense que le code sera plus compact et efficace. Mais dans le cas que je vous présente au début, c'était pas mal kif kif.

Du moins, je le crois. Est-ce que je me trompe ? Je suis un vieux qui a appris le basic au début des années 80. J'ai travaillé fort, plus tard, pour passer de Wordbasic à VBA. Je suis ici pour apprendre.

Pierre


---

[patricktoulon]

bonjour

comme ca a la volée
histoire de ne pas voir les pages défiler tu pourrais faire comme ca:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub select_a2()
Application.ScreenUpdating = False
For Each feuille In ThisWorkbook.Worksheets
feuille.Activate
[A2].Select
Next
'ici on revient a la page ou tu veux revenir
Sheets(" nom de la feuille sur la quelle tu veux revenir").Activate
[A2].Select
 
End Sub

au plaisir

[OrDonc]

Bonsoir,

histoire de n'utiliser ni Select ni Activate :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Application.ScreenUpdating = False
For Feuille = 1 To Worksheets.Count
    Application.Goto Sheets(Feuille).Range("A2")
Next Feuille
   'ou
Application.ScreenUpdating = False
For Each sh In Worksheets
  Application.Goto Sheets(sh.Name).Range("A2")
Next

[kiki29]

Salut,et la boucle est bouclée : http://www.developpez.net/forums/d10...-excel-2007-a/

[Patrice740]

Bonjour Pier3d

... , je désire ramener la sélection à A2 dans chacune des 6 feuilles question d'uniformiser la vue. ...

Puis, je me suis posé la question : Select ou Activate ?

Dans ce cas la question ne se pose pas : il faut utiliser Select ou éventuellement Goto.

J'ai essayé les deux et je n'ai pas vu de différence évidente.

La différence est visible lorsque la sélection (initiale) comprend plusieurs éléments (feuilles ou cellules), deux cas peuvent se présenter :

• l'activation porte sur un élément qui appartient à la sélection : l'élément est activé mais la sélection n'est pas modifiée.
• l'activation porte sur un élément qui n'appartient pas à la sélection : l'élément est sélectionné et activé.

Tu peux essayer le sélectionner des plages de cellules contenant A2 et d'autres sans A2, dans plusieurs feuilles. Tu peux aussi essayer de sélectionner toutes les feuilles.
Lance chacune des deux macros (avec .Activate puis avec .Select) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub Activer()
Dim Idx As Integer
  For Idx = 1 To Worksheets.Count
    Worksheets(Idx).Activate
    ActiveSheet.Range("A2").Activate
  Next Idx
End Sub
 
Private Sub Sélectionner()
Dim Idx As Integer
  For Idx = 1 To Worksheets.Count
    Worksheets(Idx).Select
    ActiveSheet.Range("A2").Select
  Next Idx
End Sub

et là tu verra la différence : Activate ne répond pas entièrement à ton cahier des charges.

Quand à l'utilisation de For Each ou For To, la seconde mobilise moins de mémoire, mais il semblerait qu'aujourd'hui ce ne soit plus un critère prépondérant.

Cordialement
Patrice

[Pier3d]

Bonjour,

Merci à tous pour vos réponses. Soyez assurés qu'elles sont étudiées, testées et appréciées.

@kiki29 :

Salut,et la boucle est bouclée : http://www.developpez.net/forums/d10...-excel-2007-a/

Pas tout à fait. Je me suis peut-être mal exprimé mais cette fois je vais être clair.

@OrDonc : Merci, me voici maintenant avec trois options et grâce à vous je viens de découvrir cette version de Goto.

Maintenant, je m'explique : En fait, ce n'est pas tant la sélection de [A1] dans chaque feuille que je désire comme de présenter la vue de cette cellule en haut à gauche de la fenêtre (de l'écran).

L'enregistreur de macro est terriblement déficient à ce propos. Si je suis sur la cellule G134 et que je la vois, et que je fais Ctrl-home, je me trouve à aller à [A1] et, pouf !, la vue se déplace et JE VOIS [A1]. L'enregistreur de macro, lui, me dit seulement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("A1").Select

Or si je place ce code dans ma macro, la cellule [A1] est bien sélectionnée mais rien ne bouge. Ma vue reste à la ligne 134.

La vraie question finalement est : comment fait-on, par programmation, pour ramener la vue en haut et à gauche de la feuille ? Quel code serait l'équivalent de Ctrl-home ?

Et je viens de le découvrir en allant dans l'Aide lire un peu sur la méthode

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.Goto

proposée par OrDonc. Il y a un paramètre « Défilement » qu'on peut ajouter à Goto. Et voici le code qui fait le travail :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
For Each Feuille In Worksheets
  Application.Goto Reference:=Worksheets(Feuille.Name).Range("A2"), Scroll:=True
Next Feuille

Encore une fois merci à tous. Je considère ce problème comme « Résolu ! ». Cependant, j'hésite à cliquer sur le bouton Résolu de peur que ça empêche l'ajout d'autres intéressants commentaires. Est-ce le cas ?

Pier3d


---

[mercatog]

Bonjour

J'ai écrit une macro qui permet de formater des données brutes qui alimentent, sur une autre feuille, 4 tableaux croisés dynamiques.

Je ne doute guère que sur cette macro tu utilise des Select.
La question de fond, pourquoi faire des sélections et chercher la(es) méthode(s) pour faire marche arrière.

Mais, grâce à ce sujet et à OrDonc, j'ai pris connaissance de Application.Goto (En fait, je n'en avais jamais besoin auparavant)

[Patrice740]

Bonjour,

La vraie question finalement est : comment fait-on, par programmation, pour ramener la vue en haut et à gauche de la feuille ? Quel code serait l'équivalent de Ctrl-home ?

Pour visualiser la cellule A1 de chaque feuille, sans modifier la sélection :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
  Dim wsh As Worksheet
  For Each wsh In ThisWorkbook.Worksheets
    wsh.Activate
    ActiveWindow.ScrollRow = 1
    ActiveWindow.ScrollColumn = 1
  Next wsh
End Sub

Patrice

[Pier3d]

Merci Patrice740.

Oui, après avoir découvert le Scroll (défilement) de Application.Goto, j'ai bien pensé que cette méthode devait exister aussi pour d'autres éléments de l'application, principalement les fenêtres. Mais comme, dans mon présent projet, je désire en même temps sélectionner A1 et afficher le haut gauche de la fenêtre, le Goto me convient très bien. J'aurai certainement des occasions pour utiliser Windows.Scroll dans le futur.

@ mercatog :

Je ne doute guère que sur cette macro tu utilise des Select.

Hé oui. La macro comprend 480 lignes sur 3 procédures et dont 51 lignes de commentaires. La méthode Select est appelé 51 fois contre 11 fois pour Activate. C'est mal ?

La question de fond, pourquoi faire des sélections et chercher la(es) méthode(s) pour faire marche arrière.

Je ne pense pas faire souvent marche arrière... La marche de la macro est progressive, du point A au point B sans détour.

J'ai de la difficulté à imaginer comment on peut se passer de Select.

Mais, grâce à ce sujet et à OrDonc, j'ai pris connaissance de Application.Goto (En fait, je n'en avais jamais besoin auparavant)

Vous êtes bien chanceux ! Pour moi, cela répond à un besoin que j'avais depuis longtemps. Bien sûr, comme me l'a expliqué Patrice740, il y a aussi le Windows.Scroll. Mais je désire également laisser le contrôle à l'utilisateur en ayant le curseur sur A1.

Pierre (très heureux de connaître ce merveilleux forum)


---

[mercatog]

Bonjour

La méthode Select est appelé 51 fois contre 11 fois pour Activate. C'est mal ?

Oui, c'est trop mal.

Un exemple (je suis en Feuil1 et je lance cette macro)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
sheets("Feuil3").Activate
Range("X450").Select
Selection.Interior.Color=vbRed

à la fin de la macro, je suis en Feuil3 et X450 a été colorée en rouge. Mais pour revenir où j'étais (en Feuil1), je dois faire marche arrière.

Maintenant, (je suis en Feuil1 et je lance cette macro)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Sheets("Feuil3").range("X455").Interior.Color=vbRed

à la fin de ma macro, je suis resté dans ma place et X455 de Feuil3 a été bel et bien colorée en rouge.

Les Select et les Activate sont sûrement à éviter parce qu'ils sont source d'instabilité du code et de perte de temps

On peut toujours travailler sans elles en instanciant convenablement les objets.

Pour écrire dans une cellule X d'une Feuille Y (d'un classeur même classeur), on peut faire directement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Sheets(Y).Range(X).Value="Toto"

[Vadorblanc]

Bonjour
J'ai défendu aussi les "Select ou Activate" car il me semblait que le code fonctionnait bien avec, mais avec le temps on apprend et je confirme les précisions du grand Mercatog le code est instable, des erreurs surviennent, il faut le plus possible supprimer ses 2 termes toujours issus par l'enregistreur de macro qui est indispensable pour les débutants mais ensuite apprendre à épurer le code de ses "Select ou Activate".
Un code avec des "Select ou Activate" est un code de débutant.
Un code sans "Select ou Activate" est un code de professionnel, et il faut du temps et des déclics pour bien en comprendre tous les avantages > un code stable, une écriture magistrale…

Cordialement

[Patrice740]

Bonjour,

Je suis entiérement d'accord avec mercatog quand il dit :

Les Select et les Activate sont sûrement à éviter parce qu'ils sont source d'instabilité du code et de perte de temps

Par contre je n'arrive pas à comprendre ceci :

Un code avec des "Select ou Activate" est un code de débutant.
Un code sans "Select ou Activate" est un code de professionnel

J'ai souvent eu un problème similaire à celui de Pier3d :

À la fin de la macro, avant de redonner le contrôle à l'utilisateur, je désire ramener la sélection à A2 dans chacune des 6 feuilles question d'uniformiser la vue.

Bien évidemment, dans mes macros, l'utilisation de select est limité au strict indispensable.
Je précise qu'en général (et c'est probablement vrai pour Pier3d), c'est l'utilisateur qui est responsable des sélections éparpillées dans le fichier.

@ Vadorblanc :
Comment le professionnel est-il capable de résoudre ce problème sans utiliser Select (ni Goto et encore moins Activate qui de toute façon ne répond pas au besoin) ???

Patrice

[Philippe Tulliez]

Bonjour,
Voici un autre code qui manipule directement l'objet Feuille sans passer par sa propriété Name

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim Feuille As Worksheet
 For Each Feuille In Worksheets
  Application.Goto Reference:=Feuille.Range("A2"), Scroll:=True
 Next

Comment le professionnel est-il capable de résoudre ce problème sans utiliser Select (ni Goto et encore moins Activate qui de toute façon ne répond pas au besoin) ???

Comme il s'agit ici de donner le focus à la cellule A2 de chaque feuille, je ne vois pas comment l'éviter.
Cependant si c'est pour modifier la valeur ou la propriété d'une ou plusieurs cellules sans changer le focus d'une cellule de la feuille, il ne faut absolument pas utiliser Activate et Select.

[mercatog]

Bonjour à tous
Toutes les approches sont plus ou moins valables (dans une certaine mesure)
Une autre proposition c'est d'utiliser l'évènement SheetActivate du workbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
On Error Resume Next 'au cas où on a des feuilles graphiques
Range("A2").Select
End Sub