Discussion :

[_developpeur_]

Bonjour à tous je sais pas ce qui se passe mais je crois que je beug...
je souhaite changer la taille de la police de plusieurs graph que je crée en VBA dans une feuille.
Je me suis aidé de l'enregistreur de macro et je suis arrivé à cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
        'Création graphique
    Dim gGraphique As ChartObject
    Application.ScreenUpdating = False
    Set gGraphique = Worksheets(sNomFeuille).ChartObjects.Add(100, 100, 100, 100)
 
    gGraphique.Chart.ChartType = xlColumnClustered
    gGraphique.Chart.SetSourceData source:=Sheets(sNomFeuille).range(sDebutRange & ":" & sFinRange), PlotBy:= _
        xlRows
    gGraphique.Chart.Location Where:=xlLocationAsObject, Name:=sNomFeuille
    gGraphique.Left = Worksheets(sNomFeuille).Columns(iColDebutPlage).Left
    gGraphique.Top = Worksheets(sNomFeuille).Rows(iLigneFinPlage + 2).Top
    gGraphique.Width = range(sDebutRange & ":" & sFinRange).Width
    gGraphique.Height = 130
 
    gGraphique.Chart.Axes(xlCategory).TickLabels.Font.Name = "Arial"
    gGraphique.Chart.Axes(xlCategory).TickLabels.Font.Size = 8
    DoEvents
 
    gGraphique.Chart.Axes(xlValue).TickLabels.Font.Name = "Arial"
    gGraphique.Chart.Axes(xlValue).TickLabels.Font.Size = 8
    DoEvents
    gGraphique.Chart.Legend.Font.Name = "Arial"
    gGraphique.Chart.Legend.Font.Size = 8
    DoEvents

ce code est dans une boucle j'ai environ 5 graphiques produit et ben figuré vous que les polices ne sont pas changées ! elles sont à 10.5 au lieu de 8 je comprends absolument rien, si quelqu'un a déja rencontré ce problème je suis preneur, merci de votre aide

petite remarque quand je me position en mode debug sur les lignes de codes qui changent les polices et quej e fais F8 a chaque fois ça marche

[mercatog]

J'ai testé ce code (Excel 2007), la police est identique au désir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Dim gGraphique As ChartObject
 
Application.ScreenUpdating = False
With Worksheets(sNomFeuille)
    Set gGraphique = .ChartObjects.Add(.Cells(1, iColDebutPlage).Left, .Cells(iLigneFinPlage + 2, 1).Top, .Range(sDebutRange & ":" & sFinRange).Width, 130)
 
    gGraphique.Chart.SetSourceData Source:=.Range(sDebutRange & ":" & sFinRange), PlotBy:=xlRows
 
    With gGraphique.Chart
        .ChartType = xlColumnClustered
 
        With .Axes(xlCategory).TickLabels.Font
            .Name = "Arial"
            .Size = 19
        End With
 
        With .Axes(xlValue).TickLabels.Font
            .Name = "Tahoma"
            .Size = 11
        End With
 
        With .Legend.Font
            .Name = "Times New Roman"
            .Size = 13
        End With
    End With
    Set gGraphique = Nothing
End With

[_developpeur_]

J'ai trouvé !!!! avec ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
'Création graphique
    Dim gGraphique As ChartObject
        
    Application.ScreenUpdating = False
    Set gGraphique = Worksheets(sNomFeuille).ChartObjects.Add(100, 100, 100, 100)
    
    gGraphique.Chart.ChartType = xlColumnClustered
    gGraphique.Chart.SetSourceData source:=Sheets(sNomFeuille).range(sDebutRange & ":" & sFinRange), PlotBy:= _
        xlRows
    gGraphique.Chart.Location Where:=xlLocationAsObject, Name:=sNomFeuille
    gGraphique.Left = Worksheets(sNomFeuille).Columns(iColDebutPlage).Left
    gGraphique.Top = Worksheets(sNomFeuille).Rows(iLigneFinPlage + 2).Top
    gGraphique.Width = range(sDebutRange & ":" & sFinRange).Width
    gGraphique.Height = 130
    gGraphique.Name = "Graphique_Niv" & iNiveauGranularite & "_Min" & iTabListeMinistere(j)
          
    Set sFeuille = Sheets(sNomFeuille)
    sFeuille.Select

    sFeuille.ChartObjects(gGraphique.Name).Select

    sFeuille.ChartObjects(gGraphique.Name).Chart.Axes(xlCategory).TickLabels.Font.Size = 8
    sFeuille.ChartObjects(gGraphique.Name).Chart.Axes(xlCategory).TickLabels.Font.Name = "Arial"

    sFeuille.ChartObjects(gGraphique.Name).Chart.Axes(xlValue).TickLabels.Font.Size = 8
    sFeuille.ChartObjects(gGraphique.Name).Chart.Axes(xlValue).TickLabels.Font.Name = "Arial"
    
    sFeuille.ChartObjects(gGraphique.Name).Chart.Legend.Font.Name = "Arial"
    sFeuille.ChartObjects(gGraphique.Name).Chart.Legend.Font.Size = 8
    
    Set gGraphique = Nothing

Si j'enleve le sFeuille.Select ca marche pas !!!! et si je le remet ça marche c'est dingue.... je suis en excel 2003.

La je part du bouleau je suis fatigué, mais juste par curiosité je testerai ton code lundi matin et je te dirais.

Merci et bon week end !