créer une liste défilante avec filtre permettant de récupérer des noms de client sur une colonne

**chombriko** · 23/04/2012, 16h02

Bonjour,
Donc voilà travaillant sur un projet en vba excel , je recherche comment faire pour pouvoir récupérer des noms de clients à partir d'une feuille , tout cela avec un UserForm!
J'ai créer un UserForm qui me demande de renseigner un nom de client mais étant donnée qu'il y en à 500 si c'est pas plus , je souhaiterai créer un filtre qui me permettrais par exemple si je saisi les trois premières lettres du nom du client ,d'avoir tout les clients commençons par ces trois premières lettres et ensuite pouvoir faire le choix du client voulue via une liste défilante.

Une fois le client saisie , il faudrait que je puisse avoir dans une liste défilante toutes les machines que se client à en sa possession.
En sachant que chaque client à un ID_adresse différent mais que les machines chez un même client ont un ID_adresse identique.

J'espère m'être bien exprimer et qu'on pourra me venir en aide

**casefayere** · 23/04/2012, 17h31

Bonjour,
Il faudrait que tu détailles plus, comment est organisé ton fichier : lignes, colonnes et peut-être envoyer une image de celui-ci et de l'USF.

Bon courage

**Didier Gonard** · 23/04/2012, 18h45

Bonjour,

le mieux est de procéder par étapes :

1 - lire Les règles :http://club.developpez.com/regles/

=> Une question pas message, ça facilite les recherches, beaucoup de réponses étant déjà dans le forum

2 - une partie de ta réponse se trouve dans le comportement de l’auto-complétion native des combobox, à tester.

vois ce fil si correspond : http://www.developpez.net/forums/d10...utocompletion/
c'est du VB6, mais proche VBA

une fois ton 1er souci résolu, tu enchaînes sur les questions suivantes dans de nouveaux messages.

vois ceci sinon aussi : http://silkyroad.developpez.com/VBA/ControlesUserForm/

Cordialement,

Ps : si le côté technique de la réponse = OK ou pas => pensez à cliquer sur les pouces et quand question résolue à la taguer résolue, et chaque action vous rapporte des points

Didier

**chombriko** · 24/04/2012, 11h45

Bonjour,

Oui désolé j'ai un peux tout mélangé

Donc pour répondre à ta question casefayere , mon fichier est organisé de la façon suivante:
-Les noms des clients sont sur la colonne B et ils se répartissent sur 5807 lignes!

Merci Ormonth

**casefayere** · 24/04/2012, 11h49

Bonjour,

En sachant que chaque client à un ID_adresse différent mais que les machines chez un même client ont un ID_adresse identique.

et

Donc pour répondre à ta question casefayere , mon fichier est organisé de la façon suivante:
-Les noms des clients sont sur la colonne B et ils se répartissent sur 5807 lignes!

et le reste !, les ID_adresse client et machines.......

**chombriko** · 24/04/2012, 12h21

Je commence par la feuille "Table adresse" ou je récupère le nom des clients en colonne B et leur ID_adresse en colonne A.

Ensuite je passe à la feuille "Table equipement adresse" ou via l'ID_adresse qui se trouve en colonne C que j'ai pu récupérer dans la feuille précédente je peux récupérer l'ID_equipement qui lui est en colonne B.

Enfin dans la feuille "Table equipement actif" via l'ID_ equipement qui se trouve en colonne A récupérer dans la feuille précédente , je dois récupérer le Nom_equipement qui se trouve en colonne C.

**casefayere** · 24/04/2012, 19h31

Bonsoir,

avançons petit à petit

je souhaiterai créer un filtre qui me permettrais par exemple si je saisi les trois premières lettres du nom du client ,d'avoir tout les clients commençons par ces trois premières lettres

Un USF avec 1 ListBox nommée "ltClients" (avec 2 colonnes) et 1 TextBox nommé "tbRecherche"

1 feuille nommée "Table adresse" avec un ID en col A (à partir de A2) et les noms correspondants en col B
déclaration des variables qui serviront sur tout l'USF, donc en haut du code de l'USF :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Option Explicit
Dim Clt, derlg As Long, x As Long, ch As String

Code à l'ouverture de l'USF pour remplir ta listbox :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub UserForm_Activate()
lbClients.BoundColumn = 2
With Sheets("Table adresse")
  derlg = .Range("A" & .Rows.Count).End(xlUp).Row
  Clt = .Range("A2:B" & derlg)
  lbClients.List = Clt
End With
End Sub

et enfin, code pour la recherche :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub tbRecherche_Change()
lbClients.Clear
ch = UCase(tbRecherche)
For x = 1 To UBound(Clt, 1)
  If UCase(Clt(x, 2)) Like ch & "*" Then
    With lbClients
      .AddItem Clt(x, 1)
      .Column(1, .ListCount - 1) = Clt(x, 2)
    End With
  End If
Next x
End Sub

testes déjà ça

on verra après,

Bonne soirée

**chombriko** · 25/04/2012, 11h32

Bonjour,

Après avoir essayé ce que tu ma donné sa marche très bien ,merci !!!

Lorsque je rentre le début du nom du client la TextBox il y a un filtre qui se crée au niveau de la ListBox et qui me donne l'identifiant recherché.

Serait ce possible de créer un filtre par rapport au nom du client?
C'est à dire si je rentre les trois premières lettres du client par exemple , j'aurai une liste défilante qui m'affiche tout les noms de clients commençons par ces lettres.

**casefayere** · 25/04/2012, 12h45

Bonjour,

Dans la listbox que je te propose, il est prévu d'avoir le nom du client étant donné qu'elle a 2 colonnes dans les propriétés (je l'ai précisé) et le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

lbClients.BoundColumn = 2

est sur 2 donc en référence au nom du client, donnes une largeur moindre à ta 1ère colonne avec les ID et élargis ta listbox si tu ne vois pas apparaitre les noms.

Bonne journée

**chombriko** · 25/04/2012, 12h56

Effectivement , merci

On peut passer à la suite

**casefayere** · 25/04/2012, 13h03

re,

Une fois le client saisi , il faudrait que je puisse avoir dans une liste défilante toutes les machines que ce client a en sa possession.
En sachant que chaque client à un ID_adresse différent mais que les machines chez un même client ont un ID_adresse identique.

Je veux bien passer à la suite quand tu m'auras dit coment est organisé ton fichier, surtout pour les machines, je t'envoie un fichier bidon, ajoutes des données bidon en correspondance pour tes machines, j'y verrai peut-être plus clair

**chombriko** · 25/04/2012, 13h05

Re,

Je fais sa et je te l'envoi

**casefayere** · 25/04/2012, 15h27

Bien que je ne comprenne pas trop ton organisation, regardes si ce résultat est ce que tu cherches

**chombriko** · 25/04/2012, 16h06

re ,

non ce n'est pas tout à fait sa ,oui désolé je ne me suis pas très bien expliqué

je viens de reformuler mon organisation en espérant avoir étais plus claire.

**casefayere** · 25/04/2012, 17h08

J'ai modifié les codes sans donner toutes les explications, tu devras chercher un peu, il te suffit de copier et coller à la place des autres codes de l'USF

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Option Explicit
'déclaration des variables pour l'USF
Dim Clt, machines As Range, selectMach(), derlg As Long, chid()
Dim x As Long, result As Long, z As Long, ch As String, cel As Range
Private Sub UserForm_Activate() 'quand on ouvre l'USF
lbClients.BoundColumn = 2 'voir avec l'aide la propriété de BoundColumn
With Sheets("Table adresse") 'évite de répêter le nom de la feuille concernée
  derlg = .Range("A" & .Rows.Count).End(xlUp).Row 'sans oublier le "." devant range et rows, donne la dernière ligne utilisée en col A
  Clt = .Range("A2:B" & derlg) 'remplit un tableau avec toutes les données de A2 à B & derniere ligne
  lbClients.List = Clt 'remplit la listbox avec le tableau
End With 'fin de référence à la feuille concernée
'PS : je préfère utiliser les tableaux surtout si tu as beaucoup de données (bien plus rapide)
End Sub
Private Sub tbRecherche_Change()
lbClients.Clear 'quand on change la textbox, la listbox se vide
ch = UCase(tbRecherche) 'variable incrémentée (en majuscule, "Ucase") par chaque lettre entrée dans le textbox
For x = 1 To UBound(Clt, 1) 'le tableau déclaré commence en 1 et on fait une boucle jusqu'à la fin du tableau(col A)
  If UCase(Clt(x, 2)) Like ch & "*" Then 'si le nom du tableau (en majuscule) contient la variable
    With lbClients 'évite de répêter "lbClients
      .AddItem Clt(x, 1) 'on ajoute en col1 de la listbox, l'ID
      .Column(1, .ListCount - 1) = Clt(x, 2) 'et le nom en col2
    End With 'fin de réference à bClients
  End If
Next x 'et on boucle
End Sub
Private Sub lbClients_Click()
z = 0 'on initialise cette variable
With Sheets("Table equipement adresse")
  derlg = .Range("A" & .Rows.Count).End(xlUp).Row
  Set machines = .Range("A2:C" & derlg) 'remplit une plage avec toutes les données de A2 à C & derniere ligne
  With Sheets("Table equipement actif")
    derlg = .Range("C" & .Rows.Count).End(xlUp).Row
  End With
  'ci-dessous on cherche la valeur de la Listbox dans la colonne B de "Table equipement adresse"
  result = WorksheetFunction.CountIf(machines.Columns(3), lbClients.Column(0))
  ReDim chid(1 To result, 1 To 3)
  For Each cel In .Range(machines.Columns(3).Address)
    If cel = lbClients.Column(0) Then
      z = z + 1
      chid(z, 1) = cel.Value: chid(z, 2) = cel(1, 0).Value
      ReDim Preserve selectMach(1 To result)
      With Sheets("Table equipement actif")
        selectMach(z) = .Range("A2:A" & derlg).Find(chid(z, 2), .Range("A" & derlg))(1, 3)
      End With
    End If
  Next cel
End With
lbMachines.Clear 'on vide la listbox
'et on la remplit
lbMachines.List = WorksheetFunction.Transpose(selectMach) 'on est obligé de tranposer car dans ce cas le tableau est en ligne
 
End Sub

Tu pourras aussi tester comme ça, j'ai supprimé la variable tableau "CHID" qui ne servait plus à rien :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Sub lbClients_Click()
z = 0 'on initialise cette variable
With Sheets("Table equipement adresse")
  derlg = .Range("A" & .Rows.Count).End(xlUp).Row
  Set machines = .Range("A2:C" & derlg) 'remplit une plage avec toutes les données de A2 à C & derniere ligne
  With Sheets("Table equipement actif")
    derlg = .Range("C" & .Rows.Count).End(xlUp).Row
  End With
  'ci-dessous on cherche la valeur de la Listbox dans la colonne B de "Table equipement adresse"
  result = WorksheetFunction.CountIf(machines.Columns(3), lbClients.Column(0))
  If result = 0 Then MsgBox "pas de correspondance": Exit Sub
  ReDim selectMach(1 To result)
    For Each cel In .Range(machines.Columns(3).Address)
      If cel = lbClients.Column(0) Then
        z = z + 1
        With Sheets("Table equipement actif")
          selectMach(z) = .Range("A2:A" & derlg).Find(cel(1, 0).Value, .Range("A" & derlg))(1, 3)
        End With
      End If
    Next cel
End With
lbMachines.Clear 'on vide la listbox
'et on la remplit
lbMachines.List = WorksheetFunction.Transpose(selectMach) 'on est obligé de tranposer car dans ce cas le tableau est en ligne
 
End Sub

Je viens de m'apercevoir d'une possibilité d'erreur si result = 0 donc ce code à corriger :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub lbClients_Click()
z = 0 'on initialise cette variable
With Sheets("Table equipement adresse")
  derlg = .Range("A" & .Rows.Count).End(xlUp).Row
  Set machines = .Range("A2:C" & derlg) 'remplit une plage avec toutes les données de A2 à C & derniere ligne
  With Sheets("Table equipement actif")
    derlg = .Range("C" & .Rows.Count).End(xlUp).Row
  End With
  'ci-dessous on cherche la valeur de la Listbox dans la colonne B de "Table equipement adresse"
  result = WorksheetFunction.CountIf(machines.Columns(3), lbClients.Column(0))
  If result = 0 Then MsgBox "pas de correspondance": Exit Sub 'a ajouter sinon si result = 0 erreur
    ReDim chid(1 To result, 1 To 3)
    For Each cel In .Range(machines.Columns(3).Address)
      If cel = lbClients.Column(0) Then
        z = z + 1
        chid(z, 1) = cel.Value: chid(z, 2) = cel(1, 0).Value
        ReDim Preserve selectMach(1 To result)
        With Sheets("Table equipement actif")
          selectMach(z) = .Range("A2:A" & derlg).Find(chid(z, 2), .Range("A" & derlg))(1, 3)
        End With
      End If
    Next cel
End With
lbMachines.Clear 'on vide la listbox
'et on la remplit
lbMachines.List = WorksheetFunction.Transpose(selectMach) 'on est obligé de tranposer car dans ce cas le tableau est en ligne
 
End Sub

**chombriko** · 26/04/2012, 12h05

Justement j'allais t'en parlé mais tu a été plus rapide que moi

Pour le moment j'ai bien ce que je veux , je vais adapter sa a mon fichier et je te tiens au courant.

Encore merci!

Bonjour,

Serait il possible de te contacter par mail , comme ça je te montrerai ce que j'ai fais en sachant que je suis encore bloqué

**casefayere** · 26/04/2012, 12h17

Bonjour chombriko

Serait il possible de te contacter par mail , comme ça je te montrerai ce que j'ai fais en sachant que je suis encore bloqué

Le principe du forum est de ne pas passer par des messages privés pour de questions techniques, alors pourquoi devrait-on régler le problème par mail, j'espère que tu comprendras et n'hésites pas à nous faire part de tes difficultés sur le forum

...en sachant que je suis encore bloqué

Dis-moi ou et comment.

Bon courage

**chombriko** · 26/04/2012, 16h12

Bonjour,

Je suis bloqué parce que je dois adapter ton code à mes USF qui ne sont pas disposé comme les tiens.
Pour la sélection du nom du client tout va bien , par contre je n'arrive pas à récupérer les marques.

Je te joint un fichier qui te montre un peu comment sont disposés mes USF en espérant m'être bien fait comprendre

**casefayere** · 26/04/2012, 17h24

Re chombriko
eh bien !, ce que je t'ai fait ne sert pas à grand-chose, tu es parti complètement ailleurs, je vais regarder ton fichier, essayer d'analyser ce que tu souhaites et peut-être te faire une proposition, je te tiendrai au courant, de toute façon. Surtout, laisse-moi du temps car j'ai d'autres choses à régler, la chance (si on peut appeler ça comme ça) est que je suis bloqué chez moi.

Patience et a +

Re,

J'essaie de comprendre ton but mais c'est difficile quand je vois ce que tu as transmis
Expliques-moi ces codes ou au moins, ce qu'ils seront censés faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub CommandButton5_Click()
' rafraichir les donnees des Feuilles provenant de la base MySql de la GMAO
'ActiveWorkbook.RefreshAll
End Sub
 
Private Sub CommandButton6_Click()
'vide la ComboBox
NcRecherche.Clear
UserForm_Nom_client.Hide
Choix_nom_client_ou_N°_serie.Show'et cet USF n'apparait nulle part
End Sub

Je n'ai pas envie d'aller plus loin si je ne comprends rien, d'autant que tu changes les textbox pour des labels, les listbox pour des combos, les codes que j'avais proposés n'aparaissent nulle part (même adaptés), tu as certainement tes raisons mais je suis largué.

**chombriko** · 27/04/2012, 10h14

Bonjour,

Oui c'est un peu compliqué à expliquer désolé

Pour t'expliquer les codes , le premier permet de rafraichir des données venant d'une base de donnée mais sa je gère déjà bien.
Le deuxième permet une fois le bouton "précédent" sélectionner de revenir à l'USF de départ et de cacher celui que je t'ai envoyé, mais sa aussi je gère déjà

Euh si! j'ai mis la première partie de ton code qui me permet de récupérer les noms de client avec un filtre et sa marche très bien!

Pour le reste du code j'ai pas réussi à adapter

créer une liste défilante avec filtre permettant de récupérer des noms de client sur une colonne

Macros et VBA Excel

Discussions similaires

Partager

Partager