Discussion :

[Tydher]

Bonjour à tous

Je souhaiterai supprimé des colonne qui sont comprises entre deux bornes.
Chaque bornes correspond à un texte précis dans la ligne 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
i = 1
limiteMin = 0
limiteMax = 0
For i = 1 To nombreColonne
    Cells(1, i).Select
    If Cells(1, i) = "xxx" Then
        limiteMin = i
    End If
    If Cells(1, i) = "yyy" Then
        limiteMax = i
    End If
Next i

Ensuite je récupere les bornes et tente de supprimé la plage avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("limiteMin:limiteMax-3").Delete Shift:=xlToLeft

Mais sans succès.
J'ai essayé diverses méthodes, mais je pense que c'est un probleme de syntaxe

L'erreur est :
Erreur d'execution 1004
La methode Range de l'objet _Global à echoué

En mode débogague ma ligne Range correspond à :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("13:61")....

qui sont bien les colonnes que je souhaite supprimé.

Votre aide sera la bienvenue

Merci

[mercatog]

Bonjour
une poposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim c As Range
Dim Deb As String, Fin As String
 
Application.ScreenUpdating = False
With Sheets("Feuil1")                                                'à adapter
    Set c = .Rows(1).Find("xxx", LookIn:=xlValues, lookat:=xlWhole)
    If Not c Is Nothing Then Deb = c.Address
    Set c = .Rows(1).Find("yyy", LookIn:=xlValues, lookat:=xlWhole)
    If Not c Is Nothing Then
        If c.Column > 3 Then Fin = c.Offset(0, -3).Address
        Set c = Nothing
    End If
    If Len(Deb) * Len(Fin) > 0 Then .Range(Deb & ":" & Fin).EntireColumn.Delete
End With

[Tydher]

Merci pour votre réponse rapide.

Après l'avoir adapter, le code fonctionne.

J'ai aussi réussi avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range(Cells(1, limiteMin), Cells(1, limiteMax - 3)).EntireColumn.Delete

Merci encore

[mercatog]

Une précision quand même, utiliser la méthode Find est plus rapide que de faire une boucle sur ta ligne.
Bon, dans ce cas ce n'est pas très significatif mais c'est l'idée. Toujours préférer les méthodes directes aux boucles si elles donnent le même résultat.

[Tydher]

Bon à savoir pour l'avenir.

Merci encore