recopier une cellule d'un classeur dans un autre classeur

**VIPNO** · 04/04/2012, 21h36

Bonjour à tous,

J'ai recopié un FichierModele en des FichierCible.
Je travaille depuis un Fichier nommé Fdt2012.
Je voudrais remplacer les cellules A1 et C1 de la Feuille NOM du FichierCible
par les cellules des colonnes A et B de la Feuille Janv2012 du fichier FdT2012,
sachant que les fichiers ne se trouvent pas sous le même répertoire.
J'ai réussi à ouvrir le fichier et activer la feuille NOM mais le code suivant me donne une erreur de syntaxe que je n'arrive pas à résoudre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Workbooks(FichierCible).Worksheets("NOM").Range("A1").Value = _
   Worbooks("D\Fdt_2012\macroFdt2012.xlsm).Worsheets(Janv2012).Range(Ligne,1).Value

Si quelqu'un pouvait m'aider à lever cette erreur, je pourrai ensuite poursuivre.
Merci d'avance à tous ceux qui m'aide et me font progresser.
Véronique

Code complet actuel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
 
Option Explicit
Sub DeploiementFdTJanv2012()
 
Dim PremLigne As Integer, DerLigne As Integer, Ligne As Integer
Dim valeur() As Variant
Dim cel As Object
Dim Fichier As String, Feuille As String, Prenom_Pers As String
Dim FichierModele As String, FichierCible As String
 
 
 
 
'Calcul du nombre de ligne à lire
Sheets("Janv2012").Activate
PremLigne = Range("A1").End(xlDown).Row + 1
DerLigne = Range("A65536").End(xlUp).Row
 
FichierModele = "D:\FdT_2012\FdT_2012_MODELE.xls"
 
 
' Copie du fichier FdT_MODELE.xls vers les FichierCible du type FichierNom en les rangeant dans les repertoires correspondant au service
 
For Ligne = PremLigne To DerLigne
 
    If Len(Cells(Ligne, 1).Value) > 0 And Len(Cells(Ligne, 4).Value) > 0 Then
 
 FichierCible = Cells(Ligne, 4).Value & "\" & Cells(Ligne, 5).Value
        FileCopy FichierModele, FichierCible
 
'     ouvrir le classeur cible à modifier
Application.Workbooks.Open (FichierCible)
' activer la feuille NOM
 
Sheets("NOM").Activate
 
'Remplacer les  cellules A1 et C1 de la Feuille NOM du  FichierCible
'par les cellules des colonnes A et B de la Feuille Janv2012 du fichier FdT2012,
'sachant que les fichiers ne se trouvent pas sous le meme répertore
 
Workbooks(FichierCible).Worksheets("NOM").Range("A1").Value = _
   Worbooks("D\Fdt_2012\macroFdt2012.xlsm).Worsheets(Janv2012).Range(Ligne,1).Value
 
   Workbooks(FichierCible).Worksheets("NOM").Range("C1").Value = _
   Worbooks("D\Fdt_2012\macroFdt2012.xlsm).Worsheets(Janv2012).Range(Ligne,2).Value
 
 End If
 
Next Ligne
 
End Sub

**casefayere** · 04/04/2012, 21h40

Bonsoir,
regardes d'abord ta syntaxe :
Worbooks au lieu de Workbooks

**VIPNO** · 04/04/2012, 22h09

Bonjour,

Il y avait effectivement une grosse erreur de syntaxe mais j'ai maintenant erreur d'exécution 9 : "l'indice n'appartient pas à la sélection avec le code suivant. Je ne vois pas ce qui peux coincer, mais c'est peut être évident pour certains d'entre vous........
J'avoue ne plus savoir où regarder.....
Merci pour votre aide.....

Véronique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Workbooks(FichierCible).Worksheets("NOM").Range("A1").Value = _
   Workbooks("D\Fdt_2012\macroFdt2012.xlsm").Worksheets("Janv2012").Range(Ligne,1).Value

**casefayere** · 04/04/2012, 22h49

Déjà, un conseil, habitues-toi à spécifier la dernière ligne comme ça (tu es avec excel2007) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DerLigne = Range("A" & rows.count).End(xlUp).Row

as-tu testé la valeur de "FichierCible" ? avec un test comme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Msgbox FichierCible

y a-t-il ".xls" ou ".xlsx" ou ".xlsm" à la fin ?

"macroFdt2012.xlsm" est-il ouvert ?

quelle est la valeur de ligne ?

peut-être

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.cells(Ligne,1).Value

**VIPNO** · 04/04/2012, 23h07

Bonsoir,

Merci pour ta réponse.
Je testais PremLigne, DerLigne (maintenant modifiée), et Ligne. Tout correspondant à ce que je veux.
Je teste FichierCible qui est OK et qui s'ouvre bien. J'ai tout mis en xlsm, les macros sont activées à l'ouverture, mais cela ne change rien...

Rien n'y fait

La nuit portera peut être conseil....

Véronique

**casefayere** · 04/04/2012, 23h14

As-tu regardé ma dernière proposition,
Si ligne est un chiffre, changes ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Workbooks(FichierCible).Worksheets("NOM").Range("A1").Value = _
   Workbooks("D\Fdt_2012\macroFdt2012.xlsm").Worksheets("Janv2012").cells(Ligne,1).Value

et non

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Workbooks(FichierCible).Worksheets("NOM").Range("A1").Value = _
   Workbooks("D\Fdt_2012\macroFdt2012.xlsm").Worksheets("Janv2012").Range(Ligne,1).Value

et attention fichiercible doit être de la forme, par exemple "toto.xlsm" et non "toto"

**VIPNO** · 05/04/2012, 07h38

Bonjour,

Merci pour ton aide.
J'ai essayé ce que tu m'as dit et toujours la même erreur.
J'ai également le même problème lorsque je remplace FichierCible par son nom en dur entre quote...

Cela doit être la combinaison workbook, worksheet, cells qui pose un problème. Est-ce qu'il y aurait une autre façon de l'écrire....

Mais là encore, je ne maitrise pas....
Merci encore pour l'aide apportée par ce forum qui me fait progresser....
Véronique

Bonjour,

J'ai fait un essai de ce que je voulais faire avec une macro manuelle et je pense que j'ai un problème de fenêtre active.....
Veronique

**Philippe Tulliez** · 05/04/2012, 07h50

Bonjour,
Il y a, je pense 3 classeurs et feuilles dans ce code
1 - Le classeur où se trouve le code VBA et la liste des services, nom du répertorie
2 - Le classeur modèle : "D:\FdT_2012\FdT_2012_MODELE.xls" (Nom + Répertoire)
3 - Le classeur cible dont le nom et le répertoire varie suivant la valeur des cellule
Est-ce correct ?
Dans ce cas est-il possible d'expliquer dans cette ligne de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FichierCible = Cells(Ligne, 4).Value & "\" & Cells(Ligne, 5).Value

Colonne 4 : Répertoire ?
Colonne 5 : Un nom de classeur
Quelle est la valeur de la variable FichierCible

**Philippe Tulliez** · 05/04/2012, 07h58

Bonjour,

Envoyé par VIPNO

Bonjour,
J'ai fait un essai de ce que je voulais faire avec une macro manuelle et je pense que j'ai un problème de fenêtre active.....
Veronique

Voici un code exemple.
Un fichier modèle nommé monModele.xls qui est copié 2 fois (voir boucle For row = 2 To 3) dans un même répertoire Z:\Tests\Test Tsf\tsf\ sous des noms différents. Le nom ici est construit avec la combinaison des colonnes 2 & 1
Avec du VBA nul besoin d'utiliser Activate pour travailler avec des feuilles différentes.
C'est bien sûr un exemple à adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Option Explicit
Const wkbTempName As String = "monModele.xls"
Const FolderFromName As String = "Z:\Tests\Test Tsf\"
Const FolderDestName As String = "Z:\Tests\Test Tsf\tsf\"
Dim wkbMaster As Workbook, shtMaster As Worksheet
Dim wkbTemplate As Workbook
Dim wkbDestName As String
Sub Init()
 Set wkbMaster = ThisWorkbook: Set shtMaster = wkbMaster.Worksheets("List")
End Sub
Sub Main()
 Init
 Dim row As Long
 With shtMaster
  For row = 2 To 3
   wkbDestName = FolderDestName & "Janvier2012" & " " & .Cells(row, 2) & "_" & .Cells(row, 1) & ".xls"
   FileCopy FolderFromName & wkbTempName, wkbDestName
   '
   '
  Next
 End With
 Ecrit
End Sub
Sub Ecrit()
 Dim app As New Excel.Application: app.Visible = False     ' Mettre à TRUE pendant les tests  
 Dim wkbTemp As Excel.Workbook ' WorkBookTemporaire
 Dim row As Long
 For row = 2 To 3
  With shtMaster
   wkbDestName = FolderDestName & "Janvier2012" & " " & .Cells(row, 2) & "_" & .Cells(row, 1) & ".xls"
   Set wkbTemp = app.Workbooks.Open(wkbDestName)
   ' Ecrire dans fichier
   wkbTemp.Worksheets("TS").Range("I2") = .Cells(row, 2) & " " & .Cells(row, 1)
 
   wkbTemp.Close SaveChanges:=True ' , Filename:=wkbDestName
 
  End With
 Next row
 app.Quit: Set app = Nothing
End Sub

**VIPNO** · 05/04/2012, 08h23

Bonjour,

Il y a effectivement 3 classeurs.

1 - Le classeur modèle "D:\FdT_2012\FdT_2012_MODELE.xls" (Nom + Répertoire)

2 - Le classeur où se trouve le code VBA "D:\FdT_2012\macroFdt2012 et la table des personnes avec Prénom, NOM, service (colonnes 1 à 3). Colonnes 4 (répertoire en fonction du service d'appartenance de la personne de type D:\FdT_2012\FdT2012_BE) et 5 (nom du fichier en fonction du nom de la personne de type FdT_2012_MOI.xlsm )

3 - Le classeur cible dont le nom et le répertoire varie suivant la valeur des cellule des colonnes 4 et 5 du classeur précèdent
Le nom de ce fichier avec chemin est bien codé par le code suivant.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FichierCible = Cells(Ligne, 4).Value & "\" & Cells(Ligne, 5).Value

FichierCible est déclaré en String.
La partie de code suivant me permet de faire la copie correctement.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub DeploiementFdTJanv2012()
 
Dim PremLigne As Integer, DerLigne As Integer, Ligne As Integer
Dim valeur() As Variant
Dim cel As Object
Dim Fichier As String, Feuille As String, Prenom_Pers As String
Dim FichierModele As String, FichierCible As String
 
 
 
 
'Calcul du nombre de ligne à lire
Sheets("Janv2012").Activate
PremLigne = Range("A1").End(xlDown).Row + 1
DerLigne = Range("A" & Rows.Count).End(xlUp).Row
 
 
FichierModele = "D:\FdT_2012\FdT_2012_MODELE.xlsm"
 
 
' Copie du fichier FdT_MODELE.xls vers les FichierCible du type FichierNom en les rangeant dans les repertoires correspondant au service
 
For Ligne = PremLigne To DerLigne
 
    If Len(Cells(Ligne, 1).Value) > 0 And Len(Cells(Ligne, 4).Value) > 0 Then
 
 FichierCible = Cells(Ligne, 4).Value & "\" & Cells(Ligne, 5).Value
        FileCopy FichierModele, FichierCible

.

Voila tous les détails.
Je poursuis en regardant le code envoyé.
Merci beaucoup pour cette aide.
A bientôt
Véronique

**VIPNO** · 05/04/2012, 11h24

Bonjour,
Merci à tous,
En adaptant le code de corona, J'ai réussi à obtenir ce que je voulais.
C'EST GRANDIOSE...
Mille merci.....

Pour revenir sur le problème de départ je devais avoir un conflit entre un nom de classeur (string) et le classeur lui même (workbook).
Du basique pour certains, mais le temps que je m'en aperçoive......
Je vais maintenant continuer sur une autre discussion pour faire progresser ma mise à jour et continuer à progresser

Véronique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
Option Explicit
Sub DeploiementFdTJanv2012()
 
Dim PremLigne As Integer, DerLigne As Integer, Ligne As Integer
Dim cel As Object
Dim Fichier As String, Feuille As String
Dim NomFichierModele As String, NomFichierCible As String
Dim ClasseurMaitre As Workbook, FeuilleMaitre As Worksheet, ClasseurCible As Workbook
Dim App As New Excel.Application
 
 
'Initialisation du classeur Maitre, du Fichier modèle
Set ClasseurMaitre = ThisWorkbook: Set FeuilleMaitre = ClasseurMaitre.Worksheets("Janv2012")
NomFichierModele = "D:\FdT_2012\FdT_2012_MODELE.xlsm"
 
 
'Calcul du nombre de ligne à lire
With FeuilleMaitre
PremLigne = Range("A1").End(xlDown).Row + 1
DerLigne = Range("A" & Rows.Count).End(xlUp).Row
 
 
 
 
' Copie du fichier FdT_MODELE.xls vers les FichierCible du type FichierNom en les rangeant dans les repertoires correspondant au service
 
For Ligne = PremLigne To DerLigne
 
    If Len(Cells(Ligne, 1).Value) > 0 And Len(Cells(Ligne, 4).Value) > 0 Then
 
        NomFichierCible = Cells(Ligne, 4).Value & "\" & Cells(Ligne, 5).Value
            FileCopy NomFichierModele, NomFichierCible
 
        ' Copie des elements de la source à la cible de la forme cible=source
        'remplacer les cellules A1 et C1 de la Feuille NOM du FichierCible
        'par les cellules des colonnes A et B de la Feuille Janv2012 du fichier FdT2012,
 
         App.Visible = False ' Permet de ne pas voir l'ouverture du fichier et la copie des cellules
                        'Changer False en True pour voir
 
            Set ClasseurCible = App.Workbooks.Open(NomFichierCible) ' Lien entre le classeur et le nom de fichier
            ClasseurCible.Worksheets("NOM").Range("A1").Value = .Cells(Ligne, 1).Value
            ClasseurCible.Worksheets("NOM").Range("C1").Value = .Cells(Ligne, 2).Value
 
        ' fermer ficihier en sauvegardant
            ClasseurCible.Close SaveChanges:=True
 
 
 
    End If
Next Ligne
 
App.Quit: Set App = Nothing
 
End With
 
End Sub

recopier une cellule d'un classeur dans un autre classeur [XL-2007]

Macros et VBA Excel

Discussions similaires

Partager

Partager