Discussion :

[wyzer]

Bonjour,

Actuellement je suis en train d'apprendre VBA pour Excel par le biais d'un livre, et aussi grâce à vous sur ce forum

Dans ce livre, l'auteur dit qu'un code VBA fonctionne plus rapidement en travaillant sur des données stocké en mémoire plutôt que sur une feuille

Jusque là ok

Mais dans mon cas je ne vois pas comment faire

Car dans ma boite j'occuppe un poste de "chargé d'extraction", ça veut dire que je fais des extractions toute la journée puis je les remets en forme

Voici ma méthode de travaille :

Dans le logiciel d'extraction, je selectionne en format de sortie "Fichier Excel"

Puis je développe une macro spécifique qui va remettre en forme ce fichier brut

Dans les options de sorties, j'ai aussi "vers le presse papiers"

Donc je comprends bien que c'est ce format de sortie qu'il faut privilégié, mais comme je ne vois pas les données, ça me semble abstrait comme technique

Pourriez-vous me dire comment vous faite pour manipuler des données en mémoire ?

Merci par avance

[mercatog]

Bonjour
Pour les mises en formes, tu n'as pas d'autre variantes que de travailler sur la feuille excel.
Pour les opérations sur les valeurs des cellules par exemple, tu peux passer par un tableau intermédiaire, tu y travaille et enfin tu transmet le résultat sur la feuille. C'est en général plus rapide que de faire les mêmes opérations directement sur la feuille, surtout pour les quantités de données importantes.

[wyzer]

Est-ce que tu pourrais me donner un exemple d'opérations à l'aide d'un tableau intermédiaire stp ?

Car j'ai encore un peu de mal avec les termes théorique, je comprends mieux lorsque je vois le code

Merci

[mercatog]

Par exemple; nous avons 70000 données numérique en colonne A et en colonne B on veux récupérer 2*A-5
(Bon, c'est un mauvais exemple car en formule c'est direct)

Teste ces 2 codes:
1. Directement sur la feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Test1()
Dim i As Long
 
With Sheets("Feuil2")
    For i = 1 To 70000
        .Range("B" & i).Value = 2 * .Range("A" & i).Value - 5
    Next i
End With
End Sub

2.A l'aide d'un tableau intermédiaire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Test2()
Dim i As Long
Dim Tb
 
With Sheets("Feuil2")
    'On récuppère dans Tb les données de la colonne A (en bloc)
    Tb = .Range("A2:A70000")
    'On fait notre traitement sur le tableau Tb et non directement sur A2:A70000
    For i = 1 To UBound(Tb)
        Tb(i, 1) = 2 * Tb(i, 1) - 5
    Next i
    'On réinjecte les résultat (en bloc) sur la feuille
    .Range("B2:B70000") = Tb
End With
End Sub

Edit: le premier code s'exécute en 23s, le deuxième en 0.35s
D'où l'intérêt

[wyzer]

Excellent !!!!!!!!!!!

je comprends maintenant !!!!


Merci beaucoup pour tes explications qui vont m'aider à gagner beaucoup de temps (car je travaille souvent sur des fichiers de 91 000 lignes sur 13 colonnes) !!