Discussion :

[statista]

Bonjour,
Ce sujet correspond exactement à mon cas, je cherche à récupérer les noms de mes points de donnée pour leur affecter automatiquement les bonnes couleurs par macro. J'ai également testé la solution ".DataLabel.TEXT" sans succès, ainsi que ".XValues" non plus, et je suis également preneuse de solution si quelqu'un a une piste.
Merci d'avance

[statista]

Bonjour,
J'ai finalement trouvé ce qui n'allait pas pour mon cas.

La solution ".DataLabel.Text" marche mais deux chose peuvent ne pas la faire marcher:

1) j'ai l'impression qu'il faut obligatoirement préciser "ActiveChart.SeriesCollection(1)." devant "datalabel.text" (soit ActiveChart.SeriesCollection(1).datalabel.text) car sinon il semble que ça ne marche pas même si c'est à l'intérieur d'un "with ActiveChart.SeriesCollection(1)."

2) si on cherche à faire des tests en fonction du nom de la catégorie (ex: si c'est telle catégorie on affecte tele couleur) il faut que les étiquettes de données ne contiennent que les noms des catégories (donc ni valeurs ni pourcentages)

Pour information voici mon code personnel pour affecter des couleurs (d'après leurs codes RGB) en fonction du nom de la catégorie (que j'ai renommé ici Categorie1, categorie2 et Categorie3):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
 
ActiveChart.SeriesCollection(1).Select
        With ActiveChart.SeriesCollection(1)
            ActiveChart.SeriesCollection(1).DataLabels.Select
 
'Memorisation du contenu des etiquettes
            Dim EtiCAT As Boolean, EtiVAL As Boolean, EtiPRC As Boolean 'Respectivement: Catégorie (point), Valeur, Pourcentage
            EtiCAT = Selection.ShowCategoryName
            EtiVAL = Selection.ShowValue
            EtiPRC = Selection.ShowPercentage
'Ne laisser que les noms de catégories dans les étiquettes
            Selection.ShowCategoryName = True
            Selection.ShowValue = False
            Selection.ShowPercentage = False
            ActiveChart.SeriesCollection(1).HasLeaderLines = False
            ActiveChart.SeriesCollection(1).DataLabels.AutoText = True
 
            Dim MesPoints As Series
            Dim MaVal As String
            For Each P In .Points
                P.Select
                MaVal = P.DataLabel.TEXT
                Select Case MaVal
                    Case "CATEGORIE1"
                        P.Select
                        Selection.Format.Fill.ForeColor.RGB = RGB(31, 73, 125)
                        Selection.Format.Line.ForeColor.RGB = RGB(31, 73, 125)
                    Case "CATEGORIE2"
                        P.Select
                        Selection.Format.Fill.ForeColor.RGB = RGB(128, 100, 162)
                        Selection.Format.Line.ForeColor.RGB = RGB(128, 100, 162)
                    Case "CATEGORIE3"
                        P.Select
                        Selection.Format.Fill.ForeColor.RGB = RGB(0, 112, 192)
                        Selection.Format.Line.ForeColor.RGB = RGB(0, 112, 192)
                End Select
            Next
        ActiveChart.SeriesCollection(1).DataLabels.ShowCategoryName = EtiCAT
        ActiveChart.SeriesCollection(1).DataLabels.ShowValue = EtiVAL
        ActiveChart.SeriesCollection(1).DataLabels.ShowPercentage = EtiPRC
        ActiveChart.SeriesCollection(1).DataLabels.AutoText = True
        End With

Voilà, en espérant que ça puisse aider l'auteur s'il revient.

[mercatog]

Une alternative pour récupérer le nom et la valeur de chaque point

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub Test()
Dim A As String, B As Double
Dim i As Integer
Dim Ch As Chart
 
Application.ScreenUpdating = False
Set Ch = Worksheets("Feuil1").ChartObjects("Graphique 1").Chart         'Adapter nom de la feuille et nom du graphique
With Ch.SeriesCollection(1)
    For i = 1 To .Points.Count
        'A le libélé du point
        A = Application.Index(.XValues, i)
        'B la valeur du point
        B = Application.Index(.Values, i)
        MsgBox "Point " & i & " (" & A & " , " & B & ")"
    Next i
End With
Set Ch = Nothing
End Sub

[Edit]@ statista
C'est plus facile et structuré comme ci-après:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub Test()
Dim Ch As Chart
Dim Klr As Long
Dim i As Integer
Dim Categ As String
 
Application.ScreenUpdating = False
Set Ch = Worksheets("Feuil1").ChartObjects("Graphique 1").Chart             'Adapter nom de la feuille et nom du graphique
With Ch.SeriesCollection(1)
    For i = 1 To .Points.Count
        Categ = Application.Index(.XValues, i)                              'Categ le libélé du point
        Select Case Categ
            Case "CATEGORIE1": Klr = RGB(31, 73, 125)
            Case "CATEGORIE2": Klr = RGB(128, 100, 162)
            Case "CATEGORIE3": Klr = RGB(0, 112, 192)
        End Select
        With .Points(i)
            .Format.Fill.ForeColor.RGB = Klr
            .Format.Line.ForeColor.RGB = Klr
        End With
    Next i
End With
Set Ch = Nothing
End Sub

[statista]

En effet c'est plus simple comme ça, merci