Discussion :

[InfoA7]

Bonjour,
je suis étudiante et je dois effectuer un projet sur VBA. J'aimerais bien récupérer la durée totale d'un fichier vidéo mais je ne sais pas si c'est possible de récupérer ce genre d'information grâce à VBA excel, est-ce que quelqu'un pourrait m'aider?
Merci par avance

[mercatog]

Bonsoir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
'Activer la référence Microsoft Shell Controls and Automation
 
Function Duree(ByVal Chemin As String, ByVal Fichier As String) As Date
Dim Shl As New Shell32.Shell
Dim Rep As Shell32.Folder
Dim Fich As Shell32.FolderItem
 
Set Rep = Shl.Namespace(Chemin)
Set Fich = Rep.Items.Item(Fichier)
 
If Rep.GetDetailsOf(Fich, 27) <> "" Then Duree = Rep.GetDetailsOf(Fich, 27)
 
Set Shl = Nothing
Set Rep = Nothing
Set Fich = Nothing
End Function

Exemple d'utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub MonTest()
Dim Chem As String, Fich As String
 
Chem = "C:\Users\user\Desktop"
Fich = "Rouicha.mp3"
MsgBox "Durée: " & Duree(Chem, Fich)
End Sub

Ci-après lien http://silkyroad.developpez.com/VBA/...asseurs/#LIV-A

[Daniel.C]

Bonjour, Essaie le code suivant sur une feuille vierge (il liste les attributs d'un dossier complet). Dans outil réferences cocher Microsoft Shell Controls and Automation. Remplace "mp3" par l'extension de ton fichier. La durée est en colonne AB :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub LireInfosJpg()
 'Dans outil réferences cocher Microsoft Shell Controls and Automation
 
  Dim Chemin As String
  Dim myShell As Shell
  Dim myFolder As Folder
  Dim myFile As FolderItem
  Dim i As Byte, f As String, lig As Long
 
  'Indiquer le chemin du répertoire
  Chemin = "C:\Users\Daniel\Documents\Donnees\Daniel\Musique\Jazz\Art Tatum" '*** modififer le chemin
  Set myShell = CreateObject("Shell.Application")
  Set myFolder = myShell.Namespace(Chemin)
  Set myFile = myFolder.Items.Item(f)
  Application.ScreenUpdating = False
  [a:ah].ClearContents
  For i = 0 To 34
    If myFolder.GetDetailsOf(myFile, i) <> "" Then _
 Cells(1, i + 1) = myFolder.GetDetailsOf(myFile, i)
  Next
  f = Dir(Chemin & "\*.mp3") '***modifier l'extension ici
  'f = Dir(Chemin & "\*.jpg")
  Do While Len(f) > 0
    Set myFile = myFolder.Items.Item(f)
    lig = [a65536].End(xlUp)(2).Row
    For i = 0 To 34
      If myFolder.GetDetailsOf(myFile, i) <> "" Then _
 Cells(lig, i + 1) = myFolder.GetDetailsOf(myFile, i)
    Next
    f = Dir
    lig = lig + 1
  Loop
  Set myShell = Nothing
  Set myFolder = Nothing
  Set myFile = Nothing
 End Sub

[InfoA7]

Merci beaucoup
je l'ai adapté pour un seul fichier et j'arrive à récupérer la durée (et d'autres caractéristiques aussi) grâce aux informations que vous m'avez fourni.
Cordialement