Discussion :

[Nikodemus]

Bonjour,

Je souhaiterai imprimer ma feuille EXCEL au format PDF sans avoir à le nommer ni sélectionner le répertoire de destination.

Quand je fais cette macro :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.PrintOut Preview:=False, ActivePrinter:="Adobe PDF"

La fenêtre PDF me demande le répertoire et le nom du fichier.

Avec celui-ci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dossier = "M:\Test.pdf"
ActiveSheet.PrintOut Preview:=False, ActivePrinter:="Adobe PDF", PrintToFile:=True, PrToFileName:=Dossier

Le fichier PDF est endommagé et impossible à ouvrir.

Et avec celui-ci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:="M:\Test.pdf

Cela ne fonctionne pas car ma version d'EXCEL n'est pas bonne.

Quelle solution me reste t'il ?
Merci d'avance.

(PS : Je bosse avec Excel 2003 et PDFCreator)

[kiki29]

Salut, si Acrobat Distiller voir sur http://www.developpez.net/forums/d43...bat-distiller/ .Avec PrintToFile en fait tu génères un fichier PS ( PostScript ) et non PDF

Si PDFCreator tu devrais aboutir à qqch comme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Option Explicit
 
Sub TstPdfCreator()
Dim JobPDF As Object
Dim sNomPDF As String
Dim sCheminPDF As String
 
    sNomPDF = "Essai.pdf"
    sCheminPDF = ThisWorkbook.Path & "\"
 
    Set JobPDF = CreateObject("PDFCreator.clsPDFCreator")
 
    With JobPDF
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Initialisation de PDFCreator impossible", vbCritical + vbOKOnly, "PDFCreator"
            Exit Sub
        End If
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
        .cOption("AutosaveDirectory") = sCheminPDF
        .cOption("AutosaveFilename") = sNomPDF
 
        '   0=PDF, 1=Png, 2=jpg, 3=bmp, 4=pcx, 5=tif, 6=ps, 7=eps, 8=txt
        .cOption("AutosaveFormat") = 0
        .cClearCache
    End With
 
    Sheets("Feuil2").PrintOut copies:=1, ActivePrinter:="PDFCreator"
 
    Do Until JobPDF.cCountOfPrintjobs = 1
        DoEvents
    Loop
    JobPDF.cPrinterStop = False
 
    Do Until JobPDF.cCountOfPrintjobs = 0
        DoEvents
    Loop
 
    JobPDF.cClose
    Set JobPDF = Nothing
End Sub

[Nikodemus]

Exactement ce dont j'avais besoin avec PDFCreator. Ca marche nickel.
Merci bien