Discussion :

[criscris11]

Bonjour à tous,
J'utilise actuellement une procédure événementielle par clic gauche dans la colonne A pour sélectionner une ligne afin de la copier dans un autre onglet mais j'aimerais l'améliorer.

Est il possible d'obtenir le même résultat mais au lieu de cliquer dans la colonne A j'aimerais que l'utilisateur clique directement sur la ou les lignes (sur les numéros de lignes directement en fait) voulues (à partir de la ligne 3 jusqu'à la dernière ligne saisie) ?
Une fois la ou les lignes sélectionnées et mise en surbrillance (copier), est il possible de coller les valeurs uniquement de la ou les lignes sélectionnées dans un des deux onglets au choix (un onglet Partants et un onglet Arrivant) après la dernière ligne saisie ?

J'espère avoir été assez explicite et je reste à votre disposition pour toutes information complémentaire.
Merci et bon week-end Pascal.

[BlueMonkey]

Bonjour,

Pour copier les lignes sélectionnées dans Feuil1 à la suite des lignes Feuil2 et Feuil3 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Const WsSource As String = "Feuil1" 'feuille source
Const WsDestinations As String = "Feuil2;Feuil3" 'liste des feuilles destinations de la copie
 
Sub DoCopy()
 
    Dim lastDestLine() As Long  'dernière ligne des feuilles destination
    Dim WsDestWsNames() As String 'tableau des noms d'onglet
 
    WsDestWsNames() = Split(WsDestinations, ";")
    ReDim lastDestLine(UBound(WsDestWsNames))
 
    'Trouve la dernière ligne des onglets destination
    Dim wi As Integer
    For wi = 0 To UBound(WsDestWsNames)
        lastDestLine(wi) = Worksheets(WsDestWsNames(wi)).Range("A" & Rows.Count).End(xlUp).Row + 1
    Next wi
 
    Worksheets(WsSource).Activate
 
    Dim r As Range
    For Each r In Selection.Rows
        r.Copy
        For wi = 0 To UBound(WsDestWsNames)
            Worksheets(WsDestWsNames(wi)).Range("A" & lastDestLine(wi)).PasteSpecial xlValues
            lastDestLine(wi) = lastDestLine(wi) + 1
        Next wi
    Next r
End Sub

[criscris11]

Bonjour,
Je reviens vers toi car ce n'est pas tout à fait ce que je souhaitais obtenir mais peut-être me suis je mal exprimé.
1 - je ne cherche pas à copier la ou les lignes sélectionnées dans les 2 onglets à la fois mais avoir le choix de l'onglet de destination si possible ;
2 - je préfèrerai que ce soit une procédure événementielle plutôt qu'une procédure à lancer manuellement par l'utilisateur au détriment d'une sélection multiple ;
3 - en clair, l'utilisateur clique sur une ligne (entête de ligne) ce qui active le copiage de la ligne en demandant à l'utilisateur où il souhaite copier cette ligne (choix entre 2 onglets définis).

Voilà en espérant avoir été un peu plus explicite.
En attendant, bonne journée à tous.

Peut-être une piste en adaptant ce code, non ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
  If Target.Column = 5 And Target.Count = 1 Then
    If Target.Value <> "" Then
      état = Target
      If état <> ActiveSheet.Name Then
        Application.EnableEvents = False
        Target.Offset(0, -4).Resize(1, 5).Copy Sheets(état).[A65000].End(xlUp).Offset(1, 0)
        Target.Offset(0, -4).Resize(1, 5).Delete shift:=xlUp
        Application.EnableEvents = True
      End If
    End If
  End If
End Sub

Merci d'avance.

[BlueMonkey]

Bonsoir,

3 - en clair, l'utilisateur clique sur une ligne (entête de ligne) ce qui active le copiage de la ligne en demandant à l'utilisateur où il souhaite copier cette ligne (choix entre 2 onglets définis).

Pour le choix de la feuille de destination, il faudra créer une UserForm contenant :
- une Combobox avec la liste des feuilles de destination possible.
- un bouton <Ok> pour la validation.

Le code de cet UserForm pourrait être :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Public wsTarget As String ' le nom sélectionné comme feuille cible
 
Private Sub CommandButton1_Click()  'clic sur <OK>
    wsTarget = ComboBox1.Text
    Hide
End Sub
 
Private Sub UserForm_Activate()
    Dim ws As Worksheet
    ComboBox1.Clear
    For Each ws In Worksheets 'on a ajoute le nom de toutes les feuilles du classeur
        ComboBox1.AddItem (ws.Name)
    Next ws
    ComboBox1.Text = IIf(wsTarget = "", Worksheets(1).Name, wsTarget)
End Sub

Pour le déclenchement de l'évènement, un clique sur la ligne permet d'afficher la UserForm de sélection de feuille destination,
puis de lancer la copie.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If (Target.EntireRow.Address = Target.Address) Then ' on a sélectionné une ligne entière
        UserForm1.Show
        With Worksheets(UserForm1.wsTarget)
              Target.Copy
              .Range("A" & .Range("A" & Rows.Count).End(xlUp).Row + 1).PasteSpecial xlValues
        End With
    End If
End Sub

[criscris11]

Bonsoir,
Après avoir tester, je vais avoir des petits réglages à faire mais le code est beaucoup plus adapté que le premier : merci encore.
Bonne soirée.

[BlueMonkey]

Bonsoir,

Content pour toi que tu es trouvé une solution qui te convienne.
Il ne reste plus qu'a noter le sujet résolu (avec le bouton ).

Pour info noter son sujet résolu donne un point. Et comme ton nombre total de points est actuellement négatif (ce qui réduit le nombre de personne
qui répondront à tes demandes), je te conseil vraiment de le faire.