Discussion :

[bilou_12]

Bonjour,

J'ai un code qui marche très bien et qui se balade dans différentes worksheets d'un workbook.

Comme je nomme mes worksheets plusieurs fois, j'ai décidé de les passer en variable. Ca pourra écononomiser à celui qui passera après moi.

Du coup, j'écris public const en haut d'un module de cette manière:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Option Explicit
Public Const feuilleRecapitulative = "COMPARAISON"
Public Const importDataReuters = "IMPORT_REUTERS"
Public Const importDataReutersJMoinsUn = "IMPORT_REUTERS J-1"
Public Const importDataKondor = "IMPORT_KONDOR"
 
 
Sub MiseEnPageComparaisonKondor()
 
'variables
Dim i, j, maxKondorComparaison, maxImportKondor, maxReutersComparaison, _
maxImportReuters, maxReutersM1Comparaison, maxImportReuters1 As Integer
 
'maxKondorComparaison correspond au nombre de maturité pour Kondor sur la feuille Comparaison
maxKondorComparaison = Worksheets(feuilleRecapitulative).Range("A" & Rows.Count).End(xlUp).Row
'maxImportKondor correspond au nombre de maturité pour Kondor sur la feuille Import
maxImportKondor = Worksheets(importDataKondor).Range("C" & Rows.Count).End(xlUp).Row
For i = 1 To maxKondorComparaison
    For j = 1 To maxImportKondor
        'on vérifie que les taux copiés dans Comparaison correspondent à la maturité
        If Worksheets(feuilleRecapitulative).Range("A" & i).Value = Worksheets(importDataKondor).Range("C" & j).Value Then
            Worksheets(feuilleRecapitulative).Range("C" & i).Value = Worksheets(importDataKondor).Range("F" & j).Value
            Worksheets(feuilleRecapitulative).Range("D" & i).Value = Worksheets(importDataKondor).Range("D" & j).Value
        End If
    Next
Next

mais j'ai une erreur dès la 1ère ligne où ma constante est appelée...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

maxKondorComparaison = Worksheets(feuilleRecapitulative).Range("A" & Rows.Count).End(xlUp).Row

la méthode rows a échoué

Quelqu'un pourrait me filer un coup de main svp?

Merci d'avance!

[mercatog]

Essaies comme ceci (n'oublies pas les points devant Range et Rows)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Worksheets(feuilleRecapitulative)
    maxKondorComparaison = .Range("A" & .Rows.Count).End(xlUp).Row
End With

PS: Attention aux déclarations, Seule la dernière variable est Integer

Il fallait spécifier chaque type devant la nom de la variable

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim i As Integer, j As Integer, maxKondorComparaison As Integer, maxImportKondor As Integer

PS2: Type aussi tes constantes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Public Const feuilleRecapitulative As String = "COMPARAISON"