Discussion :

[Wawa07]

Bonjours à tous,
Je viens vous voir car j'ai une requête à vous faire.
J'ai un fichier avec une liste de donnée (+ de 3000) classées selon la date de commande. Le problème c'est que le logiciel me les donne toutes les unes à la suite des autres depuis la première commande.
j'ai donc créer un fichier excel pour les classer année par année (un onglet par moi; et un classeur par année).
Un classeur se présente avec une page contenant la liste des commandes (que je colle); un onglet par mois; et un onglet dans lequel je renseigne les périodes pour chaque onglet. Par exemple, pour le mois de janvier, je note la date de début de période et la date de fin de période. J'aimerais qu'automatiquement les données correspondantes soient copiées à partir de la loooongue liste, puis collées dans l'onglet correspondant.

Je ne sais pas si j'ai réussi à vous faire comprendre ce que je veux dire :s,
En tout cas je vous suis reconnaissant de l'attention que vous me porterez
Merci d'avance et à bientôt


Enfin si vous avez un autre moyen de faire, je suis preneur

[mercatog]

Bonjour
Fais un filtre automatique et copie le résultat du filtre vers l'onglet correspondant.

[Wawa07]

Salut,
Oui, c'est ce que je fais pour le moment (filtre automatique personnalisé> avec le critère supérieur à ... et inférieur à ...). Le problème q'est que c'est très long (surtout pour une gestion quotidienne); c'est pour ça que j'aurait aimer trouver une technique plus simple avec la moins de manip possible

D'autres idées ?

J'étais parti dans l'idée de faire une plage de critères (à la page "page") avec une date de début et de fin pour chaque mois.

Merci

[mercatog]

Déjà à l'aide de l'enregistreur de macro tu peux traduire les manipulations manuelles en code (à épurer). C'est une première piste.

Exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Option Explicit
 
Sub Dispatch()
Dim Wbk As Workbook
Dim LastLig As Long
Dim Chemin As String
Dim AnDeb As Integer, AnFin As Integer, j As Integer
 
Application.ScreenUpdating = False
Chemin = ThisWorkbook.Path & "\"
With ThisWorkbook.Worksheets("Commandes")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    AnDeb = Year(DateValue(.Range("C2")))
    AnFin = Year(DateValue(.Range("C" & LastLig)))
    For j = AnDeb To AnFin
        .Range("C1:C" & LastLig).AutoFilter Field:=1, Criteria1:=CStr(j) & "-*"
        Set Wbk = Workbooks.Add(1)
        Wbk.Worksheets(1).Name = "Commandes" & j
        .UsedRange.SpecialCells(xlCellTypeVisible).Copy Wbk.Worksheets(1).Range("A1")
        DispatchMois Wbk, j
        Application.DisplayAlerts = False
        Wbk.SaveAs Chemin & "Data" & j
        Application.DisplayAlerts = True
        Wbk.Close
        Set Wbk = Nothing
        .AutoFilterMode = False
    Next j
End With
End Sub
 
Sub DispatchMois(Wbk As Workbook, Annee As Integer)
Dim Sh As Worksheet
Dim LastLig As Long
Dim j As Byte
 
Application.ScreenUpdating = False
With Wbk.Worksheets(1)
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    For j = 1 To 12
        .Range("C1:C" & LastLig).AutoFilter Field:=1, Criteria1:=CStr(Annee) & "-" & CStr(Format(j, "00")) & "-*"
        Set Sh = Wbk.Worksheets.Add(After:=Wbk.Worksheets(Wbk.Worksheets.Count))
        Sh.Name = MonthName(j)
        .UsedRange.SpecialCells(xlCellTypeVisible).Copy Sh.Range("A1")
        Set Sh = Nothing
        .AutoFilterMode = False
    Next j
End With
End Sub

[Wawa07]

Ah oui c'est une bonne idée, j'ai plus ou moins bidouillé pour que ca fasse pas n'importe quoi, mais ca marche. Ca me fait 1 macro par mois, mais bon c'est pas vraiment un problème ça...

Merci, à bientot

[mercatog]

j'ai plus ou moins bidouillé pour que ca fasse pas n'importe quoi, mais ca marche. Ca me fait 1 macro par mois

Explique davantage.

Le code proposé permet de filtrer les données par année et crée un classeur par année.
Ensuite dans chaque classeur créé, les données sont filtrées par mois et les feuilles mensuelles sont créées où sont reportés les données du mois.