Discussion :

[I'm_HERE]

salut,

Pour remplacer une chaine par une autre, on peux utiliser les variables de substitutions:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
set chaine=1+2+3+4+5
set chaine=%chaine:+=#%
echo %chaine%

c'est bien vous dites, mais malheureusement on ne pourra pas faire une chose du genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
set chaine=1*2*3*4*5
set chaine=%chaine:*=#%
echo %chaine%

comme vous voyer le caractère astérisque "*", même si on essaye de l'echapper par des caractères d'echappement la substitution ne prendra pas effet.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
set chaine=1*2*3*4*5
set chaine=%chaine:^*=#%
echo %chaine%

Le caractère asterisque "*" a sa propre fonction dans les variables de substitution , il permet s'il précéde une chaine, de traiter la chaine au debut et jusqu'a la première accurrence du reste de la chaine à traiter:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
set chaine=12345World
set chaine=%chaine:*5=Hello %
echo %chaine%

donc il faut envisager d'autres manières pour le remplacement des "*". en voici quelques-unes



Méthode 1:
----------
petite description: on découpe la chaine en caractères puis on teste chaque caractère à part

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
@echo off

set "string=**1*2*3**"
set del=*
set char=#

set result=
for /f "skip=7 delims=" %%_ in ('
  "%ComsPec% /u /c set string|find /v """""
 ') do (if "%%_"=="%del%" (call set "result=%%result%%%char%"
   ) else (call set "result=%%result%%%%_")
)

echo %result%
goto:eof

Méthode 2:
----------

petite description: substitution par conversion et utilisation de la variable dynamique =ExitCodeAscii

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
setlocal EnableDelayedExpansion

set old_str=**hello * world ** 
set oldchar=*
set newchar=$
set new_str=

>$1 (<nul,set/P=%old_str%)
For %%a in ($1) do set /A cnt=%%~za
>$2 (For /l %%a in (1 1 %cnt%) do <nul,set/P=µ)

For /f "tokens=3" %%a in ('"fc /b $2 $1|findstr :"') do (
    set /A dec=0x%%a
    %ComsPec% /c exit /b !dec!
    if "!=ExitCodeAscii!"=="%oldchar%" (
       set new_str=!new_str!%newchar%
      ) else (
       set new_str=!new_str!!=ExitCodeAscii!
      )
)
del $?
echo %old_str%
echo %new_str%
pause

Méthode 3:
----------

petite description: utilisation du beau vieux utilitaire EDLIN, la substitution ce fait par le bias d'un fichier temporaire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
@echo off  1>nul 2>nul 3>nul 4>nul
setlocal EnableDelayedExpansion

set string=**hello*World**
set old_char=*
set new_char=#

pushd %Temp%.\

set string>f1.t

copy nul+nul f0.t 

for /f %%a in (f0.t) do (
  (
    echo 1r%old_char%%%a%new_char%
    echo w
    echo e
  ) | edlin /b f1.t
)
for /f "tokens=*" %%i in (f1.t) do set %%i

echo !string:%new_char% =%new_char%! >con

del f0.t f1.t f1.bak

popd
pause

Méthode 4:
----------

petite description: la méthode classique, on teste chaque caractère par le biais des sous expressions de variables

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
@echo off
setlocal EnableDelayedExpansion

set string=**hello * World**
set old_char=*
set new_char=#
set new_str=

for /l %%a in (0 1 0xFF) do (
  if !string:~%%a^,1!. neq %old_char%. (
     set "new_str=!new_str!!string:~%%a,1!"
  ) else if !string:~%%a^,1!. neq . (
     Set new_str=!new_str!%new_char%))

echo !new_str!
endlocal
pause

Méthode 5:
----------

petite description: dans cette exemple on va combiner JS à notre code. cette méthode nous permet d'utiliser les RegExp's

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
@echo off

set str=**hello ** world**
set old=\*
set new=#

for /f "useback delims=" %%_ in (`@mshta "about:<script>var string='%str%';new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(string.replace(/%Old%/g,'%New%'));close();</script>" ^|more`) do set res=%%_

echo %str% 
echo %res%

pause

Méthode 6:
----------

petite description: cette exemple montre la flexibilité de PS,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
@echo off

set string=*hello***World*
set oldchar=*
set newchar=$

for /f "tokens=*" %%* in ('
   "powershell -c ""$env:string"".replace('%oldchar%','%newchar%')"
 ') do set result=%%*

echo %result%
pause

Walid

[Drizzt [Drone38]]

On peut aussi utiliser l'utilitaire sed version Windows.

[I'm_HERE]

salut,

On peut aussi utiliser l'utilitaire sed version Windows.

ça sera akors un jeu d'enfant
moi je préfere awk.exe;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

echo **hello * world ** | awk "{ gsub(/*/,"""#""",$0)}1"

[Bragu Demon]

Bonsoir,

J'étais à la recherche d'une solution pour supprimer des * d'un fichier texte.
J'ai testé avec plusieurs de des méthodes données ici, mais rien n'y fait, je pense mal me débrouiller en adaptant le code.
Mon fichier source s'appelle CR_Liste.txt avec en début de ligne un nombre de '*' variant d'une ligne à l'autre :
************vindicte-dérisoire
*******abrasion sélective
****************Ornithorynque apprivoisé

Mon fichier résultat s'appelle CR_.txt et contient ça :
string=************vindicte-dérisoire
string=*******abrasion sélective
string=****************Ornithorynque apprivoisé


Avec la méthode 1 j'ai essayé ça pour alimenter la variable string :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
rem Suppression des caractères '*' dans le fichier résultat
rem CR_Liste.txt
del U:\CR_.txt > nul

FOR /F "tokens=1-8 delims= " %%a in (U:\CR_Liste.txt) DO (
set string=%%a

rem set "string=**1*2*3**"
set del=*
set char=#
set result=
for /f "delims=" %%_ in ('
"%ComsPec% /u /c set string|find /v """""
') do (if "%%_"=="%del%" (call set "result=%%result%%%char%"
) else (call set "result=%%result%%%%_")
)
echo !result! >> U:\CR_.txt

)
pause

Une idée pour remplacer les '*' ?

[sachadee]

Les solutions de I'M_HERE Sont toutes excellentes et fonctionnelles, Il en a posté 6 et tu en voudrait d'autres....

Si tu veux utilisé celle-ci active l'expansion retardé et fait une petite substitution au final.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off

setlocal enabledelayedexpansion enableextensions

FOR /F "tokens=1-8 delims= " %%a in (U:\CR_Liste.txt) DO (set string=%%a

set del=*
set char=#
set result=
for /f "delims=" %%_ in ('
"%ComsPec% /u /c set string|find /v """""
') do (if "%%_"=="%del%" (call set "result=%%result%%%char%"
) else (call set "result=%%result%%%%_")
)
set result=!result:string=!
echo !result:~1! >> U:\CR_.txt

)

Amicalement

[Bragu Demon]

Bonjour Sachadee et merci de ta réponse.

Malheureusement j'ai déjà activé l'expansion retardée dans mon script et rien n'y fait, je ne comprends pas où ce situe mon erreur, mon fichier résultat contient toujours les '*'

Je souhaite utiliser ce script pour n'utiliser que des commandes natives.
l'exemple avec EDLIN me paraissant compliqué, je me suis tourné vers cette méthode là et la 4, sans succès.

Si j'attribue à string comme valeur une ligne de mon fichier, cela fonctionne parfaitement.
Je pense donc avoir mal positionné ma boucle For qui me sert à lire le contenu de mon fichier ligne par ligne, sachant que ma variable string prend bien comme valeur toute les ligne de mon fichier.

Voici mon script avec l'exemple 4 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@ECHO OFF
SETLOCAL enabledelayedexpansion enableextensions
del U:\CR_.txt /Q > NUL

FOR /F "tokens=* delims=" %%a in (U:\CR_Liste.txt) DO (set string=%%a
rem set string=************vindicte-dérisoire

set old_char=*
set new_char=#
set new_str=

for /l %%a in (0 1 0xFF) do (
  if !string:~%%a^,1!. neq %old_char%. (
     set "new_str=!new_str!!string:~%%a,1!"
  ) else if !string:~%%a^,1!. neq %new_char%. (
     Set new_str=!new_str!%new_char%))

	 

echo !new_str! >> U:\CR_.txt

)

pause

Merci pour vos éclaircissements.

[sachadee]

Tu as testé le code que je t'ai posté ?????

[Bragu Demon]

Oui, le problème est exactement le même.

Le code ne fonctionne que si spécifie en dur une chaîne. A partir du moment ou cette chaine varie, le remplacement ne se fait plus.

C'est pour ça que je pense que j'ai du mal combiner la lecture de mon fichier avec le traitement ligne par ligne.

L'utilisation de sed ou awk qui sont des éditeurs en ligne de commande ne peut pas convenir, il faut procéder à une installation, ce qui ne pourra pas être faisable. Il faudrait soit comment bien combiner les boucles, soit un utilitaire du type de sed mais qui soit sans installation par exemple.

[sachadee]

Salut,

J'ai adapté la méthode 4 de I'M HERE a ton cas. Sur ma machine cela fonctionne à la perfection.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

@echo off

setlocal EnableDelayedExpansion

set old_char=*
set new_char=#
set new_str=

for /f "delims=" %%b in (U:\CR_Liste.txt) do ( set string=%%b
                                        for /l %%a in (0 1 0xFF) do (
                                        if !string:~%%a^,1!. neq %old_char%. (
                                        set "new_str=!new_str!!string:~%%a,1!"
                                        ) else if !string:~%%a^,1!. neq . (
                                        Set new_str=!new_str!%new_char%)))

echo !new_str!>>U:\CR_.txt
endlocal
pause

[Bragu Demon]

Bonjour,

Je pense qu'on tient le bon bout, les * sont remplacés par des # mais le tout est écrit sur 1 seule ligne


Merci en tout cas, je continue pour voir comment faire

[sachadee]

Envoie un bout de ton fichier depart et comment tu le veux en sortie.

Parce que ce code te prend ton fichier de depart, ligne par ligne et te les restitue tel quel mais en ayant remplacé les *. Enfin sur mon ordinateur !!!

Tu as tout sur une ligne ???

Amicalement

[Bragu Demon]

Oui tout se retrouve sur 1 seule ligne, je suis sous windows XP et j'utilise notepad++ et notepad. J'obtiens le même résdultat (j'ai aussi essayer avec wordpad ou word)

Je ne sais pas si on peut joindre un fichier via le forum, mais voici ce que je recherche a obtenir :

[EDIT] : j'ai trouvé pour héberger les fichiers

Fichier d'entrée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
************vindicte-dérisoire                     FC               CRD0       D0       825       P          G            ZZSXC
*******abrasion sélective                     BI               CRB2       B2       887       P          G            ZZSXH
****************Ornithorynque apprivoisé                     CS               CRC8       C8       817       P          G            ZZSXH

http://www.sendspace.com/file/fttovu


Fichier de sortie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
vindicte-dérisoire                     FC               CRD0       D0       825       P          G            ZZSXC
abrasion sélective                     BI               CRB2       B2       887       P          G            ZZSXH
Ornithorynque apprivoisé                     CS               CRC8       C8       817       P          G            ZZSXH

http://www.sendspace.com/file/su4y4t

J'ai évidemment plus de 3 lignes dans mon fichier d'entrée (environ 40).

L'idée est de supprimer les *.

Je voulais passer par des # histoire de reprendre après mon fichier et de les supprimer.

Avec la dernière version du code, j'obtiens ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

############vindicte-dérisoire                     FC               CRD0       D0       825       P          G            ZZSXC #######abrasion sélective                     BI               CRB2       B2       887       P          G            ZZSXH ################Ornithorynque apprivoisé                     CS               CRC8       C8       817       P          G            ZZSXH

Du coup il faudrait insérer un retour à la ligne avec echo. mais pour l'instant, je n'y suis pas parvenu.

Merci pour l'aide apportée.

[sachadee]

Ton fichier source est un fichier LINUX / UNIX ?

si oui essaye de le convertir préalablement avec un l'utilitaire

http://www.efgh.com/software/unix2dos.exe

[Bragu Demon]

Il s'agit d'un fichier DOS

[sachadee]

Chez moi ton fichier de sortie contient bien 3 lignes !!!....???
(ouvert avec notepad)

[Bragu Demon]

C'est ennuyeux dans ce cas là .... Je continue de creuser.

J'avais bien fait un copié collé de ton code, je vais voir pour le retaper entièrement, des fois que ...

[sachadee]

A mon avis ce n'est pas le code.

Essaye d'ouvrir le fichier de sortie dans la console avec EDIT.

pour voir si tu as le même problème.

[Bragu Demon]

Bonsoir, j'ai le même résultat dans edit.

Je vais essayer de passer par un vbs ...

[sachadee]

Tu ne peux pas tester le code sur un autre ordinateur ?
C'est quoi ton OS ?

[Bragu Demon]

Je suis sous windows XP SP3, je vais tester sur un autre poste, mais je dois pouvoir l'exécuter depuis plusieurs postes (tous sous XP P3) et récupérer le même résultat.