Discussion :

[aminee1666]

Bonjour,
J'utilise une connexion ADODB pour récupérer, depuis un fichier excel le contenu de la première feuille d'un classeur Excel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub RequeteClasseurFerme()
    Dim Cn As ADODB.Connection
    Dim Fichier As String
    Dim NomFeuille As String, texte_SQL As String
    Dim Rst As ADODB.Recordset
 
    'Définit le classeur fermé servant de base de données
    Fichier = "C:\monClasseurBase.xls"
    'Nom de la feuille dans le classeur fermé
    NomFeuille = "Feuil1"
 
    Set Cn = New ADODB.Connection
 
    '--- Connection ---
    With Cn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = "Data Source=" & Fichier & _
            ";Extended Properties=Excel 8.0;"
        .Open
    End With
    '-----------------
 
    'Définit la requête.
    '/!\ Attention à ne pas oublier le symbole $ après le nom de la feuille.
    texte_SQL = "SELECT * FROM [" & NomFeuille & "$]"
 
    Set Rst = New ADODB.Recordset
    Set Rst = Cn.Execute(texte_SQL)
 
    'Ecrit le résultat de la requête dans la cellule A2
    Range("A2").CopyFromRecordset Rst
 
    '--- Fermeture connexion ---
    Cn.Close
    Set Cn = Nothing
 
End Sub

Jusque là tout va bien et tout fonctionne correctement.
Mon problème vient de la variable NomFeuille, qui pour l'instant est définie en dur dans le code. Mon programme importe des donnée pour différents fichier et à chaque fois il va y avoir un nom différent de la feuil

D'où ma question : Comment récupérer le nom de la première feuille d'un classeur excel fermé ?

Merci d'avance pour vos réponses

[kiki29]

Salut, à lire http://silkyroad.developpez.com/VBA/ClasseursFermes/
On récupére le nom des feuilles mais dans l'ordre alphabétique

[aminee1666]

Bonjour,
j'ai déjà vu ce document, et je n'ai pas trouvé comment trouver le nom des feuilles d'un classeur fermé

cordialement

[kiki29]

Re, dans ce cas c'est vraiment grave, relis ceci http://silkyroad.developpez.com/VBA/ClasseursFermes/#LV
Extrait

Si vous travaillez sur des fichiers Excel fermés, vous aurez peut être besoin de récupérer des informations sur leur structure: Lister le nom des feuilles, vérifier si une feuille spécifique existe, contrôler le format d'un champ...etc...Les modèles ADO et ADOX permettent d'obtenir ces données.

[aminee1666]

Bonjour kiki,

j'ai modifie le code, par contre j'ai une erreur : '' erreur d’automatisation "

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
 Sub CommandButton1_Click()
 
 
  Dim Cn As ADODB.Connection
    Dim oCat As ADOX.Catalog
    Dim Fichier As String, Resultat As String
    Dim Feuille As ADOX.Table
    Dim Rst As ADODB.Recordset
 
    Dim texte_SQL As String
 
 
   Fichier = Application.GetOpenFilename("Fichier Excel, *.csv; *.xlsm;*.xls;*.xla")
 
    Set Cn = New ADODB.Connection
    Set oCat = New ADOX.Catalog
 
    Cn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Fichier & _
            ";Extended Properties=Excel 8.0;"
 
    Set oCat.ActiveConnection = Cn
 
    For Each Feuille In oCat.Tables
        Resultat = Resultat & Feuille.Name & vbCrLf
    Next
 
 
    MsgBox Resultat
 
 
    texte_SQL = "SELECT * FROM [" & Resultat & "$]"
 
    Set Rst = New ADODB.Recordset
    Set Rst = Cn.Execute(texte_SQL)
 
    'Ecrit le résultat de la requête dans la cellule A2
    Range("A2").CopyFromRecordset Rst
 
    '--- Fermeture connexion ---
 
    Set Feuille = Nothing
    Set oCat = Nothing
    Cn.Close
    Set Cn = Nothing
 
 
End Sub

Je voulais savoir, est ce que c juste la ligne : texte_SQL = "SELECT * FROM [" & Resultat & "$]"

Merci d'avance
cdt

[kiki29]

Salut, encore un drame du copier/coller ....
Ne conserve qu'un nom de feuille dans Resultat
Dans texte_SQL enleve le $ en fin de chaine

[aminee1666]

Bonjour,

je suis toujours bloqué sur la récupération du nom de la feuille du mon classeur.
Merci pour vos aides


cdt,

[kiki29]

Salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Option Explicit
 
Sub Tst()
Dim Cn As ADODB.Connection
Dim oCat As ADOX.Catalog
Dim Fichier As Variant
Dim Feuille As ADOX.Table
Dim Rst As ADODB.Recordset
Dim texte_SQL As String
Dim Ar() As String, i As Long
 
    Fichier = Application.GetOpenFilename("Fichier Excel, *.csv;*.xls")
    If Fichier = False Then Exit Sub
 
    Set Cn = New ADODB.Connection
    Set oCat = New ADOX.Catalog
 
    Cn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Fichier & ";Extended Properties=Excel 8.0;"
 
    Set oCat.ActiveConnection = Cn
    For Each Feuille In oCat.Tables
        i = i + 1
        ReDim Preserve Ar(i)
        Ar(i) = Feuille.Name
    Next Feuille
 
    texte_SQL = "SELECT * FROM [" & Ar(1) & "]"
 
    Set Rst = New ADODB.Recordset
    Set Rst = Cn.Execute(texte_SQL)
 
    Range("A2").CopyFromRecordset Rst
 
    Set Feuille = Nothing
    Set oCat = Nothing
    Cn.Close
    Set Cn = Nothing
 
End Sub

[aminee1666]

Bonjour KiKi,

Merci bcp pour ton aide le code marche très bien, j'ai encore un problème avec l'importation des données. cette fois j'ai un fichier csv, j'ai modifié le code mais ça marche pas (erreur sur la ligne
<< Cn = "Driver={Microsoft Text Driver (*.txt; *.csv)};" & _
"Dbq=" & Fichier & ";Extensions=asc,csv,tab,txt" >> )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Sub Bouton45_Clic()
 
Feuil3.Range("AN4:AQ15000").ClearContents
 
'Option Explicit
 
Dim Cn As ADODB.Connection
Dim oCat As ADOX.Catalog
Dim Fichier As Variant
Dim Feuille As ADOX.Table
Dim Rst As ADODB.Recordset
Dim texte_SQL As String
Dim Ar() As String, i As Long
 
 
 
    Fichier = Application.GetOpenFilename("Fichier Excel, *.csv;*.xls")
    If Fichier = False Then Exit Sub
 
    Set Cn = New ADODB.Connection
    Set oCat = New ADOX.Catalog
 
 
 
Cn = "Driver={Microsoft Text Driver (*.txt; *.csv)};" & _
        "Dbq=" & Fichier & ";Extensions=asc,csv,tab,txt"
 
 
 
 
Cn.Open
 
    Set oCat.ActiveConnection = Cn
    For Each Feuille In oCat.Tables
        i = i + 1
        ReDim Preserve Ar(i)
        Ar(i) = Feuille.Name
    Next Feuille
 
 
 
 texte_SQL = "SELECT * FROM [" & Ar(1) & "]"
 
    Set Rst = New ADODB.Recordset
    Set Rst = Cn.Execute(texte_SQL)
 
   Feuil3.Range("AN4").CopyFromRecordset Rst
 
    Set Feuille = Nothing
    Set oCat = Nothing
    Cn.Close
    Set Cn = Nothing
 
 
End Sub

Merci d'avance