Discussion :

[00seb]

Bonjour,

J'aimerais créer une macro (ou si il y a une solution avec juste des formules excel cela me va très bien) qui me permette de générer une liste de noms à partir de données se trouvant sur une autre feuille du même classeur.

Sur une page 1 j'ai :
- 1ere colonne: une liste de noms
- 2eme colonne : information relatif au nom (Yes ou No)

Sur la page 2 j'aimerais afficher dans une colonne que la liste de noms ayant l'info Yes.

Merci pour votre aide!

PS: ci-joint un exemple concret de ce que je souhaiterais faire

[Fvandermeulen]

Salut,

Il y a une méthode simple sans macro...utilise un tableau croisé dynamique.

Tu affiches les noms en champs de ligne et l'indicateur en champ de page.
Tu filtres ton champ de page sur Yes et tu n'auras que les noms concerné en ligne.

Sinon, par macro, un petit exemple avec commentaire pour tenter d'être clair.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub ListeNom()
Dim WsS As Worksheet, WsC As Worksheet
Dim DerLig As Long, R As Long, newLig As Long
 
Set WsS = Sheets("Page 1") 'Feuille source
Set WsC = Sheets("Page 2") 'Feuille cible
DerLig = WsS.Cells(WsS.Columns(1).Cells.Count, 1).End(xlUp).Row 'Dernière ligne utilisée
 
WsC.Columns(1).ClearContents 'Vide le contenu de la colonne 1 e la page 2 (évite de garder les noms d'une précédente action)
 
For R = 1 To DerLig 'Boucle sur toutes les lignes de la Page 1
    If UCase(WsS.Cells(R, 2)) = "YES" Then 'Vérifie si le nom est tagé YES (Ucase met en majuscule)
        newLig = newLig + 1 'Permet l'incrémentation de la cible
        WsC.Cells(newLig, 1) = WsS.Cells(R, 1) 'Affecte le nom sur une nouvelle ligne de la page cible
    End If
Next R
 
End Sub

A+

[00seb]

Salut Fvandermeulen,

Merci beaucoup pour ton aide et d'avoir pris le temps de me répondre. Ca marche nikel !