Discussion :

[zmpod]

Bonjour à tous,

J'ai un petit soucis. Je suis super débutant en vba ^^. Je souhaiterais que ce programme ce répète de colonne en colonne (par exemple sur 12 colonnes).
J'ai essayé de rajouté une boucle For mais sans succès. Je désespère un peu.
Pouvez-vous m'aider s'il vous plait ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Dessine_Rectangle()
For i = 1 To 10
    If Cells(21, "C") = i Then
        j = 18 - i + 1
        ref = "C" & j
        Exit For
    End If
Next
 
Cells(1, 1).Value = ref  
Largeur = 8
Hauteur = 8 
Gauche = Range(ref).Left + (Range(ref).Width - Largeur) / 2
Haut = Range(ref).Top + (Range(ref).Height - Hauteur) / 2
ActiveSheet.Shapes.AddShape(msoShapeRectangle, Gauche, Haut, Largeur, Hauteur).Select
End Sub

[francky74]

Bonjour,

Premièrement, il te faut enlever le exit for.
Et tu peux remplacer la lettre "C" par un chiffre qui sera le rang de la colonne.
Ensuite tu pourras utiliser un For pour changer de colonne

[ZebreLoup]

Il faut créer une sous-procédure (enfin c'est le plus propre) qui prend en paramètre le numéro de la colonne.

Par contre ta boucle actuelle ne sert à rien.

Voici un exemple qui marche :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Option Explicit
 
Public Const LARGEUR = 8
Public Const HAUTEUR = 8
 
Sub Dessine_Rectangle()
    Dim iCol As Integer
    For iCol = 3 To 14
        Dessine_Rectangle_sub iCol
    Next iCol
End Sub
 
Sub Dessine_Rectangle_sub(numCol As Integer)
    Dim numLig As Integer
    Dim rg As Range
    Dim score As Integer
    Dim gauche As Single
    Dim haut As Single
 
    score = Cells(21, numCol).Value
 
    If score < 0 Or score > 10 Then Exit Sub
 
    numLig = 18 - score + 1
 
    Set rg = Cells(numLig, numCol)
 
    gauche = rg.Left + (rg.Width - LARGEUR) / 2
    haut = rg.Top + (rg.Height - HAUTEUR) / 2
 
    ActiveSheet.Shapes.AddShape msoShapeRectangle, gauche, haut, LARGEUR, HAUTEUR
End Sub

[zmpod]

Merci à vous deux (pour la rapidité et l'exactitude) !! C'est exactement ce que je voulais, ça fonctionne.
Je vais décortiquer le programme pour le comprendre.
Je vois que j'ai encore beaucoup à apprendre sur VBA...

Encore merci