Discussion :

[helened]

Bonjour !
Je bosse actuellement sur un projet en informatique et ça fait 2h que je bloque sur une ligne de programme.
J'essaie de copier une partie de ma feuille de calcul en tant qu'image (jusque là, ça va), puis de la copier dans un UserForm. J'ai essayé dans un cadre et dans un objet Image, mais je me retrouve toujours avec l'erreur 424 "Objet requis".
J'ai regardé sur plein de forums, et il me semble utiliser la formulation souvent conseillée, mais allez savoir pourquoi, chez moi ça bug..

Où est-ce-que je me plante ?

Voilà ma Sub pour l'instant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub Frame1_Click()
 
Dim NomIm As Variant, pic As Variant
Dim poutre As Range
 
 
Set poutre = Feuil2.Range(Cells(1, 1), Cells(10, 10))  
 
NomIm = poutre.CopyPicture(xlScreen, xlBitmap)     'copie la sélection en tant qu'image dans le presse papier
 
'Création d'une zone de diagramme temporaire :
 
With ActiveSheet.ChartObjects.Add(0, 0, 150, 150).Chart
        .Paste
        .Export ThisWorkbook.Path & "\ImagePoutre.gif", "GIF"       ' Sauvegarde l 'image du graphique au format gif dans le dossier courant
End With
 
 
'On Error Resume Next
 
'Et c'est la ligne suivante qui provoque un message d'erreur :
UserForm3.Frame2.Picture = LoadPicture("C:\Users\Hélène\Documents\Cours\Projet_Info\ImagePoutre.gif")  'Affiche l'image dans l'userform
 
 
   'Supprime le graphique et la forme :
   With ActiveSheet
        .ChartObjects(ActiveSheet.ChartObjects.Count).Delete
        .Shapes(ActiveSheet.Shapes.Count).Delete
   End With
 
End Sub

Merci de votre aide

[SfJ5Rpw8]

Bonsoir,

Vérifie le nom de ton Userform3 et de ta Frame2...

[mercatog]

Testé ce code (le tiens)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub Frame1_Click()
Dim FichierImg As String
 
FichierImg = ThisWorkbook.Path & "\ImagePoutre.gif"
With Feuil2
    .Range(.Cells(1, 1), .Cells(10, 10)).CopyPicture xlScreen, xlBitmap     'copie la sélection en tant qu'image dans le presse papier
    With .ChartObjects.Add(0, 0, 150, 150).Chart
        .Paste
        .Export FichierImg, "GIF"                ' Sauvegarde l 'image du graphique au format gif dans le dossier courant
    End With
    Me.Frame2.Picture = LoadPicture(FichierImg)  'Affiche l'image dans l'userform
    .ChartObjects(.ChartObjects.Count).Delete
End With
Kill FichierImg
End Sub

[helened]

Super, ça marche !

bbil, effectivement il y avait un problème dans mes appellations... Erreur de débutant..

Et mercatog, merci pour ton programme, c'est plus simple que ce que j'avais fait !

Et surtout merci de votre rapidité