PROC GCHART Changer l'ordre d'apparition des sous-groupes

**Hélixe** · 14/02/2012, 16h09

Bonjour,

Tout est dans le titre !

Avec par exemple la table suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
DATA test;
INPUT ville $ mois sexe $ statut $ class_age $ var1;
CARDS;
lille	2	M	non	<10	238
paris	2	M	non	<10	383
paris	2	F	non	<10	426
lille	1	F	non	<10	476
lille	1	M	non	>50	1289
paris	1	M	non	<10	2046
paris	1	M	non	>50	2271
paris	1	F	non	<10	2672
paris	1	F	oui	>50	3226
lille	1	F	oui	>50	3322
lille	2	M	oui	>10	3808
paris	2	M	oui	>10	5783
lille	1	M	oui	>10	7199
lille	2	F	oui	>10	8100
paris	2	M	nsp	>50	244
lille	2	M	nsp	<10	334
paris	2	F	nsp	<10	428
paris	2	F	nsp	>50	485
lille	2	F	nsp	<10	520
paris	2	M	nsp	>10	1127
lille	1	M	nsp	>50	1220
lille	1	F	nsp	>50	2269
paris	2	F	nsp	>10	2278
lille	1	M	nsp	>10	4529
lille	2	M	nsp	>10	4637
paris	1	M	nsp	>10	5612
lille	1	F	nsp	>10	9277
lille	2	F	nsp	>10	9936
paris	2	F	oui	<10	1193
paris	2	M	oui	<10	1465
paris	2	M	oui	>50	2426
paris	1	F	oui	<10	3432
paris	1	M	oui	<10	3547
paris	2	F	oui	>50	4120
lille	1	M	oui	<10	4896
lille	2	M	oui	<10	4992
lille	2	F	oui	<10	7982
lille	2	M	oui	>50	9200
lille	1	F	oui	<10	9542
paris	1	M	oui	>50	10222
;
RUN;

et ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
PROC SORT DATA = test OUT = test1;
	BY ville mois sexe class_age;
RUN;
AXIS1 LABEL = NONE;
LEGEND1	LABEL = NONE;
OPTION NOBYLINE;
 
PROC GCHART DATA = test1;
	HBAR class_age / SUBGROUP = statut
					LEGEND = LEGEND1
					FREQ = var1
					TYPE = PERCENT
					NOSTAT
					MAXIS = axis1;
RUN;

J'aimerais que, dans chaque barre, apparaisse d'abord le oui puis le non puis le nsp.

J'ai testé pas mal de choses, notamment avec les options order= et value= de Legend1=, mais sans succès.
Un peu d'aide ne me ferait pas de mal

Merci !

**olivier.decourt** · 15/02/2012, 07h08

Bonjour.
Les sous-groupes sont affichés selon l'ordre de leurs valeurs non formatées.
Il faudrait donc recoder STATUT, par exemple en A pour oui, B pour non et C pour nsp : ça ordonnerait les catégories selon tes vœux.
Pour que l'affichage soit bon, il suffit d'ajouter un format qui affiche oui pour A, non pour B et nsp pour C.
Bon courage.
Olivier

**Hélixe** · 15/02/2012, 09h56

Je pense que j'ai déjà essayé cette méthode en m'appuyant justement sur un post trouvé dans le forum.

Un truc du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
PROC FORMAT;
     VALUE $statut_fmt "oui" = 1
                       "non" = 2
                       "nsp" = 3;
RUN;
 
DATA test;
SET test;
     rang = PUT(statut, $statut_fmt.);
RUN;
 
PROC SORT DATA = test OUT = test1 (DROP = rang);
     BY ville mois sexe class_age rang;
RUN;
 
AXIS1 LABEL = NONE;
LEGEND1	LABEL = NONE;
OPTION NOBYLINE;
 
PROC GCHART DATA = test1;
	HBAR class_age / SUBGROUP = statut
					LEGEND = LEGEND1
					FREQ = var1
					TYPE = PERCENT
					NOSTAT
					MAXIS = axis1;
RUN;

sans beaucoup plus de résultats !

**Hélixe** · 15/02/2012, 10h32

Et tant que j'y suis, je me permets de vous solliciter pour un autre problème du même type :

Je veux maintenant ordonner les barres de mon graphique. Pour cela, j'utilise l'option MIDPOINTS= avec une macro variable contenant le nom des barres, entre guillemets et dans l'ordre voulu.
Mes barres sont effectivement réorganisées mais je perds toute l'information pour l'une d'elles (la barre est à 0).

Ce n'est pas le bon intitulé me direz-vous !
Et pourtant SI ! D'autant plus que j'ai utilisé une macro-variable plutôt que de tout retaper à la main, donc pas d'erreur possible à ce niveau (?) !

Une idée de l'origine du problème ?

**olivier.decourt** · 15/02/2012, 10h49

Pour le 1er problème, une fois que tu as créé la variable RANG, ce n'est pas utile de s'en servir dans un tri, par contre c'est ta variable dans SUBGROUP. Et tu ajoutes un format dans le sens inverse du précédent pour afficher tes libellés habituels.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
DATA test;
INPUT ville $ mois sexe $ statut $ class_age $ var1;
CARDS;
lille	2	M	non	<10	238
paris	2	M	non	<10	383
paris	2	F	non	<10	426
lille	1	F	non	<10	476
lille	1	M	non	>50	1289
paris	1	M	non	<10	2046
paris	1	M	non	>50	2271
paris	1	F	non	<10	2672
paris	1	F	oui	>50	3226
lille	1	F	oui	>50	3322
lille	2	M	oui	>10	3808
paris	2	M	oui	>10	5783
lille	1	M	oui	>10	7199
lille	2	F	oui	>10	8100
paris	2	M	nsp	>50	244
lille	2	M	nsp	<10	334
paris	2	F	nsp	<10	428
paris	2	F	nsp	>50	485
lille	2	F	nsp	<10	520
paris	2	M	nsp	>10	1127
lille	1	M	nsp	>50	1220
lille	1	F	nsp	>50	2269
paris	2	F	nsp	>10	2278
lille	1	M	nsp	>10	4529
lille	2	M	nsp	>10	4637
paris	1	M	nsp	>10	5612
lille	1	F	nsp	>10	9277
lille	2	F	nsp	>10	9936
paris	2	F	oui	<10	1193
paris	2	M	oui	<10	1465
paris	2	M	oui	>50	2426
paris	1	F	oui	<10	3432
paris	1	M	oui	<10	3547
paris	2	F	oui	>50	4120
lille	1	M	oui	<10	4896
lille	2	M	oui	<10	4992
lille	2	F	oui	<10	7982
lille	2	M	oui	>50	9200
lille	1	F	oui	<10	9542
paris	1	M	oui	>50	10222
;
RUN;
PROC FORMAT;
     INVALUE statut_infmt "oui" = 1
                       "non" = 2
                       "nsp" = 3;
    VALUE statut_fmt
        1 = "oui" 
        2 = "non" 
        3 = "nsp" ;
RUN;
 
DATA test;
SET test;
     rang = INPUT(statut, statut_infmt.);
RUN;
AXIS1 LABEL = NONE;
LEGEND1	LABEL = NONE;
OPTION NOBYLINE;
PROC GCHART DATA = test;
  FORMAT rang statut_fmt. ;
	HBAR class_age / SUBGROUP = rang
					LEGEND = LEGEND1
					FREQ = var1
					TYPE = PERCENT
					NOSTAT
					MAXIS = axis1 ;
RUN; QUIT ;

**olivier.decourt** · 15/02/2012, 10h50

Pour le 2e problème, est-ce que la variable est numérique ou caractère ?
Avec un format ou non ?
Comment crées-tu la macro-variable, CALL SYMPUTX ou PROC SQL ?

**Hélixe** · 15/02/2012, 11h05

Merci beaucoup, ça marche très bien maintenant !

Pour le deuxième problème, il s'agit comme dans l'exemple d'une variable numérique, sans format et je crée ma macro-variable en utilisant une proc SQL comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
DATA test1;
SET test1;
	IF class_age = "<10" THEN rang = 3;
	IF class_age = ">10" THEN rang = 2;
	IF class_age = ">50" THEN rang = 1;
RUN;
 
PROC SQL NOPRINT;
	SELECT DISTINCT QUOTE(STRIP(class_age)) INTO :var separated BY " " FROM test1 ORDER BY rang;
QUIT;
 
AXIS1 LABEL = NONE;
LEGEND1	LABEL = NONE;
OPTION NOBYLINE;
 
PROC GCHART DATA = test1;
	HBAR class_age / SUBGROUP = statut
					LEGEND = LEGEND1
					MIDPOINTS = &var.
					FREQ = var1
					TYPE = PERCENT
					NOSTAT
					MAXIS = axis1;
RUN;

Pourquoi ajoutes-tu un QUIT; après le RUN; à la fin de la proc GCHART ?

**olivier.decourt** · 15/02/2012, 11h36

Envoyé par Hélixe

Pour le deuxième problème, il s'agit comme dans l'exemple d'une variable numérique, sans format

Ben non, dans ton exemple, c'est une variable caractère (CLASS_AGE) et pas numérique.
Et si tu ajoutes l'option DISCRETE avec MIDPOINTS et compagnie ?

Envoyé par Hélixe

Pourquoi ajoutes-tu un QUIT; après le RUN; à la fin de la proc GCHART ?

C'est une vieille histoire, la présence de ce QUIT, mais normalement il est nécessaire pour terminer totalement la proc GCHART (idem pour GPLOT, REG, GLM, DATASETS, et quelques autres procédures qui ont des RUN et des QUIT). Cela dit, si tu es dans Enterprise Guide, les QUIT sont ajoutés automatiquement en fin de programme, donc petit à petit je pense qu'on va arriver à s'en débarrasser...

**Hélixe** · 15/02/2012, 11h52

Oui pardon, c'est bien comme dans l'exemple donc CARACTERE !
J'ai essayé avec DISCRETE, pas d'amélioration.

Sinon, n'y a t il pas un autre moyen d'ordonner les barres de l'histogramme que cette option MIDPOINTS ?

**olivier.decourt** · 15/02/2012, 12h03

Tu peux écrire un AXIS avec une option VALUES et/ou ORDER, puis le brancher comme MAXIS.

**Hélixe** · 15/02/2012, 13h12

Voilà, tout à fait !
J'avais déjà fait la même chose pour la légende.

Merci beaucoup !!!

PROC GCHART Changer l'ordre d'apparition des sous-groupes

ODS et reporting

Discussions similaires

Partager

Partager