Discussion :

[helenaide]

Bonjour à tous,

Voilà mon problème... J'ai un fichier Excel, avec une première feuille qui doit contenir une image différente selon que le contenu de l'une des cellules soit égale à 0 ou à 1. J'arrive à faire celà, lorsque les images sont stockées sur mon disque dur, mais je souhaiterais que les images soient stockées sur la feuille 2 car ce fichier sera utilisé par un grand nombre de personne sur un grand nombre de poste.

Merci d'avance...

Voilà le code que j'utilise jusqu'à présent :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub AjoutImageFeuille()
    Dim Shp As Shape
    Dim logo1 As String
    Dim logo2 As String
    Dim Cell As Range
 
    logo1 = "C:\image1.jpg"
    logo2 = "C:\image2.jpg"
 
    Set Cell = Range("test2")
    If Range("fédé") = "1" Then
    Set Shp = Feuil1.Shapes.AddPicture(logo1, msoFalse, msoCTrue, Cell.Left, Cell.Top, Cell.Width, Cell.Height)
    Else
    Set Shp = Feuil1.Shapes.AddPicture(logo2, msoFalse, msoCTrue, Cell.Left, Cell.Top, Cell.Width, Cell.Height)
    End If
End Sub

[mercatog]

Bonjour
Renomme tes images insérées en Feuil2: logo1 et logo2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub AjoutImageFeuille()
Dim strImg As String
Dim Shp As Shape
Dim c As Range
 
Application.ScreenUpdating = False
With Feuil1
    strImg = IIf(.Range("fédé") = 1, "logo1", "logo2")
    For Each Shp In .Shapes
        If Shp.Name Like "logo*" Then Shp.Delete
    Next Shp
    Set c = .Range("test2")
    Feuil2.Shapes(strImg).Copy
   .Paste
    With .Shapes(.Shapes.Count)
        .Left = c.Left
        .Top = c.Top
        .Width = c.Width
        .Height = c.Height
    End With
    c.Activate
    Set c = Nothing
End With
End Sub

[helenaide]

Merci beaucoup...
Ca fonctionne parfaitement...