Optimisation de code avec les noms des CheckBox

**brownthefou** · 26/04/2012, 12h34

Bonjour à tous,

J'ai créé un petit UseFerm avec plein de jolies petites CheckBox.
J'ai un commandButton qui me permet d'en sélectionner plusieurs en même temps seulement le code est un gros copié/collé bourrin :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Private Sub CommandButton9_Click()
    'Colonne 1
    If (CheckBox1 = False) Then
        CheckBox1 = True
    Else
        CheckBox1 = False
    End If
    If (CheckBox2 = False) Then
        CheckBox2 = True
    Else
        CheckBox2 = False
    End If
    If (CheckBox3 = False) Then
        CheckBox3 = True
    Else
        CheckBox3 = False
    End If
    If (CheckBox4 = False) Then
        CheckBox4 = True
    Else
        CheckBox4 = False
    End If
    If (CheckBox5 = False) Then
        CheckBox5 = True
    Else
        CheckBox5 = False
    End If
    If (CheckBox6 = False) Then
        CheckBox6 = True
    Else
        CheckBox6 = False
    End If
    If (CheckBox7 = False) Then
        CheckBox7 = True
    Else
        CheckBox7 = False
    End If
    If (CheckBox8 = False) Then
        CheckBox8 = True
    Else
        CheckBox8 = False
    End If
End Sub

Vous comprenez que c'est réellement moche

!

Du coup j'ai essayé plusieurs fois de rentrer ce pavé dans une boucle seulement tout ce que j'ai essayé a loupé.

J'ai essayé les :
variable_str = "CheckBox" & i
==> avec i le numéro de checkbox qui fait la boucle

J'ai essayé plein d'autres choses qui ne marchent pas plus les unes que les autres.
En même temps je ne m'y connais pas trop dans la façon de gérer ces betes la :s

Bref si quelqu'un connait la solution à mon problème, il est le bienvenue

Cordialement

**casefayere** · 26/04/2012, 12h37

Bonjour,

Un peu de lecture

Bon courage

**brownthefou** · 26/04/2012, 14h57

Bonjour casefayere,

Merci de l'attention et merci pour le lien, cependant je l'ai déja regardé et j'ai déja essayé d'adapter ce qu'il y a dessus.

Cependant ce que je n'arrive pas a faire c'est donner à une variable intermédiaire le numéro dune checkbox et ensuite à intégrer ce numéro à la checkbox, j'ai toujorus des erreurs de compilation.

Cordialement

**casefayere** · 26/04/2012, 15h01

Re,

Cependant ce que je n'arrive pas a faire c'est donner à une variable intermédiaire le numéro dune checkbox et ensuite à intégrer ce numéro à la checkbox, j'ai toujorus des erreurs de compilation.

Montres ce code ou envoies un fichier bidon.

Je regarderai car pour l'instant je ne comprends pas trop

**ZebreLoup** · 26/04/2012, 15h02

Tu dois sans doute confondre l'objet CheckBox avec son nom. Il faudrait faire un truc du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub CommandButton9_Click()
    Dim cbx As CheckBox
    Dim i As Integer
 
    For i = 1 to 8
      Set cbx = Me.Controls("CheckBox" & i)
      cbx.Value = Not cbx.Value
    Next i
End Sub

Je n'ai pas testé...

**brownthefou** · 26/04/2012, 15h18

Et bien voila, c'est quasi-exactement le code que j'avais fait. Cependant le :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set cbx = Me.Controls("CheckBox" & i)

me marque une incompatibilité de type, et en essayant de changer ce code, c'est toujours la ligne de code ou apparait dedans la concaténation suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

"CheckBox" & i

Donc je ne suis meme pas persuadé qu'il y ai une solution à ce problème en ne pouvant pas "indicer" ou "numéroter" les CheckBox, je cherche juste une solution à ce problème !

Edit : Je n'avais même pas pensé au "not" ... Quel bleu !

**rvtoulon** · 26/04/2012, 15h33

bonjour à tous, il me semble que tu as déjà une solution pour faire une boucle sur tes checkbox. voir ce récent post.

il te suffit de l'adapter à ce que tu souhaites faire.

comme çà (pas tester):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub CommandButton1_Click()
Dim Ctrl As Control
 
For Each Ctrl In Me.Controls
    If TypeOf Ctrl Is MSForms.CheckBox Then
        Select Case Ctrl.Object.Value
            Case True
                Ctrl.Object.value = False
            Case False
                Ctrl.Object.value = True
        End Select
    End If
Next Ctrl
 
End Sub

**brownthefou** · 26/04/2012, 15h39

Bonjour rvtoulon,

En effet je me rappelle de ce post, c'est le mien

Cependant j'ai 32 CheckBox et au final je veux les inverser 8 par 8, donc il me faudrait forcément un moyen de les numéroter.

Ou alors je fais une boucle qui me le fait que 8 fois mais du coup ça partira toujours de la premiere CheckBox et de la 9 a la 32 il me serait impossible de les bidouiller.

Enfin voila, avis aux personnes ayant envie de se pencher plus dessus ce n'est qu'une optimisation comme marqué dans le titre donc ne vous prenez pas trop la tête dessus vu que le code marche quand meme

Mais c'est pour un soucis de propreté quoi (je suis en stage et je dois imprimer mon code pour mon rapport ... ça fait tache quand meme ...)

**fring** · 26/04/2012, 15h47

Bonjour,

Un autre exemple qui fonctionne (comme tous ceux donnés précédemment)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub CommandButton9_Click()
Dim i As Byte
 
For i = 1 To 8
    Me.Controls("CheckBox" & i).Value = Not Me.Controls("CheckBox" & i).Value
Next
 
End Sub

**rvtoulon** · 26/04/2012, 15h47

re, avec le code de ZebreLoup

remplace

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim cbx As CheckBox

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim cbx As Control

EDIT: Désolé j'ai posté en doublon avec Fring

**brownthefou** · 26/04/2012, 15h49

Bonjour,

"Un autre exemple qui fonctionne (comme tous ceux donnés précédemment)
"

Euh ... Bah non, soit c'est moi qui suit complètement con, soit c'est la version, soit on est déja le 21 décembre...