Discussion :

[vbfoxter]

Bonjour,

Aprés plusieurs recherches, j'ai trouvé avec l'aide du forum la façon de créer des checkbox dynamiques dans une userform.

Le problème rencontré est la façon de récupérer l'information concernant un checkbox sélectionné. Quelqu'un pourrait-il m'indiquer comment on peut procéder ?

Merci d'avance pour votre aide.

[bifconsult]

Bonjour,


Une checkbox étant égale à TRUE ou FALSE, pour récupérer la valeur:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
'Nom de la userform avec la checkbox : frm_test
'Nom de la checkbox : chk_test
dim a as boolean
a = frm_test.chk_test.value

A sera égal à TRUE ou FALSE selon l'état de la checkbox.

[vbfoxter]

Bonjour bifconsult,

Je suis d'accord avec ton code pour récupérer la valeur d'un checkbox intégrer à une useform. Mais dans ma problèmatique, il s'agit de checkbox dynamique c'est à dire introduit dans la userform par code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
'Procedure de creation de CheckBox dynamique
'dans l'UserForm
 
 
Private Sub MiseAJourCheckBox()
    Dim Obj As Control
    Dim Cl As Classe1
    Dim nb As Integer
 
 
    nb = Sheets("Données").Range("B50000").End(xlUp).Row - 1
 
    For u = 1 To nb
 
 
        Set Collect = New Collection
 
        Set Obj = Me.Controls.Add("forms.Checkbox.1")
        With Obj
            .Name = "Checkbox" & u
            .Object.Caption = Sheets("Données").Cells(u + 1, 2)
            .Left = 350
            .top = 60 + (u - 1) * 20
            .Width = 140
            .Height = 15
        End With
 
 
        'ajout de l'objet dans la classe
        Set Cl = New Classe1
        Set Cl.ChkBx = Obj
        Collect.Add Cl
    Next u
 
End Sub

Je vais chercher les intitulés des checkbox dans une feuille de données et j'affiche les checkbox dans la userform. C'est un code qui n'est pas de moi.

Je recherche la façon de pouvoir connaitre les checkbox selectionner.

Si quelqu'un a des suggestions ??

Merci

[bifconsult]

Bonjour,

Comme tous les checkbox générés portent un nom commençant par Checkbox suivi d'un numéro:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub chk_check()
Dim ctrl As Control
For Each ctrl In UserForm1.Controls
chk_nm = ctrl.Name
If Left(chk_nm, 8) = "Checkbox" Then
'la ligne suivant permet de retourner le numéro de la checkbox
chk_nr = Right(chk_nm, Len(chk_nm) - InStr(chk_nm, "x")) * 1
chk_val = ctrl.Value
End If
Next ctrl
End Sub

[vbfoxter]

Je vais tester ton code dès demain.

Je me demandais si il y a moyen de lancer une procédure à chaque sélection de checkbox ?

Merci bifconsult

[mercatog]

Tu as commencé par utiliser ton module de classe, pourquoi ne pas y continuer

1. Module de classe nommée Classe1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Public WithEvents ChkBx As MSForms.CheckBox
 
Private Sub ChkBx_Change()
 
'ici mettre le code appelé au changement de l'état des chechbox crée dynamiquement
'Par exemple on affiche le nom et la valeur du checkbox cliqué
MsgBox ChkBx.Name & " - Valeur: " & ChkBx.Value
End Sub

2. Module de ton userform (Ton code légèrement adapté)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Dim Collect As Collection
 
Private Sub MiseAJourCheckBox()
Dim Nb As Integer, i As Integer
Dim Obj As Control
Dim CL As Classe1
Dim Tb As Variant
 
With Worksheets("Données")
    Nb = .Cells(.Rows.Count, "B").End(xlUp).Row
    Tb = .Range("B2:B" & Nb)
End With
 
Set Collect = New Collection
For i = 1 To Nb - 1
    Set Obj = Me.Controls.Add("forms.Checkbox.1")
    With Obj
        .Name = "MonCheckBox" & i
        .Object.Caption = Tb(i, 1)
        .Left = 350
        .Top = 60 + (i - 1) * 20
        .Width = 140
        .Height = 15
    End With
    'ajout de l'objet dans la classe
    Set CL = New Classe1
    Set CL.ChkBx = Obj
    Collect.Add CL
    Set CL = Nothing
Next i
End Sub
 
Private Sub UserForm_Initialize()
 
MiseAJourCheckBox
End Sub
 
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
 
Set Collect = Nothing
End Sub

[vbfoxter]

Bonjour mercatog

Vraiment MERCI!

J'ai galèré pour trouver une solution. Encore merci.

Trés bonne journée