Discussion :

[funkyspirit]

Bonjour à tous,

Je cherche à construire une procédure me permettant de parcourir les données d'une feuille Excel ("Anakr") de 17 colonnes et 5869 lignes, et de repérer les doublons sur les 2 premières colonnes (nom et prénom). Quand je dis doublon, il peut y avoir 5 fois la même (pas limité à 2)

Je souhaite que cette procédure coupe-colle dans une autre feuille ("DoublonAnak") les lignes entières (17 colonnes) correspondant à un doublon les une en dessous des autres (variable actueldanak pour incrémenter le numéro de ligne d'écriture). Cette procédure doit finir par couper-coller la ligne initiale à l'orgine du doublon.

La macro dure longtemps et ne marche pas. Même sur un test basique (je créé exprès deux lignes identiques)...

Avez-vous une idée du souci ?

Merci d'avance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
 
 
' Initialisation des variables
 
actueldanak = 1
detecteur = 0
 
' Boucle 1
 
For anak = 2 To 5869
Sheets("Anakr").Select
nomanak = Trim(Sheets("Anakr").Cells(anak, 1).Value)
prenomanak = Trim(Sheets("Anakr").Cells(anak, 2).Value)
 
 
 
If IsEmpty(Sheets("Anakr").Cells(anak, 1)) = true  Then 
 
' Boucle 2
 
    For anak2 = 2 To 5869
 
        If anak <> anak2 Then
 
            Sheets("Anakr").Select
            nomanak2 = Trim(Sheets("Anakr").Cells(anak2, 1).Value)
            prenomanak2 = Trim(Sheets("Anakr").Cells(anak2, 2).Value)
 
 
                If nomanak = nomanak2 And prenomanak = prenomanak2 Then
 
                Sheets("Anakr").Select
                Range(Cells(anak2, 1), Cells(anak2, 17)).Select
                Selection.Cut
 
                Sheets("DoublonAnak").Select
                Range(Cells(actueldanak, 1), Cells(actueldanak, 1)).Select
                ActiveSheet.Paste
 
                actueldanak = actueldanak + 1
                detecteuranak = 1
                End If
 
 
        End If
 
 
    Next
 
    If detecteuranak = 1 Then
                Sheets("Anakr").Select
                Range(Cells(anak, 1), Cells(anak, 17)).Select
                Selection.Cut
 
                Sheets("DoublonAnak").Select
                Range(Cells(actueldanak, 1), Cells(actueldanak, 1)).Select
                ActiveSheet.Paste
 
                actueldanak = actueldanak + 1
                detecteuranak = 0
    End If
 
End If
 
Next

[Philippe Tulliez]

Bonsoir,
La lecture de ce didacticiel sur la gestion des doublons et tout particulièrement le chapitre des macros, te sera d'un grand secours.
Si tu gères cela en mémoire, tu devrais arriver à un temps d'exécution de 2 à 4 minutes de traitement grand maximum.

[Theze]

Bonjour,

Une piste :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
 
Sub Doublons()
 
    Dim Dico As Object
    Dim Plage As Range
    Dim I As Long
    Dim Critere As String
 
    'feuille sur laquelle effectuer la recherche de doublons
    With Worksheets("Anakr")
 
        Set Plage = .Range(.[A1], .[A65536].End(xlUp))
 
    End With
 
    'création du dictionnaire
    Set Dico = CreateObject("Scripting.Dictionary")
 
    'parcour la plage à l'envers pour pouvoir supprimer les lignes
    For I = Plage.Count To 1 Step -1
 
        'concatène le nom et prénom
        Critere = Plage(I).Value & Plage(I).Offset(0, 1).Value
 
        'si pas dans le dico, le rajoute
        If Dico.exists(Critere) = False Then
 
            Dico.Add Critere, Critere
 
        Else
 
            'dans le cas contraire, copie la ligne entière
            'dans la feuille "DoublonAnak" et supprime le doublon
            With Worksheets("DoublonAnak")
 
                If .Range("A1") = "" Then
 
                    Plage(I).EntireRow.Copy .Range("A1")
 
                Else
 
                    Plage(I).EntireRow.Copy .Range("A" & .[A65536].End(xlUp).Row + 1)
 
                End If
 
                Plage(I).EntireRow.Delete
 
            End With
 
        End If
 
    Next I
 
End Sub

Hervé.