Discussion :

[eno97]

Bonjour tout le monde

Voilà, je dispose d'une matrice d'une taille de 1000 lignes et 10 colonnes. Je souhaiterai afficher un graphique qui m'affiche 10 courbes qui correspondent chacune à l'une des colonnes.

Pour l'instant, la seule solution que j'ai trouvé, c'est de déclarer 10 vecteurs colonnes dans lesquels je répartie les valeurs de la matrice.

Voilà le code pour mon graphe :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Charts.Add
 
ActiveChart.Location _
Where:=xlLocationAsObject, Name:="Feuil2"
 
With ActiveChart
    .HasTitle = True
    .SeriesCollection.NewSeries
    .SeriesCollection(1).XValues = tableau()
    .SeriesCollection(1).Values = tableau1()
    .SeriesCollection.NewSeries
    .SeriesCollection(2).XValues = tableau()
    .SeriesCollection(2).Values = tableau2()
 
    .ChartType = xlLine
End With

où tableau est un vecteur qui contient toutes les valeurs entières de 1 à 1000, et tableau1 et tableau2 les deux vecteurs intermédiaires des deux premières colonnes de ma matrice.

est-ce que quelqu'un peut m'aider svp?

merci d'avance

[mercatog]

Par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Dim LastLig As Long
Dim Ch As ChartObject
 
Application.ScreenUpdating = False
With Worksheets("Feuil2")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    Set Ch = .ChartObjects.Add(200, 100, 450, 300)
    Ch.Chart.ChartType = xlLine
    Ch.Chart.SetSourceData .Range("A1:J" & LastLig), PlotBy:=xlColumns
    Set Ch = Nothing
End With

[eno97]

ça aurait pu fonctionné, mais j'ai oublié de préciser que mes données ne sont pas rentrées dans une feuille excel, mais bien dans un tableau de données créé comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim table(999, 9) As Double

du coup je ne suis pas sure que le bout de code que tu m'as passé puisse fonctionner dans mon cas

[mercatog]

Une procédure générique qui a comme paramètre la variable tableau Tb

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub CreatGraph(Tb As Variant)
Dim Ch As ChartObject
Dim Res() As Double
Dim i As Long
Dim k As Byte
 
Application.ScreenUpdating = False
Set Ch = Worksheets("Feuil2").ChartObjects.Add(200, 100, 450, 300)
ReDim Res(LBound(Tb, 1) To UBound(Tb, 1))
With Ch.Chart
    .ChartType = xlLine
    For k = LBound(Tb, 2) To UBound(Tb, 2)
        With .SeriesCollection.NewSeries
            For i = LBound(Tb, 1) To UBound(Tb, 1)
                Res(i) = Tb(i, k)
            Next i
            .Values = Res
        End With
    Next k
End With
Set Ch = Nothing
End Sub

Qu'on appelle comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Tracer()
Dim LastLig As Long
Dim Tableau As Variant
 
With Worksheets("Feuil2")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    Tableau = .Range("A1:J" & LastLig).Value
End With
CreatGraph Tableau
End Sub

[eno97]

Ca y est ça marche, merci beaucoup