Discussion :

[Bonero]

Bonjour a tous,

J’aimerais savoir si il y existe un moyen simple pour remplacer les Chaines Vides par des NULL dans les tous champs de toutes mes tables de ma DDB.

Je suis tombe sur le lien suivant:
http://allenbrowne.com/bug-09.html
Quand j’ai execute la fonction suivante, ca a effectivment change les proprietes REQUIRED et ALLOW ZERO LENGHT a No.
Mais le probleme c’est que j’ai toujours les Chaines Vides dans mes tables.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Function FixZLS()
    Dim db As DAO.Database
    Dim tdf As DAO.TableDef
    Dim fld As DAO.Field
    Dim prp As DAO.Property
    Const conPropName = "AllowZeroLength"
    Const conPropValue = False
 
    Set db = CurrentDb()
    For Each tdf In db.TableDefs
        If (tdf.Attributes And dbSystemObject) = 0 Then
            If tdf.Name <> "Switchboard Items" Then
                For Each fld In tdf.Fields
                    If fld.Properties(conPropName) Then
                        Debug.Print tdf.Name & "." & fld.Name
                        fld.Properties(conPropName) = conPropValue
                    End If
                Next
            End If
        End If
    Next
 
    Set prp = Nothing
    Set fld = Nothing
    Set tdf = Nothing
    Set db = Nothing
End Function

Merci de m’aider.

[nico84]

Bonsoir,

Pourquoi ne pas simplement glisser un UPDATE entre les lignes 15 et 16 ? Il y a toutes les infos pour cela me semble-t-til...

[Bonero]

Bonjour ,
j'ai inserre le code suivant entre les lignes 15 et 16; ca marche.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
strSQL = "UPDATE " & "[" & tdf.Name & "]" & " SET " & _
"[" & fld.Name & "]" & "=Null WHERE " & _
"[" & fld.Name & "]" & " =''"
'Debug.Print strSQL
 
DB.Execute strSQL

en fait, j'avais cru que le code suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

fld.Properties(conPropName) = conPropValue

suffisait a transformer/convertir les chaines vides en NULL.
Grand merci pour ton aide.